dialog run {
  title "Ultimate Runners Script - By interSys"
  size -1 -1 199 238
  option dbu
  text "Runners Script - By intersys", 1, 60 7 71 8
  box "Login details", 2, 110 23 86 70
  text "Username:", 3, 7 33 28 8
  edit "", 4, 40 33 64 8
  text "Password:", 5, 7 44 26 8
  edit "", 6, 40 44 64 8
  check "Save details?", 7, 8 68 42 8
  box "Login to the gatherbot", 8, 3 23 106 70
  text "Username:", 9, 114 32 28 8, disable
  text "Not enter yet", 10, 148 32 36 8, disable
  text "Password:", 11, 114 42 26 8, disable
  text "Not enter yet", 12, 148 42 36 8, disable
  check "Auto login on connect", 14, 8 80 72 8
  button "Login", 15, 55 67 37 10
  text "Auto login:", 16, 114 71 28 8, disable
  text "OFF", 17, 153 71 23 8, disable
  text "Login Status:", 18, 114 82 35 8, disable
  text "OFFLINE", 19, 153 82 31 8, disable
  text "Details saving:", 13, 114 61 37 8, disable
  text "OFF", 20, 153 61 23 8, disable
  box "Run Gather", 21, 2 96 194 140
  text "Gather Number", 22, 8 111 39 8
  list 23, 7 121 93 82, size
  text "Maps to run", 24, 104 111 31 8
  list 25, 103 121 86 82, size
  button "Run Gather", 26, 6 205 185 12
  edit "Gather Status", 27, 6 221 184 10, disable center
  text "Gbot name:", 28, 7 54 31 8
  edit "", 29, 40 54 64 8
  button "Add Map", 30, 141 109 46 10
  button "Refresh", 31, 50 109 40 10
  text "Gbot name:", 32, 114 51 31 8, disable
  text "Bar - Gather", 33, 148 51 41 8, disable
}

on *:dialog:run:*:*: {
  if ($devent == dclick) {
    if ($did == 25) {
      did -r $dname 25
      var %x = 1
      write -d $+ $read(RMaps.txt,$did($dname,25).sel) RMaps.txt
      while ($read(RMaps.txt,%x)) {
        did -a $dname 25 $ifmatch
        inc %x
      }
    }
  }
  elseif ($devent == sclick) {
    if ($did == 26) {
      echo -s $did(29)
      if ($did($dname,23).sel == 0) { did -ra $dname 27 Error! You not selected gather to run. }
      elseif ($did($dname,25).sel == 0) { did -ra $dname 27 Error! You not selected map to run. }
      elseif (!%r.gbot) || (!$did(29)) { did -ra $dname 27 Error! You dont write the gatherbot name. }
      elseif (%r.log != on) { did -ra $dname 27 Error! You not logged to the gatherbot. }
      else {
        var %sign = $readini(RunGTR.ini,$did($dname,23).sel,Sign), %map = $read(RMaps.txt,$did($dname,25).sel)
        msg $iif(%r.gbot,%r.gbot,$did(29)) %sign $+ start %map | did -ra $dname 27 Your run gather succsesfuly!
      }
    }
    elseif ($did == 30) {
      var %x = $input(Enter new map,e,Adding new map), %i = 1 | if (%x) write RMaps.txt %x | did -r $dname 25
      while ($read(RMaps.txt,%i)) {
        did -a $dname 25 $ifmatch
        inc %i
      }
    }
    elseif ($did == 31) {
      rund
      did -ra $dname 23 Getting status, please wait ...
      .timer 1 5 rund2
    }
    elseif ($did == 15) {
      join #vgathers.crew,#vGames
      var %x = $regsubex($me,/^(?:\[?.+?\](.+?)|.+\|(.+?))$/i,\1) | nick vG $+ $chr(124) $+ %x
      .timer 1 1 msg $iif(%r.gbot,%r.gbot,$did(29)) !login $iif(%r.user,%r.user,$did(4)) $iif(%r.pass,%r.pass,$did(6))
      did -ra $dname 10 $iif(%r.user,%r.user,$did(4))
      did -a $dname 12 $iif(%r.pass,%r.pass,$did(6))
      did -a $dname 33 $iif(%r.gbot,%r.gbot,$did(29))
      did -a $dname 20 $iif(%r.dsave == ON,ON,OFF)
      did -a $dname 17 $iif(%r.autolog == ON,ON,OFF)
    }
    elseif ($did == 7) {
      set %r.dsave $iif($did(7).state == 1,ON,OFF)
      did -a $dname 20 $iif($did(7).state == 1,ON,OFF)
      if (%r.dsave == on) {
        set %r.user $did(4)
        set %r.pass $did(6)
        set %r.gbot $did(29)
      }
      else { unset %r.* }
    }
    elseif ($did == 14) { set %r.autolog $iif($did(14).state == 1,ON,OFF) | did -a $dname 17 $iif($did(14).state == 1,ON,OFF) }
  }
  elseif ($devent == init) {
    did -a $dname 4 %r.user
    did -a $dname 6 %r.pass
    did -a $dname 29 %r.gbot
    did -a $dname 10 $iif(%r.user,%r.user,Not enter yet)
    did -a $dname 12 $iif(%r.pass,%r.pass,Not enter yet)
    did -a $dname 33 $iif(%r.gbot,%r.gbot,Not enter yet)
    did -a $dname 20 $iif(%r.dsave == ON,ON,OFF)
    did -a $dname 17 $iif(%r.autolog == ON,ON,OFF)
    did -a $dname 19 $iif(%r.log == ON,ONLINE,OFFLINE)
    did $iif(%r.dsave == on,-c,-u) $dname 7
    did $iif(%r.autolog == on,-c,-u) $dname 14
    var %x = 1
    while ($ini(RunGTR.ini,%x)) {
      did -a $dname 23 Gather: $ifmatch $chr(124) Status $readini(RunGTR.ini,$ifmatch,Gather $+ %x) $+ $chr(124) Sign: $readini(RunGTR.ini,$ifmatch,Sign $+ %x)
      inc %x
    }
    var %x = 1
    while ($read(RMaps.txt,%x)) {
      did -a $dname 25 $ifmatch
      inc %x
    }
  }
}

on *:connect: {
  if (%r.autolog == on) {
    set %r.log OFF
    echo -s 10(Autologin - By intersys) Auto connecting to your accounet in vGames.Gathers, Please wait ...
    var %x = $regsubex($me,/^(?:\[?.+?\](.+?)|.+\|(.+?))$/i,\1)
    .timer 1 3 nick vG $+ $chr(124) $+ %x
    .timer 1 4 join #vGames.Gathers,#vGathers.Crew
    .timer 1 7 msg %r.gbot !login %r.user %r.pass
  }
}

on *:text:*:?: {
  if ($nick == %r.gbot) {
    if (You have successfully login isin $strip($1-)) { set %r.log ON | did -ra run 19 ONLINE }
    elseif (You are logged out isin $strip($1-)) { set %r.log OFF | did -ra run 19 OFFLINE }
  }
}

on *:text:*:#vGames.Gathers: {
  if ($nick == vG|Rankbot) && (Gather 1: isin $strip($1-)) && (%msgon) {
    noop $regsubex($strip($1-),/\((.)\) Gather (\d+): \((ON|OFF|Adding)(?:\|[^\x29]*)?\)/g, $rplaa(\1, \2, \3))
  }
}

alias rund2 {
  did -r run 23
  var %x = 1
  while ($ini(RunGTR.ini,%x)) {
    did -a run 23 Gather: %x $chr(124) Status $readini(RunGTR.ini,%x,Gather $+ %x) $+ $chr(124) Sign: $readini(RunGTR.ini,%x,Sign $+ %x)
    inc %x
  }
}

alias rund {
  .echo -ag 14Please wait, its get the status gathers ...
  .msg #vGames.gathers ?status
  .set -u3 %msgon on
}

alias rplaa { writeini -n RunGTR.ini $2 Gather $+ $2 $3 | writeini -n RunGTR.ini $2 Sign $1 }
alias RunnerD { rund | if (!$dialog(run)) .timer 1 5 dialog -m run run }
menu * {
  Runners Script - By intersys: RunnerD
}
on *:load: {
  echo -s 04Ulitmate Runners Script - By intersys
  echo -s 04Version 0.1
  var %a = write RMaps.txt
  %a de_dust2
  %a de_inferno
  %a de_nuke
  %a de_train
  %a de_mirage
  %a de_cbble
  %a de_dust
  %a de_cpl_strike
  %a de_cpl_fire
  %a de_cpl_fire
  %a de_vertigo
  %a de_rotterdam
  %a de_aztec
  %a de_vegas
  %a de_prodigy
  %a de_survivor
  %a de_torn
  %a de_storm
  %a de_chateau
  %a de_piranesi
  %a de_perfect_inferno
  %a de_airstrip
  %a de_nuke_1337
  %a de_tuscan
  %a de_cpl_mill
  %a de_forge
  %a de_cpl_fire
  %a de_cpl_strike
  %a de_rats
  %a de_rats_1337
  %a de_perfect_inferno
  %a de_nuke_1337
  %a cs_havana
  %a cs_thunder
  %a cs_assault_upc
  %a cs_assault
  %a cs_italy
  %a cs_assault_shadow
  %a cs_assault_upc
  %a as_oilrig
  %a cs_estate
  %a cs_office
  %a cs_747
}