CompressPhotos.VBS v2

Option Explicit

Const AppGUID = "{D96D136C-F6C5-4F99-8344-759DD645CFDB}"

Dim FSO
Dim WShell

DoIt

'====================================================================
Private Sub DoIt()
  If DoIt2() Then
    WScript.Quit 0
  Else
    WScript.Quit 1
  End If
End Sub

'====================================================================
Private Function DoIt2()
  Dim Folder
  Dim SourcePath

  DoIt2 = False

  Set FSO = CreateObject("Scripting.FileSystemObject")
  Set WShell = CreateObject("WScript.Shell")

  SourcePath = GetSourcePath()
  If SourcePath = "" Then
    ShowUsage
    Exit Function
  End If

  On Error Resume Next

  Set Folder = FSO.GetFolder(SourcePath)
  If Err.Number <> 0 Then
    WScript.Echo "ERROR! Can't get source folder."
    Exit Function
  End If

  If Not CompressPhotos(Folder.Files) Then Exit Function

  WScript.Echo "=============="
  WScript.Echo "All done! ^_^v"

  DoIt2 = True
End Function

'====================================================================
Private Function GetSourcePath()
  If WScript.Arguments.Count = 1 Then _
    GetSourcePath = WScript.Arguments(0)
End Function

Private Sub ShowUsage()
  WScript.Echo "Usage: CompressPhotos.VBS SourcePath"
End Sub

'====================================================================
Private Function CompressPhotos(ByRef Files)
  Dim File
  Dim Ext

  For Each File In Files
    Ext = UCase(FSO.GetExtensionName(File.Name))
    If Ext = "JPG" Or Ext = "JPEG" Then
      If File.Size > 1.3 * 1024 * 1024 Then
        If Not CompressPhoto(File) Then
          CompressPhotos = False
          Exit Function
        End If
      Else
        WScript.Echo "Ignoring: " & File.Path
      End If
    End If
  Next

  CompressPhotos = True
End Function

'====================================================================
Private Function CompressPhoto(ByRef File)
  Dim SourceFileName
  Dim TargetFileName
  Dim CmdLine
  Dim RC

  On Error Resume Next

  CompressPhoto = False

  SourceFileName = File.Path
  TargetFileName = File.Path & " " & AppGUID & _
                   "." & FSO.GetExtensionName(File.Name)

  '==================================================================
  WScript.Echo "Converting: " & SourceFileName

  CmdLine = """Y:\PortableApps\IrfanView\i_view32.exe"" " & _
            """" & SourceFileName & """ " & _
            "/resize_long=2000 /resample /aspectratio " & _
            "/convert=""" & TargetFileName & """"
  RC = WShell.Run(CmdLine, 10, True)

  If Err.Number <> 0 Then
    WScript.Echo "ERROR! Can't execute IrfanView."
    WScript.Echo "ERROR! Command line: " & CmdLine
    Exit Function
  End If

  If RC <> 0 Then
    WScript.Echo "ERROR! IrfanView returns " & CStr(RC) & "."
    Exit Function
  End If

  '==================================================================
  CmdLine = "RecycleFile.EXE " & _
            """" & SourceFileName & """"
  RC = WShell.Run(CmdLine, 0, True)

  If Err.Number <> 0 Then
    WScript.Echo "ERROR! Can't execute AJPapps - Recycle file."
    WScript.Echo "ERROR! Command line: " & CmdLine
    Exit Function
  End If

  If RC <> 0 Then
    WScript.Echo "ERROR! AJPapps - Recycle file returns " & CStr(RC) & "."
    Exit Function
  End If

  '==================================================================
  FSO.MoveFile TargetFileName, SourceFileName

  If Err.Number <> 0 Then
    WScript.Echo "ERROR! Can't move file: " & TargetFileName
    Exit Function
  End If

  '==================================================================
  'WScript.Echo File.Path & " :: " & File.Size & " bytes"
  'WScript.Echo SourceFileName & " ==> " & TargetFileName
  'WScript.Echo CmdLine
  'WScript.Echo File.Path & " :: RC ==> " & RC

  CompressPhoto = True
End Function