/*
    Author: Jean-Park
    Teamspeak 3: ts.the-programmer.com
    Web site: www.the-programmer.com

    Terms of use:
      - This file is forbidden unless you have permission from the author. If you have this file without permission to use it please do not use it and do not share it.
      - If you have permission to use this file, you can use it on your server however it is strictly forbidden to share it.
      - Out of respect for the author please do not delete this information.

*/
_CurConfig = missionConfigFile >> "The_programmer_Duty_Config";
_east_side = getNumber (_CurConfig >> "east_configuration" >> "east_side");

if ((playerSide isEqualto independent) || (playerSide isEqualto west)) exitWith {
	 hint parseText (['STR_ALREADY_EMT',"The_programmer_Duty_Config","Prise_Service_Localization"] call theprogrammer_core_fnc_localize);
};

if ((player getVariable "The_Programmer_IsCop") || (player getVariable "The_Programmer_IsEMT")) exitWith {
	 hint parseText (['STR_ALREADY_EMT',"The_programmer_Duty_Config","Prise_Service_Localization"] call theprogrammer_core_fnc_localize);
};

if ((_east_side isEqualTo 1) && ((playerSide isEqualTo east) || (player getVariable "The_Programmer_IsAdac"))) exitWith {
	 hint parseText (['STR_ALREADY_EMT',"The_programmer_Duty_Config","Prise_Service_Localization"] call theprogrammer_core_fnc_localize);
};

_TP_Authorized_Adac = player getVariable "TP_Authorized_Adac";
_TP_Authorized_Police = player getVariable "TP_Authorized_Police";
_TP_Authorized_Medic = player getVariable "TP_Authorized_Medic";

if !(_TP_Authorized_Medic) exitWith {
  hint parseText (['STR_NOT_EMT',"The_programmer_Duty_Config","Prise_Service_Localization"] call theprogrammer_core_fnc_localize);
};

_syncdata = [] spawn SOCK_fnc_updateRequest;
waitUntil {scriptDone _syncdata};

_grp = createGroup independent;
_oldPlayer = player;
_oldPosplayer = getposWorld player;
_dir = getDir player;

_unit = _grp createUnit ["I_Survivor_F", position player, [], 0, "FORM"];
_unit allowDamage false;
_oldVarName = vehicleVarName _oldPlayer;

_unit setPosWorld _oldPosplayer;
_unit setDir _dir;
[_unit] joinSilent _grp;

selectPlayer _unit;
deleteVehicle _oldPlayer;

The_programmer_initialised = true;
player allowDamage true;

missionNamespace setVariable [_oldVarName,player,true];
[player,_oldVarName] remoteExecCall ["The_programmer_Duty_fnc_SetvehicleVarName",0,player];

[(getPlayerUID player)] remoteExec ["TON_fnc_houseCleanup",2];

[getText (_CurConfig >> "path_init")] spawn {
    _path_init = _this select 0;
    [] execVM _path_init;
};

if ((getNumber (_CurConfig >> "briefing")) isEqualTo 1) then {
    [] execVM "briefing.sqf";
};

player setVariable ["The_Programmer_IsCop",false,true];
player setVariable ["The_Programmer_IsEMT",true,true];
player setVariable ["The_Programmer_IsAdac",false,true];
player setVariable ["ace_medical_medicClass",2,true];

player setVariable ["TP_Authorized_Adac",_TP_Authorized_Adac,true];
player setVariable ["TP_Authorized_Police",_TP_Authorized_Police,true];
player setVariable ["TP_Authorized_Medic",_TP_Authorized_Medic,true];

hint parseText (['STR_ONDUTTY_EMT',"The_programmer_Duty_Config","Prise_Service_Localization"] call theprogrammer_core_fnc_localize);

if ((getNumber (_CurConfig >> "save_between_disconnection")) isEqualTo 1) then {
	[2,player] remoteExec ["The_programmer_Duty_fnc_UpdateQuery",2];
};

["Prisedeservice",[format[(['STR_NO_TAKE_DUTY',"The_programmer_Duty_Config","Prise_Service_Localization"] call theprogrammer_core_fnc_localize),name player]]] remoteExec ["BIS_fnc_showNotification",independent];