Decorate

// Defines the Pickup Classes

ACTOR Slot311Pickup : CustomInventory replaces Shotgun
{
	Inventory.PickupMessage ""
	Inventory.PickupSound "silence"
	Inventory.RespawnTics 357 //10 seconds to respawn
	+FLOATBOB
	States
	{
	Spawn:
		SHOT A -1
		Stop
	Pickup:
		SHOT A 0 A_GiveInventory("12-Gauge Shotgun")
		SHOT A 0 A_PlaySound("weapons/pickup")
		SHOT A 0 ACS_ExecuteAlways(880,0,311)
		Stop
	}
}

// Defines the Weapon Classes

ACTOR "12-Gauge Shotgun" : Weapon
{
	Weapon.AmmoGive 10
	Weapon.AmmoType "ShotShells"
	Weapon.AmmoUse 1
	// Weapon.BobRangeX 0.5
	// Weapon.BobRangeY 0.2
	// Weapon.BobSpeed 2
	// Weapon.BobStyle "InverseSmooth"
	Weapon.Kickback 200
	Weapon.SelectionOrder 540
	Weapon.SlotNumber 3
	Weapon.SlotPriority 1
	Weapon.UpSound "weapons/select"
	DamageType "Shotgun.Single"
	Decal Bulletchip
	Obituary "%k pumped %o full of buckshot."
	Tag "12-Gauge Shotgun"
	+WEAPON.NOAUTOAIM
	States
	{
	Ready:
		SHTG A 1 A_WeaponReady
		Loop
	Select:
		SHTG AAAA 0 A_Raise
		SHTG A 1 A_Raise
		Loop
	Deselect:
		SHTG AAAA 0 A_Lower
		SHTG A 1 A_Lower
		Loop
	Fire:
		SHTG A 0 A_JumpIfInventory("VersusModeOn",1,"FireVersus")

		SHTG A 0 A_FireBullets(700/100.0,100/100.0,8,random(12,20),"BulletPuff",FBF_USEAMMO|FBF_NORANDOM)
		SHTG A 0 ACS_ExecuteAlways(800)
        	SHTG A 0 A_PlaySound ("weapons/singleshotgun/fire", CHAN_WEAPON)
		SHTG A 7 A_GunFlash

		SHTG BC 6
		SHTG D 5
        	SHTG CB 6
        	SHTG A 5 A_GiveInventory("Subtic.3-1",7)
		SHTG A 0 A_JumpIfInventory("Subtic.3-1",21,2)
		SHTG A 1
		SHTG A 0 A_ReFire
		Goto Ready
	FireVersus:
		SHTG A 0 A_FireBullets(700/100.0,100/100.0,8,random(8,12),"BulletPuff",FBF_USEAMMO|FBF_NORANDOM)
		SHTG A 0 ACS_ExecuteAlways(800)
        	SHTG A 0 A_PlaySound ("weapons/singleshotgun/fire", CHAN_WEAPON)
		SHTG A 5 A_GunFlash

		SHTG BC 4
		SHTG D 3
        	SHTG CB 4
        	SHTG A 4 A_GiveInventory("Subtic.3-1",9)
		SHTG A 0 A_JumpIfInventory("Subtic.3-1",21,2)
		SHTG A 1
		SHTG A 0 A_ReFire
		Goto Ready
	Flash:
		SHTF A 0 A_JumpIfInventory("VersusModeOn",1,"FlashVersus")

		SHTF A 4 Bright A_Light1
		SHTF A 3 Bright A_Light1
		Goto LightDone
	FlashVersus:
		SHTF A 3 Bright A_Light1
		SHTF B 2 Bright A_Light2
		Goto LightDone
//	Spawn:
//		SHOT A -1
//		Stop
	}
}

ACTOR "Subtic.3-1" : Inventory //Subtic Attachment
{
	Inventory.Amount 1
	Inventory.MaxAmount 42
	+UNDROPPABLE
	-INVBAR
	+IGNORESKILL
}