kino

Proceso sin_titulo
	Definir numJ, numM, indice, x_indice Como Entero;
	Definir valorTemporal, aciertos Como Entero;
	Definir validador Como Logico;
	Dimension numJ(14);
	Dimension numM(14);
	validador = verdadero;
	aciertos = 0;
	valorTemporal = 0;
	indice = 0;
	x_indice = 0;

	// En esta parte se asigna el valor 0 a las 14 variables dentro de los 2 arreglos.
	Para indice <-0 Hasta 13 con paso 1 hacer
		numM(indice) = 0;
		numJ(indice) = 0;
	FinPara
	// Aqui se asigan los 14 numeros de la maquina. y se verefica que no se repitan. en caso de repetirse, se vuelve a tirar un numero al azar.

	Para indice <- 0 hasta 13 con paso 1 Hacer
		numM(indice) = azar (25)+1;
		para x_indice <- 0 Hasta 13 con paso 1 hacer
			Si indice != x_indice Entonces
				Si numM(indice) == numM(x_indice) Entonces
					validador = Falso;
				FinSi
			FinSi
		FinPara
		Si validador == falso Entonces
			indice = indice -1;
			validador = Verdadero;
		FinSi
	FinPara

	// En esta parte el usuario ingresa sus 14 numeros, en caso de ser un numero repetido, este le pedira que ingrese nuevamente...
	// yo lo deje con un selector automatico para ahorrar tiempo al momento de testiar...(linea 39).
	Para indice <- 0 Hasta 13 con paso 1 Hacer
		Escribir "Ingrese un numero entre 1 y 25, no se puede repetir";
		numJ(indice) = azar(25)+1;
		Esperar 200 milisegundo;
		Limpiar Pantalla;
		Si numJ(indice) > 0 && numJ(indice) < 26 Entonces
			para x_indice <-0 Hasta 13 con paso 1 Hacer
				si indice != x_indice Entonces
					Si numJ(indice) == numJ(x_indice) Entonces
						validador = falso;
					FinSi
				FinSi
			FinPara
			Si validador ==  falso Entonces
				indice = indice -1;
				validador = Verdadero;
				Escribir "El numero seleccionado ya fue ingresado, Ingrese nuevamente";
			FinSi
		Sino
			Escribir "Debe ingresar un numero en el rango valido";
			indice = indice-1;
		FinSi
	FinPara

	// En esta parte se ordenan los numeros.
	Para indice <- 0 Hasta 13 con paso 1 Hacer
		para x_indice <- 0 Hasta 13 con paso 1 hacer
			Si x_indice != 0 Entonces
				Si numM(x_indice -1) > numM(x_indice) Entonces
					valortemporal = numM(x_indice);
					numM(x_indice) = numM(x_indice -1);
					numM(x_indice -1) = valortemporal;
				FinSi
			FinSi
		FinPara
	FinPara

	Para indice <- 0 Hasta 13 con paso 1 Hacer
		Para x_indice <- 0 Hasta 13 con paso 1 hacer
			Si numJ(indice) == numM(x_indice) Entonces
				aciertos = aciertos +1;
			FinSi
		FinPara
	FinPara

	Escribir "============================================";
	Escribir "Los numeros sorteados fueron";
	Escribir "============================================";
	Para indice <- 0 Hasta 13 Con paso 1 Hacer
		Escribir Sin Saltar "|", numM(indice),"|";
	FinPara
	Escribir "";
	Escribir "============================";
	Escribir "Tus numeros seleccionados fueron";
	Escribir "============================";
	Para indice <-0 Hasta 13 con paso 1 Hacer
		Escribir sin saltar "|", numJ(indice),"|";
	FinPara
	Escribir "";
	Escribir "=======================================";
	Escribir "Hubieron ",aciertos," aciertos en tu apuesta";
FinProceso