PKGBUILD

# Maintainer: Davi da Silva Böger <dsboger at gmail dot com>

pkgname=warsaw-bb
pkgver=1.12.3.11
pkgrel=1
pkgdesc="Security module for internet banking (Banco do Brasil)"
arch=("i686" "x86_64")
url="http://www.dieboldnixdorf.com.br/gas-antifraude"
license=("custom")

depends=("dbus" "openssl" "nss" "curl")
makedepends=("chrpath")

source=("warsaw-core.service")
md5sums=('8b0b90542a5910bde4dff94a4f4a7bd7')

_runfile_i686="warsaw_32_installer.run"
source_i686=("https://cloud.gastecnologia.com.br/bb/downloads/ws/${_runfile_i686}")
md5sums_i686=('b53b1696e2a0624f54eb516538ac655b')

_runfile_x86_64="warsaw_64_installer.run"
source_x86_64=("https://cloud.gastecnologia.com.br/bb/downloads/ws/${_runfile_x86_64}")
md5sums_x86_64=('2d19b66de26dbd01a7980427a0535a8f')

noextract=("${_runfile_i686}" "${_runfile_x86_64}")
options=('!strip')
install="warsaw-bb.install"

if [[ $CARCH == x86_64 ]]; then
	_runfile=warsaw_64_installer.run
	_warsawdir=tmp/warsaw_x64
else
	_runfile=warsaw_32_installer.run
	_warsawdir=tmp/warsaw_x86
fi

prepare() {
	# 363 is a "magic number" found in the installer
	tail -n +363 ${_runfile} | tar -zxvf - -C "${srcdir}"

	if [[ $CARCH == i686 ]]; then
		# WTF???
		sed -e '7s|/\(ibfontconfig.so.1\)|/l\1|' \
			-e '7s|/\(ibgmp.so.10\)|/l\1|' \
			-e '7,74s|$| \\|' \
			-i "${srcdir}"/${_warsawdir}/Makefile.am
	fi

	cd "${srcdir}"/${_warsawdir}/
	autoreconf --force
}

pkgver() {
	cd "${srcdir}"/${_warsawdir}

	grep AC_INIT configure.ac | sed -e 's/^AC_INIT.*\[\([0-9\.]*\)\].*/\1/'
}

build() {
	cd "${srcdir}"/${_warsawdir}

	./configure
}

package() {
	cd "${srcdir}"/${_warsawdir}

	make install DESTDIR="${pkgdir}"

	# Fix installation

	# Move copyright notice to licences dirS
	install -D -m 644 "${pkgdir}"/usr/share/doc/warsaw/copyright \
		"${pkgdir}"/usr/share/licenses/${pkgname}/copyright
	rm -r "${pkgdir}"/usr/share/doc

	# Remove insecure RPATH
	chrpath -d "${pkgdir}"/usr/local/lib/warsaw/wsbrmu.so
	chrpath -d "${pkgdir}"/usr/local/lib/warsaw/wsftbco.so
	chrpath -d "${pkgdir}"/usr/local/lib/warsaw/wsftbid.so
	chrpath -d "${pkgdir}"/usr/local/lib/warsaw/wsftbmo.so
	chrpath -d "${pkgdir}"/usr/local/lib/warsaw/wsftdl.so
	chrpath -d "${pkgdir}"/usr/local/lib/warsaw/wsftuan.so
	chrpath -d "${pkgdir}"/usr/local/lib/warsaw/wsftup.so
	chrpath -d "${pkgdir}"/usr/local/lib/warsaw/wslbmid.so
	chrpath -d "${pkgdir}"/usr/local/bin/warsaw/migratecache

	# Replace init.d script with systemd service
	rm -rf "${pkgdir}"/etc/init.d
	install -D -m 644 "${srcdir}"/warsaw-core.service \
		"${pkgdir}"/usr/local/lib/systemd/system/warsaw-core.service

	# Make binaries executable
	chmod 755 "${pkgdir}"/usr/local/bin/warsaw/*
}