GM2_Camera_AdditionalScripts

///----------------------------------------------///
///          CalculateCameraDelayMovement        ///
///----------------------------------------------///

var _x = targetX - cameraOriginX;
var _y = targetY - cameraOriginY;

if (isSmooth)
{
    var _followSpeed = 0.08;

    cameraX = lerp(cameraX, _x, _followSpeed);
    cameraY = lerp(cameraY, _y, _followSpeed);
}
else
{
    cameraX = _x;
    cameraY = _y;
}

///----------------------------------------------///
///              MoveCameraToPoint               ///
///----------------------------------------------///

/// @param moveSpeed

var _moveSpeed = argument0;

cameraX = lerp(cameraX, targetX - cameraOriginX, _moveSpeed);
cameraY = lerp(cameraY, targetY - cameraOriginY, _moveSpeed);

///----------------------------------------------///
///                 SetCameraMode                ///
///----------------------------------------------///

/// @description SetCameraMode

/// @param mode
/// @param followTarget/targetX
/// @param targetY


with (global.Camera)
{
    cameraMode = argument[0];

    switch (cameraMode)
    {
        case CameraMode.FollowObject:
        case CameraMode.MoveToFollowObject:
            cameraFollowTarget = argument[1];
        break;

        case CameraMode.MoveToTarget:
            targetX = argument[1];
            targetY = argument[2];
        break;
    }
}

///----------------------------------------------///
///                 SetCameraZoom                ///
///----------------------------------------------///

/// @description SetCameraZoom

/// @param newZoom

var _zoom = argument0;

with (global.Camera)
{
    cameraZoom = clamp(_zoom, 0.1, cameraZoomMax);
    camera_set_view_size(mainCamera, global.IdealWidth / cameraZoom, global.IdealHeight / cameraZoom);
}