@name EGPServerInfo
@inputs S:wirelink
@outputs
@persist Chat:array
@trigger
#@model models\props/cs_office/computer_caseB.mdl

if(first()) {
    S:egpClear()
    if(S:entity():type() == "gmod_wire_egp_emitter") {
        S:egpBox(1, vec2(256, 256), vec2(512, 512))
        S:egpColor(1, vec(0, 0, 0))
    }
    S:egpBox(2, vec2(256, 256), vec2(512, 512))
    S:egpColor(2, vec(50, 50, 50))
    if(S:entity():type() == "gmod_wire_egp_hud") {
        S:egpAlpha(2, 220)
    }
    S:egpMaterial(2, "console/background01")
    S:egpBox(10, vec2(32, 32), vec2(16, 16))
    S:egpMaterial(10, "gui/info")
    S:egpText(11, hostname(), vec2(48, 22))
    S:egpSize(11, 18)
    S:egpCircle(12, vec2(512-32, 32), vec2(32, 32))
    S:egpColor(12, vec(80, 0, 0))
    S:egpBox(13, vec2(512-32, 32), vec2(96, 96))
    S:egpMaterial(13, "gui/faceposer_indicator")
    S:egpText(15, maxPlayers():toString(), vec2(512-32, 32))
    S:egpAlign(15, 1, 0)
    S:egpSize(15, 20)
    S:egpLine(18, vec2(20, 50), vec2(450, 50))
    S:egpText(20, "Name", vec2(32, 88))
    S:egpAlign(20, 0, 2)
    if(gamemode():find("DarkRP")) {
        S:egpText(21, "Job", vec2(300, 88))
        S:egpAlign(21, 0, 2)
    } else {
        S:egpText(21, "Frags", vec2(300, 88))
        S:egpAlign(21, 0, 2)
        S:egpText(22, "Deaths", vec2(370, 88))
        S:egpAlign(22, 0, 2)
    }
    S:egpText(23, "Ping", vec2(440, 88))
    S:egpAlign(23, 0, 2)

    S:egpLine(19, vec2(20, 430), vec2(512-84, 430))

    S:egpBox(140, vec2(512 - 52, 460), vec2(64, 64))
    S:egpMaterial(140, "maps/gm_construct")
    S:egpBoxOutline(141, vec2(512 - 52, 460), vec2(64, 64))

    Map = map()
    Map = Map:replace("_", " ")
    MapA = Map:explode(" ")
    MapB = array()
    I = 1
    foreach(K,V2:string = MapA) {
        if(I >= 2) {
            MapB:pushString(V2:sub(0, 1):upper() + V2:sub(2))
        }
        I++
    }
    S:egpText(142, MapB:concat(" "), vec2(420, 435))

    S:egpAlign(142, 2, 0)
    S:egpSize(142, 32)
    S:egpText(143, gamemode(), vec2(420, 470))
    S:egpAlign(143, 2, 0)
}

S:egpText(14, numPlayers():toString(), vec2(512-32, 36))
S:egpAlign(14, 1, 2)
S:egpSize(14, 28)

Players = players()
foreach(K,V:entity = Players) {
    if(K<=12) {
        S:egpTextLayout(30+K*8, V:name(), vec2(32, 58 + K*28), vec2(260, 24))
        S:egpSize(30+K*8, 24)
        if(gamemode():find("DarkRP")) {
            S:egpText(31+K*8, teamName(V:team()):sub(0, 15), vec2(300, 60 + K*28))
            S:egpSize(31+K*8, 24)
        } else {
            S:egpText(31+K*8, V:frags():toString(), vec2(300, 60 + K*28))
            S:egpSize(31+K*8, 24)
            S:egpText(32+K*8, V:deaths():toString(), vec2(370, 60 + K*28))
            S:egpSize(32+K*8, 24)
        }
        S:egpText(33+K*8, V:ping():toString(), vec2(440, 60 + K*28))
        S:egpSize(33+K*8, 24)

        S:egpBox(34+K*8, vec2(16, 70 + K*28), vec2(16, 16))
        if(V:isSuperAdmin()) {
            S:egpMaterial(34+K*8, "gui/silkicons/shield")
            S:egpBox(35+K*8, vec2(20, 74 + K*28), vec2(8, 8))
            S:egpMaterial(35+K*8, "gui/silkicons/add")
        } elseif (V:isAdmin()) {
            S:egpMaterial(34+K*8, "gui/silkicons/shield")
            S:egpRemove(35+I*8)
        } else {
            S:egpMaterial(34+K*8, "gui/silkicons/user")
            S:egpRemove(35+I*8)
        }

        Color = teamColor(V:team())
        S:egpColor(30+K*8, Color)
        S:egpColor(31+K*8, Color)
        S:egpColor(32+K*8, Color)
        S:egpColor(33+K*8, Color)
        S:egpColor(36+K*8, Color)
        S:egpColor(37+K*8, Color)
    }
}
for(I=Players:count()+1, 12) {
    S:egpRemove(30+I*8)
    S:egpRemove(31+I*8)
    S:egpRemove(32+I*8)
    S:egpRemove(33+I*8)
    S:egpRemove(34+I*8)
    S:egpRemove(35+I*8)
    S:egpRemove(36+I*8)
    S:egpRemove(37+I*8)
}

#if(owner():keyAttack1() & owner():aimEntity() == S:entity()) {
#    S:egpPos(237, S:egpCursor(owner()))
#}

interval(1000)