# Ovale Optimized Script Leafkiller 5.4
# Ovale source: http://wow.curse.com/downloads/wow-addons/details/ovale.aspx
# Cat Rotation based on Simulationcraft single target default script. Contributions to that have come from many ferals.
# Revision History
# 5.4.4   08/29/2012 Change TF code to take into account the new T13 4 piece bonus. Try to give Rake more leeway.
#                    Add opportunistic FF after fillers.
# 5.4.3   08/28/2012 Misc small changes to make it more robust per discussion with Tinderhoof
# 5.4.2   08/28/2012 Rudimentary Bear stuff - I need someway to track Mangle...
# 5.4.1   08/27/2012 First version for patch 5.4 - leaving out Guardian and Feral/Bear for the moment
#                    Assume Glyph of Rake and Glyph of Shred
#                    TargetDeadIn seems to be having issues - so removing the calls for now. Won't affect most combat

Define(BERSERK 106951) #cat+bear cd buff
Define(FAERIEFERAL 770) #bear+cat
Define(FEROCIOUSBITE 22568) #cat finish 35-70 mana
Define(MAIM 22570) #cat interrupt
Define(MANGLECAT 33876) #cat bleed+debuff
   SpellInfo(MANGLECAT inccounter=ripshreds)
Define(RAKE 1822) #cat bleed
Define(RIP 1079) #cat bleed
   SpellInfo(RIP resetcounter=ripshreds)
Define(SAVAGEROAR 127538) #cat damage buff
Define(SHRED 5221) #cat behind
    SpellInfo(SHRED inccounter=ripshreds)
Define(SKULLBASHCAT 80965) #cat interrupt
Define(TIGERSFURY 5217) #cat buff

Define(BERSERKBEAR 106952) #cat+bear cd buff
  SpellInfo(BERSERKBEAR duration=10 cd=180 )
  SpellAddBuff(BERSERKBEAR BERSERKBEAR=1)
Define(MANGLEBEAR 33878)
Define(LACERATE 33745)
Define(FRENZIEDREGEN 22842)
Define(INCARNATIONBEAR 102558)
Define(MAUL 6807)
Define(MIGHTOFURSOC 106922)
Define(RENEWAL 108238)
Define(SAVAGEDEFENSE 62606)
Define(SURVIVALINSTINCTS 61336)
Define(SWIPEBEAR 779)
Define(THRASHBEAR 77758)
Define(BARKSKIN 22812)
Define(ENRAGE 5229)

Define(cat_form 768)
  SpellAddBuff(cat_form cat_form=1)
Define(mark_of_the_wild 1126)
  SpellInfo(mark_of_the_wild duration=3600 )
  SpellAddBuff(mark_of_the_wild mark_of_the_wild=1)
Define(ravage 6785)
  SpellInfo(ravage energy=45 combo=1 )
  SpellInfo(ravage inccounter=ripshreds)
Define(incarnation 102543)
  SpellInfo(incarnation duration=30 cd=180 )
Define(treants 106737)
  SpellInfo(treants duration=15 cd=60 )
Define(weakened_armor 113746)
  SpellInfo(weakened_armor duration=30 )
  SpellAddBuff(weakened_armor weakened_armor=1)
Define(weakened_blows 115798)
  SpellInfo(weakened_blows duration=30 )
  SpellAddBuff(weakened_blows weakened_blows=1)
Define(dream_of_cenarius_talent 17)
Define(force_of_nature_talent 12)
Define(incarnation_talent 11)
Define(natures_swiftness_talent 4)
Define(natures_vigil_talent 18)

#Buff
Define(CLEARCASTING 16870)

AddCheckBox(berserk "Cat Berserk" default mastery=2)
AddCheckBox(cooldownsL "Show Left Rotation Boxes" default mastery=2)
AddCheckBox(cooldownsR "Show Right Cooldown Boxes" default mastery=2)
AddCheckBox(lucioles SpellName(FAERIEFERAL) default mastery=2)
AddCheckBox(shred "Use Shred for fillers"  default mastery=2)



AddIcon help=cd size=small mastery=3 {
    Spell(BARKSKIN)
}

AddIcon help=cd size=small mastery=3 {
    Spell(RENEWAL)
}

# Main rotation
AddIcon help=main mastery=3 {
    if 1s before Spell(MANGLEBEAR) Spell(MANGLEBEAR)

    if target.DebuffStacks(weakened_armor) <1 Spell(FAERIEFERAL)

    if not TargetDebuffPresent(weakened_blows) Spell(THRASHBEAR)

    Spell(LACERATE)
}

AddIcon help=defense mastery=3 {
    Spell(SAVAGEDEFENSE usable=1)
    Spell(FRENZIEDREGEN)
}

AddIcon help=cd size=small mastery=3 {
    Spell(SURVIVALINSTINCTS)
}

AddIcon help=cd size=small mastery=3 {
    Spell(MIGHTOFURSOC)
}

AddIcon help=cd size=small mastery=3 {
    Spell(ENRAGE)
}

AddIcon help=cd size=small mastery=3 {
    Spell(BERSERKBEAR)
}

AddFunction AddCombo
{
   if TalentPoints(incarnation_talent) Spell(ravage usable=1)
   if BuffPresent(TIGERSFURY) or BuffPresent(BERSERK) or CheckBoxOn(shred) Spell(SHRED)
    Spell(MANGLECAT)
}
4
AddFunction BITWRange
{
   {ArmorSetParts(T13 more 1) and TargetLifePercent(less 60)} or TargetLifePercent(less 25)
}
# Main rotation
AddIcon help=main mastery=2 {
    # Savage Roar
    if BuffRemains(SAVAGEROAR) <=1 or {ComboPoints(more 0) and ComboPoints(less 5) and BuffExpires(SAVAGEROAR 3)} {
        Spell(SAVAGEROAR)
    }

    # TF + Berserk logic - only show Berserk if both are off of cooldown - everyone should macro TF to their Berserk key
    if not {BuffPresent(BERSERK) or BuffPresent(CLEARCASTING)} {
        if ArmorSetParts(T13 more 3) {
            if Energy(less 26) and {0s before Spell(TIGERSFURY)} {
                if CheckBoxOn(berserk) Spell(BERSERK)
                Spell(TIGERSFURY)
            }
        }
        if not ArmorSetParts(T13 more 3) {
            if Energy(less 36) and {0s before Spell(TIGERSFURY)} {
                if CheckBoxOn(berserk) Spell(BERSERK)
                Spell(TIGERSFURY)
            }
        }
    }

    #In case Berserk was not cast with TF
    if BuffPresent(TIGERSFURY) and CheckBoxOn(berserk) {
        Spell(BERSERK)
    }

    if not TargetInRange(SHRED) {
        Texture(ability_druid_catformattack)
    }

    if CheckBoxOn(lucioles) and target.DebuffStacks(weakened_armor) <1 {
        Spell(FAERIEFERAL)
    }

    # Two conditions for FB during Blood of the Water phase
    # Add in FB code for end of fight - only do this is Rip buff is present
    if BITWRange() and TargetDebuffPresent(RIP mine=1) {
        if ComboPoints(more 4) Spell(FEROCIOUSBITE)
        if ComboPoints(more 0) and TargetDebuffExpires(RIP 2.9 mine=1) Spell(FEROCIOUSBITE)
    }
    #Extends Rip with shred/mangle/ravage
    if TargetDebuffPresent(RIP mine=1) and TargetDebuffExpires(RIP 4 mine=1) and Counter(ripshreds less 3) AddCombo()

    # Time to recast Rip - clip if possible - try to hold off for TF
    if ComboPoints() >=5 and TargetDebuffExpires(RIP 2 mine=1) and {BuffPresent(BERSERK) or target.DebuffRemains(RIP mine=1)+1.9 <=SpellCooldown(TIGERSFURY) }
        Spell(RIP)

    # FBs during Berserk
    if BuffPresent(BERSERK) {
        if ComboPoints(more 4) and Energy(more 12) and TargetDebuffPresent(RIP 5 mine=1) and BuffPresent(SAVAGEROAR 3) {
            Spell(FEROCIOUSBITE)
        }
    }

    # clip Rake early if TF is up and rake ramining is less than 9 seconds
    if TargetDebuffExpires(RAKE 8.9 mine=1) and BuffPresent(TIGERSFURY) {
        Spell(RAKE)
    }

    # intentionally clip Rake to maximize uptime
    if TargetDebuffExpires(RAKE 2.9 mine=1) and {BuffPresent(BERSERK) or Energy(more 60) or {SpellCooldown(tigers_fury) +0.8 } >=target.DebuffRemains(RAKE mine=1)}
        Spell(RAKE)

    if BuffPresent(CLEARCASTING) AddCombo()

    # Burn combo points on FB if the target is about to die - on a boss fight this is redundant with BotW phase
    if ComboPoints(more 4) and TargetDeadIn(less 7) {
        Spell(FEROCIOUSBITE)
    }

    # Shred aggressively for Berserk and TF
    if BuffPresent(BERSERK) or BuffPresent(TIGERSFURY) AddCombo()

    # Shred for combo points for Rip or SR
    if ComboPoints(less 5) and TargetDebuffExpires(RIP 3 mine=1) AddCombo()
    if ComboPoints(less 1) and BuffExpires(SAVAGEROAR 2) AddCombo()

    # Shred to burn off energy so we can TF without capping
    if { 3s before Spell(TIGERSFURY) } AddCombo()

    # Shred is the mob will die within one Rake
    if TargetDeadIn(less 8.5) AddCombo()

    # Fallback Shred to prevent energy capping
    if 1.2s before Energy(more 99) AddCombo()

    # opportunistic FF
    if TargetDebuffExpires(weakened_armor 15) Spell(FAERIEFERAL)
}