ComputerKey

wmic path softwareLicensingService get OA3xOriginalProductKey

Option Explicit

Dim objshell,path,path2,DigitalID,Result,MyHostName,objWMIService,colSMBIOS,objSMBIOS
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
Path2 = "HKLM\HARDWARE\DESCRIPTION\System\BIOS\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
'Get current computer name
MyHostName = objshell.ExpandEnvironmentStrings("%ComputerName%")
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & MyHostName & "\root\cimv2")
Set colSMBIOS = objWMIService.ExecQuery _
    ("Select * from Win32_SystemEnclosure")
For Each objSMBIOS in colSMBIOS
    SerialNumber = "Serial Number:  " & objSMBIOS.SerialNumber
Next
Dim ComputerName,ProductName,ProductID,ProductKey,ProductData,SerialNumber,PartNumber,ProductVersion1,ProductVersion2,ProductVersion3
'Get ProductName, ProductID, ProductKey
ComputerName = "Computer Name:  " & objshell.ExpandEnvironmentStrings("%ComputerName%")
ProductName = "Product Name:    " & objshell.RegRead(Path & "ProductName")
ProductVersion1 = "Vers. (build):   " & objshell.RegRead(Path & "ReleaseID")
ProductVersion2 = " (" & objshell.RegRead(Path & "CurrentBuild")
ProductVersion3 = "." & objshell.RegRead(Path & "UBR") & ")"
ProductID = "Product ID:    " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key:    " & ConvertToKey(DigitalID)

PartNumber = "Part Number:  " & objshell.RegRead(Path2 & "SystemSKU")
ProductData = ComputerName & vbNewLine & ProductName  & vbNewLine & ProductVersion1 & ProductVersion2 & ProductVersion3 & vbNewLine & ProductID  & vbNewLine & ProductKey & vbNewLine & SerialNumber & vbNewLine & PartNumber
'Show messbox if save to a file
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "Back-up Windows Key Information") then
   Save ProductData
End If



'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
           Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0

    If (isWin8 = 1) Then
        keypart1 = Mid(KeyOutput, 2, Last)
        insert = "N"
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then KeyOutput = insert & KeyOutput
    End If


    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)


End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName,ComputerName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")
    'Get current computer name
    ComputerName = objshell.ExpandEnvironmentStrings("%ComputerName%")
    'Create a text file on desktop
    fName = "C:\Users\" & UserName & "\Desktop\" & ComputerName & ".txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function