Trapping Info Commands

(0:100) If {*} Anything {*} {Trap Info Commands}
$ Begin Wolfscript: (1)
// Trap Info and Clear Rose Counts
&newvar #info &getvar(message)
&ifs #info = {Furcadia UID: 37692527}
  &newvar #cookiefile &getvar(SCRIPTDIR)
  &join #cookiefile {logs\cookies.log}
  &setvar rosecolors {}
  &set scalesprior &getvar(scalesnow)
  &setvar botcookies 0
  &setvar baked 0
  &setvar snugs 0
  &setvar digos {}
//  &setvar digos {freebie }
  &setvar digogifts {}
  &setvar digochecks {}
  &setvar digodates {}
  &setvar rosecounts {}
  &setvar waterballoons 0
  &setvar pillowcount 0
  &setvar snowballs 0
  &setvar candies 0
  &actstop
  &exitwolf
&endif
&set #which &array(#info {:} 0)
&ifs #which = {DragonScales Balance}
  &newvar #gold &array(#info { } 2)
  &newvar #silver &array(#info { } 4)
  &newvar #copper &array(#info { } 6)
  &newvar #scales #gold
  &join #scales {.}
  &join #scales #silver
  &join #scales {.}
  &join #scales #copper
  &join #scales { - }
  &mul #gold 100
  &mul #silver 10
  &add #gold #silver
  &add #gold #copper
  &setvar scalesnow #gold
  &join #scales #gold
  &display #scales
  &display &getvar(digos)
  &display &getvar(digogifts)
  &display &getvar(digochecks)
  &display &getvar(rosecolors)
  &display &getvar(rosecounts)
  &actstop
  &exitwolf
&endif
&ifs #which = {Extra}
  &set #which &lcase(&replace(&array(#info { } 1) {,} {}))
  &set #realname &replace(&array(#info { } 1) {,} {})
  &set #iswings &replace(&array(#info { } 2) {,} {})
  &ifs #iswings = {Wings}
    &set #realname &sprintf({%1|%2} #realname #iswings)
  &endif
  &for #index=0 to &count({null dragon phoenix gryffe tricolored butterfly bat} { })
    &ifs #which = &array({null dragon phoenix gryffe tricolored butterfly bat} { } #index)
      &exitfor
    &endif
  &endfor
  &ifn #index > &count({null dragon phoenix gryffe tricolored butterfly bat} { })
    &exitwolf
  &endif

  &newvar #offset 4
  &ifn #index > 3
    &set #offset 5
  &endif
  &newvar #expires &array(#info { } #offset)
  &set #expires &array(#expires {/} 0)

  &newvar #digodates &getvar(digodates)
  &set #digodates &sprintf({%1: %2 / %3} #realname #expires #digodates)
  &setvar digodates #digodates

  &newvar #digos &getvar(digos)
  &join #digos &replace(&array({null dragon phoenix gryffe|eagle triwngs bflywngs batwngs} { } #index) {|} { })
  &join #digos { }
  &setvar digos #digos

  &set #digos &getvar(digogifts)
  &join #digos &array({null dragongift phoenixgift gryffegift triwingsgift butterflywingsgift batwingsgift} { } #index)
  &join #digos { }
  &setvar digogifts #digos

  &set #digos &getvar(digochecks)
  &join #digos &array({null dragon phoenix gryffe triwings butterfly batwings} { } #index)
  &join #digos { }
  &setvar digochecks #digos
  &exitwolf
&endif
&ifs #which = {Item}
  &set #which &array(#info { } 2)
  &ifs #which = {roses}
    &newvar #color &array(#info { } 1)
    &newvar #count &array(#info { } 5)
    &newvar #roses &getvar(rosecolors)
    &newvar #rosecounts &getvar(rosecounts)
    &join #rosecounts #color
    &join #rosecounts {(}
    &join #rosecounts #count
    &join #rosecounts {) }
    &setvar rosecounts #rosecounts
    &join #roses #color
    &join #roses { }
    &setvar rosecolors #roses
    &setvar &sprintf({rose%1} #color) #count
    &actstop
    &exitwolf
  &endif
  &set #which &array(#info { } 1)
  &ifs #which = {cookies}
    &setvar botcookies &array(#info { } 4)
    &set #which &mid(&array(#info { } 2) 2)
    &setvar baked #which
    &actstop
    &exitwolf
  &endif
  &ifs #which = {snugs}
    &setvar snugs &array(#info { } 4)
    &actstop
    &exitwolf
  &endif
&endif

&newvar #balloons &instr(1 #info {Water Balloons})
  &ifn #balloons > 0
    &set #balloons &mid(&replace(#info {Item Stack: Water Balloons } {}) 2)
    &setvar waterballoons &array(#balloons { } 0)
    &actstop
    &exitwolf
  &endif

&newvar #balloons &instr(1 #info {Candies})
  &ifn #balloons > 0
    &set #balloons &mid(&replace(#info {Item Stack: Candies } {}) 2)
    &setvar candies &array(#balloons { } 0)
    &actstop
    &exitwolf
  &endif

&newvar #balloons &instr(1 #info {Pillows})
  &ifn #balloons > 0
    &set #balloons &mid(&replace(#info {Item Stack: Pillows } {}) 2)
    &setvar pillowcount &array(#balloons { } 0)
    &actstop
    &exitwolf
  &endif

&newvar #balloons &instr(1 #info {Snowballs})
  &ifn #balloons > 0
    &set #balloons &mid(&replace(#info {Item Stack: Snowballs } {}) 2)
    &setvar snowballs &array(#balloons { } 0)
    &actstop
    &exitwolf
  &endif

$ End Wolfscript: (1)