Minimal_Plugins.bat

@rem Minimal_Plugins.bat "$Revision: 1396 $" "$Date: 2019-03-16 12:57:46 +0200 (la, 16 maalis 2019) $"
@rem
@rem See PluginEnablerOrDisablerPlugin.cs for additonal notes and customizations!
@rem
@goto :prepare_minimal
:copy_minimal
rem
rem Draws circle on Minimap for normal and resplendent chests.
rem
call :copyfile Actors\ChestPlugin.cs
rem
rem Draws circle and label on Minimap for cursed event chests.
rem
call :copyfile Actors\CursedEventPlugin.cs
rem
rem Draws round marker on Minimap for rift progression orbs and power globes.
rem
call :copyfile Actors\GlobePlugin.cs
rem
rem Draws label on Minimap for portals (level entry points).
rem
call :copyfile Actors\PortalPlugin.cs
rem
rem Draws markers and labels for shrines, healing  wells and pylons on Minimap.
rem
call :copyfile Actors\ShrinePlugin.cs
rem
rem Press F6 to see bounties state summary.
rem
call :copyfile BountyTablePlugin.cs
rem
rem Shows blood shard amoount using green, yellow or red label on bottom skillbar.
rem
call :copyfile Inventory\BloodShardPlugin.cs
rem
rem Enchances item display, in our case draws "A" or "P" marker on item.
rem
call :copyfile Inventory\InventoryAndStashPlugin.cs
rem
rem Shows item description for "equipped" Canai's Cube items on Inventory header.
rem
call :copyfile Inventory\InventoryKanaiCubedItemsPlugin.cs
rem
rem Shows material counts on Inventory bottom.
rem
call :copyfile Inventory\InventoryMaterialCountPlugin.cs
rem
rem Draws marker and label for cosmetic items on Minimap.
rem
call :copyfile Items\CosmeticItemsPlugin.cs
rem
rem Customized to show only ancient and primal items, hide item labels.
rem
call :copyfile Items\ItemsPlugin.cs
rem
rem Shows pickup range indicator (filled circle) under player. Disabled now.
rem
call :copyfile Items\PickupRangePlugin.cs
rem
rem Show POI markers on Map. For example for bounty names or keywarden names.
rem
call :copyfile Minimap\MarkerPlugin.cs
rem
rem Shows rift progression value in colors for monsters during rifts on Minimap.
rem This is customized to show less colors for clarity.
rem - yellow for elites that can drop rift orbs,
rem - blue   for monsters with good progression value,
rem - green  for monsters with some progression value,
rem - gray   for monsters with little progression value.
rem Check http://www.warpath.eu/index.html for details about rift progression values.
rem
call :copyfile Monsters\MonsterRiftProgressionColoringPlugin.cs
rem
rem Shows monsters in different colors on Minimap.
rem
call :copyfile Monsters\StandardMonsterPlugin.cs
rem
rem Shows those minion like actors on Minimap that layer can spawn to fight/help for him/her.
rem
call :copyfile Players\PlayerSkillPlugin.cs
rem
rem Shows health and class specific numbers over corresponding UI "globes" on bottom skillbar.
rem
call :copyfile ResourceOverGlobePlugin.cs
rem
rem Shows health potion cooldown over it. Sometimes show garbage numbers (in town).
rem
call :copyfile SkillBars\OriginalHealthPotionSkillPlugin.cs
rem
rem Shows more info about skill duration and cooldown etc. over them in skillbar.
rem
call :copyfile SkillBars\OriginalSkillBarPlugin.cs
rem
rem Shows special events bounties on Act Map.
rem
call :copyfile WaypointQuestsPlugin.cs
echo.
echo Done
popd
pause
goto :eof

:copyfile
set filename=%1
copy .\plugins.bak\Default\%filename% .\plugins\Default\%filename%  >nul 2>&1
if %ERRORLEVEL% EQU 0 (
    echo file copy ok    %filename%
) ELSE (
    echo file copy ERROR %ERRORLEVEL% %filename%
)
goto :eof

:copydir
set dirname=%1
copy .\plugins.bak\Default\%dirname% .\plugins\Default\%dirname%  >nul 2>&1
if %ERRORLEVEL% NEQ 0 (
    echo dir  copy ERROR %ERRORLEVEL% %dirname%
)
goto :eof

:prepare_minimal
@echo off
pushd ..\..
echo Current directory
cd
echo.
rem
rem Move everything from plugins\Default to backup folder for clean start.
rem
robocopy plugins\Default plugins.bak\Default *.* /S /MOVE /R:0 /W:0
rem
rem Create required plugins folder structure.
rem
mkdir .\plugins\Default\Actors  >nul 2>&1
mkdir .\plugins\Default\BasePlugin  >nul 2>&1
mkdir .\plugins\Default\BuffLists  >nul 2>&1
mkdir .\plugins\Default\BuffLists\Painter  >nul 2>&1
mkdir .\plugins\Default\Decorators  >nul 2>&1
mkdir .\plugins\Default\Extensions  >nul 2>&1
mkdir .\plugins\Default\Faders  >nul 2>&1
mkdir .\plugins\Default\ItemRenderers  >nul 2>&1
mkdir .\plugins\Default\Inventory  >nul 2>&1
mkdir .\plugins\Default\Items  >nul 2>&1
mkdir .\plugins\Default\LabelLists  >nul 2>&1
mkdir .\plugins\Default\LabelLists\TopLabelList  >nul 2>&1
mkdir .\plugins\Default\Minimap  >nul 2>&1
mkdir .\plugins\Default\Monsters  >nul 2>&1
mkdir .\plugins\Default\Players  >nul 2>&1
mkdir .\plugins\Default\RadiusTransformators  >nul 2>&1
mkdir .\plugins\Default\RotationTransformators  >nul 2>&1
mkdir .\plugins\Default\ShapePainters  >nul 2>&1
mkdir .\plugins\Default\SkillBars  >nul 2>&1
mkdir .\plugins\Default\SkillBars\Painter  >nul 2>&1
mkdir .\plugins\Default\WorldShapePainters  >nul 2>&1
rem
rem These are needed for plugin infrastructure.
rem
call :copydir BasePlugin
call :copydir BuffLists\Painter
call :copydir Decorators
call :copydir Extensions
call :copydir Faders
call :copydir ItemRenderers
call :copydir LabelLists\TopLabelList
call :copydir RadiusTransformators
call :copydir RotationTransformators
call :copydir ShapePainters
call :copydir SkillBars\Painter
call :copydir WorldShapePainters
goto :copy_minimal