font dialect

use [f] [

    font: func [
        {Font dialect. Makes font object.

        Examples
        eg: font ["lucinda" 36 silver top left 5x5 10x10 1x1]
        arial12: font ["arial" 12]
        fixedsys: font ["fixedsys" bold]
        lucinda12: font ["lucinda" 12 silver top left]

        view layout compose/deep [area font (eg: font ["lucinda" 36 silver top left 5x5 10x10 1x1])]

        possible changes
        make font default to top left alignment
        }
        a
        /local oss
    ] [
        f: make face/font []
        do bind/copy [

            oss: copy [] ;pairs become the offset space and shadow, see [1] and [2]
            foreach a a  [
                switch type?/word a [
                    string!         [name: a]
                    integer!        [size: a]
                    block!          [style: a]
                    tuple!          [color: a]
                    word!           [
                        switch a [
                            left right center       [align: a]
                            top bottom middle       [valign: a]
                            bold italic underline   [style: a]
                        ]
                        if all [value? a tuple? get a] [color: get a]
                    ]
                    pair!           [append oss a] ;[1]
                ]
            ]
            set [offset space shadow] oss ;[2]
        ] f

        return f
    ]

]