@echo off
COLOR 0B
TITLE A3 Night5 Autorestart alle 4 Stunden
SETLOCAL EnableExtensions enabledelayedexpansion
set EXE=arma3server_x64.exe
set /A restartCounter=0

rem Zeit in Minuten bis zum Restart
Set secondsToRestart=240

goto SelectServerType

:SelectServerType
cls
echo A3 Night5 Autorestart Launcher gedoens.
echo.
echo 1 - Night5 Arma3 Haupt-Server.

echo.
set /P mod=Waehle deinen Server:
if "%mod%"=="1" goto SetRestartTime

goto Server_Error


:Server_Error
cls
echo.
echo Falsche Serverauswahl (ID), gebe Sie erneut ein und versuche es nochmal, ansonsten geh erstmal eine rauchen.
pause > NUL
goto SelectServerType


:SetRestartTime
cls

for /F "tokens=1-3 delims=:." %%a in ("%time%") do (
   set timeHour=%%a
   set timeMinute=%%b
   set timeSeconds=%%c
)

set cTime=%timeHour%:%timeMinute%:%timeSeconds%
set /A newTime=timeHour*60 + timeMinute + %secondsToRestart%
set /A timeHour=newTime/60, timeMinute=newTime%%60
if %timeHour% gtr 23 set timeHour=0
if %timeHour% lss 10 set timeHour=0%timeHour%
if %timeMinute% lss 10 set timeMinute=0%timeMinute%
set restartTime=%timeHour%:%timeMinute%:%timeSeconds%
echo Der Server wurde am %cTime% neugestartet und wird am %restartTime% erneut neugestartet und das alle 4 Stunden.
goto StartArma3Server


:StartArma3Server
echo Der Night5 A3 Haupt-Server startet und wurde schon %restartCounter% oft neugestartet.
if "%mod%"=="1" start /b arma3server_x64.exe -autoinit -port=3202 -servermod=@extDB3;@life_server;@ac_metrics;@The_Programmer;@Night5_RealLife;@allianceapps_admintool -config=server.cfg -bepath=C:\server\battleye -profiles=C:\server
timeout 10 >nul
goto CheckServerRunning


:CheckServerRunning
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto ServerFound
goto ServerNotFound


:ServerFound
for /F "tokens=1-3 delims=:." %%a in ("%time%") do (
   set timeHour=%%a
   set timeMinute=%%b
   set timeSeconds=%%c
)

set /A newTime=timeHour*60 + timeMinute
set /A timeHour=newTime/60, timeMinute=newTime%%60
if %timeHour% gtr 23 set timeHour=0
if %timeHour% lss 10 set timeHour=0%timeHour%
if %timeMinute% lss 10 set timeMinute=0%timeMinute%
set theCurrentTime=%timeHour%:%timeMinute%:%timeSeconds%

if %restartTime% LSS %theCurrentTime% goto KillRestartServer
timeout 10 >nul
goto CheckServerRunning


:ServerNotFound
echo Server nicht gefunden.
timeout 5 >nul
goto SetRestartTime


:KillRestartServer
set /A restartCounter+=1
echo Bitte warten, der Server startet gerade.
timeout 1 >nul
taskkill /F /IM %EXE% >nul
timeout 15 >nul
goto SetRestartTime