plugins {
    id "com.android.application"
    id "kotlin-android"
    id "kotlin-kapt"
    id "kotlinx-serialization"
    id "de.mannodermaus.android-junit5"
    id "com.github.triplet.play" version "3.4.0"
    id "androidx.navigation.safeargs.kotlin"
    id "com.google.gms.google-services"
    id "com.google.firebase.crashlytics"
    id "com.google.firebase.firebase-perf"
}

play {
    // Файл с учётными данными сервисного аккаунта для доступа к Google Play Publisher API
    serviceAccountCredentials.set(file("google-play-api-service-account.json"))
    // Публикуем только в трек для внутреннего тестирования
    // Перевод в общедоступный трек вручную в консоли Google Play
    track.set("internal")
    // Пока приложение не опубликовано можно создавать только черновики релизов
    // После публикации можно будет выкатывать релиз полностью автоматически
    releaseStatus.set(com.github.triplet.gradle.androidpublisher.ReleaseStatus.COMPLETED)
    defaultToAppBundles.set(true)
    resolutionStrategy.set(com.github.triplet.gradle.androidpublisher.ResolutionStrategy.AUTO)
}

android {
    signingConfigs {
        debug {
            storeFile file("keystore.jks")
            keyAlias "debug"
            keyPassword "vU6>#ip64P"
            storePassword "G6q3S;jt9n-Q"
        }
    }
    compileSdkVersion 30
    buildToolsVersion "30.0.3"

    defaultConfig {
        applicationId "ru.dapdriftpro"
        minSdkVersion 23
        targetSdkVersion 30
        versionCode 16
        versionName "1.0.0"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        testInstrumentationRunnerArgument "runnerBuilder", "de.mannodermaus.junit5.AndroidJUnit5Builder"
    }

    buildTypes {
        debug {
            minifyEnabled false
            signingConfig signingConfigs.debug
            manifestPlaceholders = [crashlyticsCollectionEnabled:"false", performanceCollectionDeactivated:"true"]
            FirebasePerformance {
                instrumentationEnabled false
            }
        }
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro"
            manifestPlaceholders = [crashlyticsCollectionEnabled:"true", performanceCollectionDeactivated:"false"]
        }
    }

    buildFeatures {
        viewBinding true
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }
}

dependencies {
    implementation project(":domain")
    implementation project(":data")
    //Constraint
    def constraint_version = "2.0.4"
    implementation "androidx.constraintlayout:constraintlayout:$constraint_version"
    //Coil
    def coil_version = '1.2.0'
    implementation "io.coil-kt:coil:$coil_version"
    //Fragment
    def fragment_version = "1.3.3"
    implementation "androidx.fragment:fragment-ktx:$fragment_version"
    //Navigation
    def navigation_version = "2.3.5"
    implementation "androidx.navigation:navigation-fragment-ktx:$navigation_version"
    implementation "androidx.navigation:navigation-ui-ktx:$navigation_version"
    //ViewModel & LiveData
    def lifecycle_version = "2.3.1"
    implementation "androidx.lifecycle:lifecycle-viewmodel-ktx:$lifecycle_version"
    implementation "androidx.lifecycle:lifecycle-livedata-ktx:$lifecycle_version"
    // Koin for Android + Scope + ViewModel
    implementation "org.koin:koin-android:$koin_version"
    implementation "org.koin:koin-androidx-scope:$koin_version"
    implementation "org.koin:koin-androidx-viewmodel:$koin_version"
    //Room
    def room_version = "2.3.0"
    implementation "androidx.room:room-runtime:$room_version"
    implementation "androidx.room:room-ktx:$room_version"
    kapt "androidx.room:room-compiler:$room_version"
    //Material Design
    def material_version = "1.3.0"
    implementation "com.google.android.material:material:$material_version"
    //Coroutines & Flow
    def coroutines_version = "1.4.2"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$coroutines_version"
    //Retrofit
    def retrofit_version = "2.9.0"
    implementation "com.squareup.retrofit2:retrofit:$retrofit_version"
    //Kotlin Serialization
    def kotlin_serialization_version = "1.1.0"
    implementation "org.jetbrains.kotlinx:kotlinx-serialization-json:$kotlin_serialization_version"
    //Retrofit Converter
    def retrofit_serialization_version = "0.8.0"
    implementation "com.jakewharton.retrofit:retrofit2-kotlinx-serialization-converter:$retrofit_serialization_version"
    //Okhttp Logging Interceptor
    def interceptor_version = "4.9.0"
    implementation "com.squareup.okhttp3:logging-interceptor:$interceptor_version"
    //Open Street Map
    def osm_version = "6.1.10"
    implementation "org.osmdroid:osmdroid-android:$osm_version"
    //Prefs
    def preference_version = "1.1.1"
    implementation "androidx.preference:preference-ktx:$preference_version"
    //Google Play Billing
    def billing_version = "3.0.3"
    implementation "com.android.billingclient:billing-ktx:$billing_version"
    //Google Services Location
    def services_location_version = "18.0.0"
    implementation "com.google.android.gms:play-services-location:$services_location_version"
    //Skeleton loading
    def veil_version = "1.1.1"
    implementation "com.github.skydoves:androidveil:$veil_version"
    //Google Auth
    def auth_version = "19.0.0"
    implementation "com.google.android.gms:play-services-auth:$auth_version"
    //Encrypted Shared Preferences
    def security_version = "1.1.0-alpha03"
    implementation "androidx.security:security-crypto:$security_version"
    //Timber logging
    def timber_version = "4.7.1"
    implementation "com.jakewharton.timber:timber:$timber_version"
    //RecyclerView
    def recyclerview_version = "1.2.0"
    implementation "androidx.recyclerview:recyclerview:$recyclerview_version"
    // Firebase
    implementation platform("com.google.firebase:firebase-bom:27.1.0")
    implementation "com.google.firebase:firebase-analytics-ktx"
    implementation "com.google.firebase:firebase-crashlytics"
    implementation "com.google.firebase:firebase-perf-ktx"
    //ShowCase
    def showcase_version = "1.3.4"
    implementation "com.github.deano2390:MaterialShowcaseView:$showcase_version"
    //Junit5
    androidTestImplementation "androidx.test:runner:1.3.0"
    androidTestImplementation "org.junit.jupiter:junit-jupiter-api:5.7.1"
    androidTestImplementation "de.mannodermaus.junit5:android-test-core:1.0.0"
    androidTestRuntimeOnly "de.mannodermaus.junit5:android-test-runner:1.0.0"
}