Windows Repair Script

@echo off
setlocal

net session >nul 2>&1
if not %errorlevel%==0 (
    echo Dieses Script muss als Administrator ausgefuehrt werden.
    pause
    exit /b 1
)

cls
echo Windows Repair Script by @nurjns
echo ---
echo www.nurjns.de
echo.
echo Mit diesem Script wird ein beschaedigtes Windows automatisch repariert. Folgende Reparaturen werden dabei durchgefuehrt:
echo.
echo - Fehler im Dateisystem beheben
echo - Windows Update Cache zuruecksetzen
echo - Windows Komponenten-Store zuruecksetzen
echo - Systemdateien ueberpruefen und reparieren
echo.
echo Waehrend der Reparatur koennen Fehlermeldungen auftauchen. Diese koennen ignoriert werden.
echo.
pause
cls

echo Pruefe Dateisystem...
chkdsk %SystemDrive% /F

echo.
echo Stoppe Windows Update-Dienste...
net stop wuauserv
net stop bits
net stop cryptsvc

echo.
echo Setze Windows Update Cache zurueck...
if exist "%WinDir%\SoftwareDistribution" rd "%WinDir%\SoftwareDistribution" /S /Q
mkdir "%WinDir%\SoftwareDistribution" >nul 2>&1

echo Starte Windows Update-Dienste...
net start cryptsvc
net start bits
net start wuauserv

echo.
echo Pruefe Windows-Komponentenstore...
Dism /Online /Cleanup-Image /CheckHealth
Dism /Online /Cleanup-Image /ScanHealth
Dism /Online /Cleanup-Image /RestoreHealth

echo.
echo Pruefe Systemdateien...
sfc /scannow

cls
echo.
echo Alle Reparaturen wurden durchgefuehrt. Der Computer wird jetzt neu gestartet.
echo.
pause
shutdown /g /t 0