#NoEnv
#SingleInstance Force

; You will need to install Acc stuff First, https://www.autohotkey.com/boards/viewtopic.php?f=6&t=26201

F1:: ; Press F1 and a MsgBox will appear with all chrome tabs on new lines. That makes it easy to put into an array
    Tabs := JEE_ChromeGetTabNames(hWnd:="0x200A2", vSep:="`n") ; Use AccViewer.ahk to get hWnd Value, Yours will be different, Or leave blank for active window
    MsgBox, % Tabs
return

JEE_ChromeAccInit(vValue)
{
    if (vValue = "U1")
        return "4.1.2.1.2.5.2" ;address bar
    if (vValue = "U2")
        return "4.1.2.2.2.5.2" ;address bar
    if (vValue = "T")
        return "4.1.2.1.1.1"
}

JEE_ChromeGetTabNames(hWnd:="", vSep:="`n")
{
    local
    static vAccPath := JEE_ChromeAccInit("T")
    if (hWnd = "")
        hWnd := WinExist("A")
    oAcc := Acc_Get("Object", vAccPath, 0, "ahk_id " hWnd)

    vHasSep := !(vSep = "")
    if vHasSep
        vOutput := ""
    else
        oOutput := []
    for _, oChild in Acc_Children(oAcc)
    {
        ;ROLE_SYSTEM_PUSHBUTTON := 0x2B
        if (oChild.accRole(0) = 0x2B)
            continue
        try vTabText := oChild.accName(0)
        catch
            vTabText := ""
        if vHasSep
            vOutput .= vTabText vSep
        else
            oOutput.Push(vTabText)
    }
    oAcc := oChild := ""
    return vHasSep ? SubStr(vOutput, 1, -StrLen(vSep)) : oOutput
}