HoN startup script

@echo off
rem ============================================================================================================
rem That script run hon with mac spoofer and proxy
rem !!! When edit settings dont use space after '=' !!!
rem ============================================================================================================

rem ============================================================================================================
rem Settings
rem ============================================================================================================

rem For change you IP uncomment (remove 'rem' word and space) next 1-2 lines for enable proxy and change proxy settings, you can use any anonymous proxy
rem SET http_proxy=http://user:password@hostname:port/
rem SET https_proxy=https://hostname:port/

rem Change HONEXE value to full path to your hon.exe or hon_x64.exe
SET HONEXE=C:\Program Files\Heroes of Newerth x64\hon_x64.exe

rem To enable auto-start ACD set STARTACD to 1
SET STARTACD=0
rem Change ACDEXE value to full path to your acd.exe (dont use paths with space or dots, не используйте путь с русскими буквами, пробелами и точками в пути)
SET ACDEXE=C:\hona\acd.exe

rem You can rename files macspoofer.exe and macspoofer_x64.exe to anything and change next 2 lines.
SET INJECTOR=macspoofer.exe
SET INJECTOR_x64=macspoofer_x64.exe

rem You can rename files macspoofer.dll and macspoofer_x64.dll to anything and change next 2 lines.
SET INJECTED=macspoofer.dll
SET INJECTED_x64=macspoofer_x64.dll

rem End of settings
rem ============================================================================================================

rem ============================================================================================================
rem Code
rem ============================================================================================================
setlocal enableextensions enabledelayedexpansion

rem ============================================================================================================
rem Main()
rem ============================================================================================================
IF NOT x"%HONEXE:x64.exe=%"==x"%HONEXE%" GOTO :x64
:x32
ECHO Spoofing MACs in x32 HoN...
call :startprocess %INJECTOR% "%HONEXE%" %INJECTED%
GOTO :next

:x64
ECHO Spoofing MACs in x64 HoN...
call :startprocess %INJECTOR_x64% "%HONEXE%" %INJECTED_x64%

:next
IF NOT ERRORLEVEL 0 GOTO :sexit
IF NOT "%STARTACD%"=="1" GOTO :sexit
ECHO Starting ACD from %ACDEXE%
CALL :getacdfilepath %ACDEXE%
ECHO ACD PATH: "%ACDPATH%"
START "s" /D "%ACDPATH%" %ACDEXE%

:sexit
EXIT

rem ============================================================================================================
rem Functions
rem ============================================================================================================

rem getacdfilepath(filename)
rem ===============================
:getacdfilepath
SET ACDPATH=%~d1%~p1
EXIT /b
rem ===============================

rem startprocess(inj,exe,dll)
rem ===============================
:startprocess
setlocal enableextensions enabledelayedexpansion
SET HONEXE=
SET STARTACD=
SET ACDEXE=
SET INJECTOR=
SET INJECTOR_x64=
SET INJECTED=
SET INJECTED_x64=
%1 %2 %3
endlocal
EXIT /b
rem ===============================

endlocal