Batch Script - Open Windows Registry to Custom Path

:: CREATED BY SlyFox1186
:: https://pastebin.com/u/slyfox1186
:: https://stackoverflow.com/users/10572786/slyfox11867

:: THIS SCRIPT WILL OPEN CMD.EXE AND PROMPT THE USER TO SELECT >>
:: A LIST OF PREDEFINED REGISTRY PATHS THAT ARE COMMONLY ASSOCIATED WITH >>
:: >> EDITING FILE EXPLORER'S CONTEXT MENU

:: THIS SCRIPT REQUIRES REGJUMP.EXE
:: YOU CAN DOWNLOAD IT FROM MICROSOFT'S SYSINTERNALS WEBSITE >>
:: >> (https://docs.microsoft.com/en-us/sysinternals/downloads/regjump)

:: THE USER PROMPT WILL HAVE YOU CHOOSE BETWEEN >>
:: >> FOLDERS ASSOCIATED WITH THE [ USER ] OR [ MACHINE ] REGISTRY FOLDERS >>
:: >> OR ENTER YOUR OWN [CUSTOM PATH]

@ECHO OFF
IF NOT "%1"=="am_admin" (POWERSHELL -WindowStyle Hidden -Command START -verb RunAs '%0' am_admin & EXIT /B)
:-------------------------------------
PROMPT $G
COLOR 0A
TITLE REGJUMP TO EXPLORER SHELL FOLDERS

:restart
SETLOCAL

PUSHD "%~dp0"

SET HKCR=HKEY_CLASSES_ROOT
SET HKLM=HKEY_LOCAL_MACHINE\SOFTWARE\Classes

:: CHOOSE A REGISTRY REPOSITORY
CLS && ECHO.
ECHO [1] USER [%HKCR%]
ECHO [2] MACHINE [%HKLM%]
ECHO [3] INPUT CUSTOM PATH
ECHO [4] EXIT && ECHO.

CHOICE /C 1234 /N /M "Choose a repository:"

IF ERRORLEVEL 4 GOTO :EOF
IF ERRORLEVEL 3 ENDLOCAL && GOTO regCUSTOM
IF ERRORLEVEL 2 GOTO regMACHINE
IF ERRORLEVEL 1 GOTO regUSER

:regMACHINE
CLS && ECHO.
ECHO CHOOSE A MACHINE FOLDER && ECHO.
ECHO [1] %HKLM%\*\shell
ECHO [2] %HKLM%\AllFilesystemObjects\shell
ECHO [3] %HKLM%\DesktopBackground\shell
ECHO [4] %HKLM%\Directory\Background\shell
ECHO [5] %HKLM%\Directory\shell
ECHO [6] %HKLM%\Drive\shell
ECHO [7] %HKLM%\Folder\shell
ECHO [8] Exit && ECHO.

CHOICE /C 12345678 /N /M "CHOOSE A FOLDER:"

IF ERRORLEVEL 8 GOTO :EOF
IF ERRORLEVEL 7 regjump.exe %HKLM%\Folder\shell && GOTO :EOF
IF ERRORLEVEL 6 regjump.exe %HKLM%\Drive\shell && GOTO :EOF
IF ERRORLEVEL 5 regjump.exe %HKLM%\Directory\shell && GOTO :EOF
IF ERRORLEVEL 4 regjump.exe %HKLM%\Directory\Background\shell && GOTO :EOF
IF ERRORLEVEL 3 regjump.exe %HKLM%\DesktopBackground\shell && GOTO :EOF
IF ERRORLEVEL 2 regjump.exe %HKLM%\AllFilesystemObjects\shell && GOTO :EOF
IF ERRORLEVEL 1 regjump.exe %HKLM%\*\shell && GOTO :EOF

:regUSER
CLS && ECHO.
ECHO CHOOSE A USER FOLDER && ECHO.
ECHO [1] %HKCR%\*\shell
ECHO [2] %HKCR%\AllFilesystemObjects\shell
ECHO [3] %HKCR%\DesktopBackground\shell
ECHO [4] %HKCR%\Directory\Background\shell
ECHO [5] %HKCR%\Directory\shell
ECHO [6] %HKCR%\Drive\shell
ECHO [7] %HKCR%\Folder\shell
ECHO [8] Exit && ECHO.

CHOICE /C 12345678 /N /M "CHOOSE A FOLDER:"

IF ERRORLEVEL 8 GOTO :EOF
IF ERRORLEVEL 7 regjump.exe %HKCR%\Folder\shell && GOTO :EOF
IF ERRORLEVEL 6 regjump.exe %HKCR%\Drive\shell && GOTO :EOF
IF ERRORLEVEL 5 regjump.exe %HKCR%\Directory\shell && GOTO :EOF
IF ERRORLEVEL 4 regjump.exe %HKCR%\Directory\Background\shell && GOTO :EOF
IF ERRORLEVEL 3 regjump.exe %HKCR%\DesktopBackground\shell && GOTO :EOF
IF ERRORLEVEL 2 regjump.exe %HKCR%\AllFilesystemObjects\shell && GOTO :EOF
IF ERRORLEVEL 1 regjump.exe %HKCR%\*\shell && GOTO :EOF

:: CUSTOM REGISTRY PATH
:regCUSTOM
SETLOCAL ENABLEDELAYEDEXPANSION
CLS && ECHO.
ECHO Enter a registry path and hit ENTER to JUMP
SET /P customPATH=
IF ERRORLEVEL 1 GOTO jumpFAIL
CALL :jumpCUSTOM !customPATH!
GOTO :EOF

:jumpFAIL
:: USER INPUT NOT DETECTED
CLS && ECHO.
ECHO NOTHING WAS ENTERED... && ECHO.
ECHO [1] Retry custom path
ECHO [2] Restart from beginning
ECHO [3] Exit && ECHO.

CHOICE /C 123 /N

IF ERRORLEVEL 3 GOTO :EOF
IF ERRORLEVEL 2 ENDLOCAL && GOTO restart
IF ERRORLEVEL 1 ENDLOCAL && GOTO regCUSTOM

:jumpCUSTOM
regjump.exe %~1 && EXIT /B