image/spotlight
	plane = -1
	blend_mode = BLEND_ADD
	icon = 'icons/light.dmi'
	icon_state = "circle"
	mouse_opacity = 0
	alpha = 0

	New(icon,loc,icon_state,layer,dir)
		..()
		var matrix/m = new
		m.Scale(9, 9)
		m.Translate(44, 40)
		transform = m
		var anim_scale = 0.9
		var matrix/base_transform = transform
		var matrix/anim_transform = new
		anim_transform.Scale(9, 9)
		anim_transform.Translate(44 * 1.1, 40 * 1.1)
		anim_transform *= anim_scale
		animate(src, transform = anim_transform, time = 7, loop = -1, easing = SINE_EASING)
		animate(transform = base_transform, time = 7)
		animate(src, alpha = 255, time = 25, flags = ANIMATION_PARALLEL)

obj
	plane_lighten
		plane = -1
		blend_mode = BLEND_ADD
		mouse_opacity = 0
		icon = 'icons/box.dmi'
		screen_loc = "CENTER:12, CENTER:12"

		New(set_alpha)
			..()
			var/matrix/m = matrix()
			m.Scale(33, 25)
			transform = m
			animate(src, alpha = set_alpha || 24, time = 10)

		dispose_custom()
			set waitfor = 0
			if(!isactive(src))
				return
			datum_state = DATUM_STATE_INACTIVE
			animate(src, alpha = 255, time = 15)
			sleep(15)
			..()


obj
	base_plane
		plane = 0
		appearance_flags = PLANE_MASTER | PIXEL_SCALE
		screen_loc = "1, 1"

		New()
			transform *= 2

		dark
			blend_mode = BLEND_MULTIPLY
			appearance_flags = PLANE_MASTER | PIXEL_SCALE | NO_CLIENT_COLOR
			color = list(null, null, null, "#0000", "#000f")
			mouse_opacity = 0

			flower_mist
				screen_loc = "SOUTH,WEST to NORTH,EAST"
				icon = 'icons/blur.dmi'
				icon_state = "3"
				/*
				New()
					..()
					animate(src, alpha = 192, time = 10, loop = -1, easing = CIRCULAR_EASING)
					animate(alpha = 255, time = 5)
					*/