@ECHO OFF
FOR /F "usebackq tokens=3*" %%A IN (`reg query "HKLM\SOFTWARE\EA Games\STAR WARS Battlefront II" /v "Install Dir"`) DO (
    set iiinstalldir=%%B
    )

FOR /F "usebackq tokens=3*" %%A IN (`reg query "HKLM\SOFTWARE\Wow6432Node\EA Games\STAR WARS Battlefront" /v "Install Dir"`) DO (
    set iinstalldir=%%B
    )

FOR /F "usebackq tokens=3*" %%A IN (`reg query "HKLM\SOFTWARE\WOW6432Node\BioWare\Mass Effect Andromeda" /v "Install Dir"`) DO (
    set minstalldir=%%B
    )

FOR /F "tokens=2* skip=2" %%A IN ('reg query "HKLM\SOFTWARE\WOW6432Node\Electronic Arts\EA Core" /v "EADM6InstallDir"') DO (
    set origindir=%%B
    )

FOR /F "tokens=2* skip=2" %%A IN ('reg query "HKLM\SOFTWARE\WOW6432Node\Electronic Arts\EA Desktop" /v "DesktopAppPath"') DO (
    set eadesk=%%B
    )

cls

ECHO ----------------------------------------------------------------------------------------------------------------------
ECHO Star Wars Battlefront (2015) and Star Wars Battlefront II (2017) and Mass Effect: Andromeda Modding Patch v1.2.2 for Epic Games Store, Steam and EA Desktop/Game Pass.
ECHO Created by VictorPLopes, BattleDash and Diana (Dulana57)
ECHO ----------------------------------------------------------------------------------------------------------------------
ECHO It is recommended to launch the game with Frosty after forcing mods.
ECHO It works directly from Origin/EA Desktop but it's better to launch Battlefront from Frosty Mod Manager/Editor to guarantee everything is working fine and to refresh your mod list.
ECHO You must run this program again every time you want to play another Battlefront game, so you can either disable mods or select the other game.
ECHO You must disable this whenever you play any other Frostbite game or if you encounter issues with other games.
ECHO It's normal to see some error messages when running this patch. Ignore "EADesktop.exe" or "Origin.exe" not being found.
ECHO It's recommended to restart your computer after running this program.
ECHO ----------------------------------------------------------------------------------------------------------------------
ECHO For more information about this patch, modding and support, join the Battlefront Modding Discord server at https://discord.gg/EzXSJfUDmq
ECHO ----------------------------------------------------------------------------------------------------------------------
if defined GAME_DATA_DIR (echo The patch is currently [Installed] - Mods are being forced to load)
if not defined GAME_DATA_DIR (echo The patch is currently [Not installed] - Mods are not being forced to load)
ECHO ----------------------------------------------------------------------------------------------------------------------

ECHO What do you want to do?
ECHO 1 - Enable mods for Star Wars Battlefront (2015).
ECHO 2 - Enable mods for Star Wars Battlefront II (2017).
ECHO 3 - Disable mods for all games.
ECHO 4 - Enable mods for Mass Effect: Andromeda
set /p mods="Type the number of your desired option and press [ENTER]: "
set /p launch="What do you want to do? Start EA Desktop [E], start Origin [O], restart your computer [R] or close this program [ENTER]? "

ECHO ----------------------------------------------------------------------------------------------------------------------
ECHO This window will close by itself, do NOT press X to close it.
ECHO ----------------------------------------------------------------------------------------------------------------------

if "%mods%" == "1" setx GAME_DATA_DIR "%iinstalldir%\ModData"
if "%mods%" == "2" setx GAME_DATA_DIR "%iiinstalldir%\ModData"
if "%mods%" == "3" setx GAME_DATA_DIR ""
if "%mods%" == "4" setx GAME_DATA_DIR "%minstalldir%\ModData"

taskkill /f /im Origin.exe
taskkill /f /im EADesktop.exe
timeout 10 >nul
if "%launch%" == "O" start "" "%origindir%\Origin.exe
if "%launch%" == "E" start "" "%eadesk%"
if "%launch%" == "R" shutdown /r -t 30