Advertisement
Not a member of Pastebin yet?
Sign Up,
it unlocks many cool features!
- pragma solidity ^0.4.18;
- /**
- * @title ERC20Basic
- * @dev Simpler version of ERC20 interface
- * @dev see https://github.com/ethereum/EIPs/issues/179
- */
- contract ERC20Basic {
- uint256 public totalSupply;
- function balanceOf(address who) public view returns (uint256);
- function transfer(address to, uint256 value) public returns (bool);
- event Transfer(address indexed from, address indexed to, uint256 value);
- }
- /**
- * @title Ownable
- * @dev The Ownable contract has an owner address, and provides basic authorization control
- * functions, this simplifies the implementation of "user permissions".
- */
- contract Ownable {
- address public owner;
- event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
- /**
- * @dev The Ownable constructor sets the original `owner` of the contract to the sender
- * account.
- */
- function Ownable() public {
- owner = msg.sender;
- }
- /**
- * @dev Throws if called by any account other than the owner.
- */
- modifier onlyOwner() {
- require(msg.sender == owner);
- _;
- }
- /**
- * @dev Allows the current owner to transfer control of the contract to a newOwner.
- * @param newOwner The address to transfer ownership to.
- */
- function transferOwnership(address newOwner) public onlyOwner {
- require(newOwner != address(0));
- OwnershipTransferred(owner, newOwner);
- owner = newOwner;
- }
- }
- /**
- * @title SafeMath
- * @dev Math operations with safety checks that throw on error
- */
- library SafeMath {
- function mul(uint256 a, uint256 b) internal pure returns (uint256) {
- if (a == 0) {
- return 0;
- }
- uint256 c = a * b;
- assert(c / a == b);
- return c;
- }
- function div(uint256 a, uint256 b) internal pure returns (uint256) {
- // assert(b > 0); // Solidity automatically throws when dividing by 0
- uint256 c = a / b;
- // assert(a == b * c + a % b); // There is no case in which this doesn't hold
- return c;
- }
- function sub(uint256 a, uint256 b) internal pure returns (uint256) {
- assert(b <= a);
- return a - b;
- }
- function add(uint256 a, uint256 b) internal pure returns (uint256) {
- uint256 c = a + b;
- assert(c >= a);
- return c;
- }
- }
- /**
- * @title Crowdsale
- * @dev Crowdsale is a base contract for managing a token crowdsale.
- * Crowdsales have a start and end timestamps, where investors can make
- * token purchases and the crowdsale will assign them tokens based
- * on a token per ETH rate. Funds collected are forwarded to a wallet
- * as they arrive.
- */
- contract Crowdsale {
- using SafeMath for uint256;
- // The token being sold
- MintableToken public token;
- // start and end timestamps where investments are allowed (both inclusive)
- uint256 public startTime;
- uint256 public endTime;
- // address where funds are collected
- address public wallet;
- // how many token units a buyer gets per wei
- uint256 public rate;
- // amount of raised money in wei
- uint256 public weiRaised;
- /**
- * event for token purchase logging
- * @param purchaser who paid for the tokens
- * @param beneficiary who got the tokens
- * @param value weis paid for purchase
- * @param amount amount of tokens purchased
- */
- event TokenPurchase(address indexed purchaser, address indexed beneficiary, uint256 value, uint256 amount);
- function Crowdsale(uint256 _startTime, uint256 _endTime, uint256 _rate, address _wallet) public {
- require(_startTime >= now);
- require(_endTime >= _startTime);
- require(_rate > 0);
- require(_wallet != address(0));
- token = createTokenContract();
- startTime = _startTime;
- endTime = _endTime;
- rate = _rate;
- wallet = _wallet;
- }
- // creates the token to be sold.
- // override this method to have crowdsale of a specific mintable token.
- function createTokenContract() internal returns (MintableToken) {
- return new MintableToken();
- }
- // fallback function can be used to buy tokens
- function () external payable {
- buyTokens(msg.sender);
- }
- // low level token purchase function
- function buyTokens(address beneficiary) public payable {
- require(beneficiary != address(0));
- require(validPurchase());
- uint256 weiAmount = msg.value;
- // calculate token amount to be created
- uint256 tokens = weiAmount.mul(rate);
- // update state
- weiRaised = weiRaised.add(weiAmount);
- token.mint(beneficiary, tokens);
- TokenPurchase(msg.sender, beneficiary, weiAmount, tokens);
- forwardFunds();
- }
- // send ether to the fund collection wallet
- // override to create custom fund forwarding mechanisms
- function forwardFunds() internal {
- wallet.transfer(msg.value);
- }
- // @return true if the transaction can buy tokens
- function validPurchase() internal view returns (bool) {
- bool withinPeriod = now >= startTime && now <= endTime;
- bool nonZeroPurchase = msg.value != 0;
- return withinPeriod && nonZeroPurchase;
- }
- // @return true if crowdsale event has ended
- function hasEnded() public view returns (bool) {
- return now > endTime;
- }
- }
- /**
- * @title CappedCrowdsale
- * @dev Extension of Crowdsale with a max amount of funds raised
- */
- contract CappedCrowdsale is Crowdsale {
- using SafeMath for uint256;
- uint256 public cap;
- function CappedCrowdsale(uint256 _cap) public {
- require(_cap > 0);
- cap = _cap;
- }
- // overriding Crowdsale#validPurchase to add extra cap logic
- // @return true if investors can buy at the moment
- function validPurchase() internal view returns (bool) {
- bool withinCap = weiRaised.add(msg.value) <= cap;
- return super.validPurchase() && withinCap;
- }
- // overriding Crowdsale#hasEnded to add cap logic
- // @return true if crowdsale event has ended
- function hasEnded() public view returns (bool) {
- bool capReached = weiRaised >= cap;
- return super.hasEnded() || capReached;
- }
- }
- /**
- * @title FinalizableCrowdsale
- * @dev Extension of Crowdsale where an owner can do extra work
- * after finishing.
- */
- contract FinalizableCrowdsale is Crowdsale, Ownable {
- using SafeMath for uint256;
- bool public isFinalized = false;
- event Finalized();
- /**
- * @dev Must be called after crowdsale ends, to do some extra finalization
- * work. Calls the contract's finalization function.
- */
- function finalize() onlyOwner public {
- require(!isFinalized);
- require(hasEnded());
- finalization();
- Finalized();
- isFinalized = true;
- }
- /**
- * @dev Can be overridden to add finalization logic. The overriding function
- * should call super.finalization() to ensure the chain of finalization is
- * executed entirely.
- */
- function finalization() internal {
- }
- }
- /**
- * @title RefundVault
- * @dev This contract is used for storing funds while a crowdsale
- * is in progress. Supports refunding the money if crowdsale fails,
- * and forwarding it if crowdsale is successful.
- */
- contract RefundVault is Ownable {
- using SafeMath for uint256;
- enum State { Active, Refunding, Closed }
- mapping (address => uint256) public deposited;
- address public wallet;
- State public state;
- event Closed();
- event RefundsEnabled();
- event Refunded(address indexed beneficiary, uint256 weiAmount);
- function RefundVault(address _wallet) public {
- require(_wallet != address(0));
- wallet = _wallet;
- state = State.Active;
- }
- function deposit(address investor) onlyOwner public payable {
- require(state == State.Active);
- deposited[investor] = deposited[investor].add(msg.value);
- }
- function close() onlyOwner public {
- require(state == State.Active);
- state = State.Closed;
- Closed();
- wallet.transfer(this.balance);
- }
- function enableRefunds() onlyOwner public {
- require(state == State.Active);
- state = State.Refunding;
- RefundsEnabled();
- }
- function refund(address investor) public {
- require(state == State.Refunding);
- uint256 depositedValue = deposited[investor];
- deposited[investor] = 0;
- investor.transfer(depositedValue);
- Refunded(investor, depositedValue);
- }
- }
- /**
- * @title RefundableCrowdsale
- * @dev Extension of Crowdsale contract that adds a funding goal, and
- * the possibility of users getting a refund if goal is not met.
- * Uses a RefundVault as the crowdsale's vault.
- */
- contract RefundableCrowdsale is FinalizableCrowdsale {
- using SafeMath for uint256;
- // minimum amount of funds to be raised in weis
- uint256 public goal;
- // refund vault used to hold funds while crowdsale is running
- RefundVault public vault;
- function RefundableCrowdsale(uint256 _goal) public {
- require(_goal > 0);
- vault = new RefundVault(wallet);
- goal = _goal;
- }
- // We're overriding the fund forwarding from Crowdsale.
- // In addition to sending the funds, we want to call
- // the RefundVault deposit function
- function forwardFunds() internal {
- vault.deposit.value(msg.value)(msg.sender);
- }
- // if crowdsale is unsuccessful, investors can claim refunds here
- function claimRefund() public {
- require(isFinalized);
- require(!goalReached());
- vault.refund(msg.sender);
- }
- // vault finalization task, called when owner calls finalize()
- function finalization() internal {
- if (goalReached()) {
- vault.close();
- } else {
- vault.enableRefunds();
- }
- super.finalization();
- }
- function goalReached() public view returns (bool) {
- return weiRaised >= goal;
- }
- }
- /**
- * @title Basic token
- * @dev Basic version of StandardToken, with no allowances.
- */
- contract BasicToken is ERC20Basic {
- using SafeMath for uint256;
- mapping(address => uint256) balances;
- /**
- * @dev transfer token for a specified address
- * @param _to The address to transfer to.
- * @param _value The amount to be transferred.
- */
- function transfer(address _to, uint256 _value) public returns (bool) {
- require(_to != address(0));
- require(_value <= balances[msg.sender]);
- // SafeMath.sub will throw if there is not enough balance.
- balances[msg.sender] = balances[msg.sender].sub(_value);
- balances[_to] = balances[_to].add(_value);
- Transfer(msg.sender, _to, _value);
- return true;
- }
- /**
- * @dev Gets the balance of the specified address.
- * @param _owner The address to query the the balance of.
- * @return An uint256 representing the amount owned by the passed address.
- */
- function balanceOf(address _owner) public view returns (uint256 balance) {
- return balances[_owner];
- }
- }
- /**
- * @title ERC20 interface
- * @dev see https://github.com/ethereum/EIPs/issues/20
- */
- contract ERC20 is ERC20Basic {
- function allowance(address owner, address spender) public view returns (uint256);
- function transferFrom(address from, address to, uint256 value) public returns (bool);
- function approve(address spender, uint256 value) public returns (bool);
- event Approval(address indexed owner, address indexed spender, uint256 value);
- }
- /**
- * @title Standard ERC20 token
- *
- * @dev Implementation of the basic standard token.
- * @dev https://github.com/ethereum/EIPs/issues/20
- * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
- */
- contract StandardToken is ERC20, BasicToken {
- mapping (address => mapping (address => uint256)) internal allowed;
- /**
- * @dev Transfer tokens from one address to another
- * @param _from address The address which you want to send tokens from
- * @param _to address The address which you want to transfer to
- * @param _value uint256 the amount of tokens to be transferred
- */
- function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
- require(_to != address(0));
- require(_value <= balances[_from]);
- require(_value <= allowed[_from][msg.sender]);
- balances[_from] = balances[_from].sub(_value);
- balances[_to] = balances[_to].add(_value);
- allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
- Transfer(_from, _to, _value);
- return true;
- }
- /**
- * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
- *
- * Beware that changing an allowance with this method brings the risk that someone may use both the old
- * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
- * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
- * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
- * @param _spender The address which will spend the funds.
- * @param _value The amount of tokens to be spent.
- */
- function approve(address _spender, uint256 _value) public returns (bool) {
- allowed[msg.sender][_spender] = _value;
- Approval(msg.sender, _spender, _value);
- return true;
- }
- /**
- * @dev Function to check the amount of tokens that an owner allowed to a spender.
- * @param _owner address The address which owns the funds.
- * @param _spender address The address which will spend the funds.
- * @return A uint256 specifying the amount of tokens still available for the spender.
- */
- function allowance(address _owner, address _spender) public view returns (uint256) {
- return allowed[_owner][_spender];
- }
- /**
- * approve should be called when allowed[_spender] == 0. To increment
- * allowed value is better to use this function to avoid 2 calls (and wait until
- * the first transaction is mined)
- * From MonolithDAO Token.sol
- */
- function increaseApproval(address _spender, uint _addedValue) public returns (bool) {
- allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue);
- Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
- return true;
- }
- function decreaseApproval(address _spender, uint _subtractedValue) public returns (bool) {
- uint oldValue = allowed[msg.sender][_spender];
- if (_subtractedValue > oldValue) {
- allowed[msg.sender][_spender] = 0;
- } else {
- allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
- }
- Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
- return true;
- }
- }
- /**
- * @title Mintable token
- * @dev Simple ERC20 Token example, with mintable token creation
- * @dev Issue: * https://github.com/OpenZeppelin/zeppelin-solidity/issues/120
- * Based on code by TokenMarketNet: https://github.com/TokenMarketNet/ico/blob/master/contracts/MintableToken.sol
- */
- contract MintableToken is StandardToken, Ownable {
- event Mint(address indexed to, uint256 amount);
- event MintFinished();
- bool public mintingFinished = false;
- modifier canMint() {
- require(!mintingFinished);
- _;
- }
- /**
- * @dev Function to mint tokens
- * @param _to The address that will receive the minted tokens.
- * @param _amount The amount of tokens to mint.
- * @return A boolean that indicates if the operation was successful.
- */
- function mint(address _to, uint256 _amount) onlyOwner canMint public returns (bool) {
- totalSupply = totalSupply.add(_amount);
- balances[_to] = balances[_to].add(_amount);
- Mint(_to, _amount);
- Transfer(address(0), _to, _amount);
- return true;
- }
- /**
- * @dev Function to stop minting new tokens.
- * @return True if the operation was successful.
- */
- function finishMinting() onlyOwner canMint public returns (bool) {
- mintingFinished = true;
- MintFinished();
- return true;
- }
- }
- /**
- * @title SampleCrowdsaleToken
- * @dev Very simple ERC20 Token that can be minted.
- * It is meant to be used in a crowdsale contract.
- */
- contract SampleCrowdsaleToken is MintableToken {
- string public constant name = "Sample Crowdsale Token";
- string public constant symbol = "SCT";
- uint8 public constant decimals = 2;
- }
- /**
- * @title SampleCrowdsale
- * @dev This is an example of a fully fledged crowdsale.
- * The way to add new features to a base crowdsale is by multiple inheritance.
- * In this example we are providing following extensions:
- * CappedCrowdsale - sets a max boundary for raised funds
- * RefundableCrowdsale - set a min goal to be reached and returns funds if it's not met
- *
- * After adding multiple features it's good practice to run integration tests
- * to ensure that subcontracts works together as intended.
- */
- contract SampleCrowdsale is CappedCrowdsale, RefundableCrowdsale {
- function SampleCrowdsale(uint256 _startTime, uint256 _endTime, uint256 _rate, uint256 _goal, uint256 _cap, address _wallet) public
- CappedCrowdsale(_cap)
- FinalizableCrowdsale()
- RefundableCrowdsale(_goal)
- Crowdsale(_startTime, _endTime, _rate, _wallet)
- {
- //As goal needs to be met for a successful crowdsale
- //the value needs to less or equal than a cap which is limit for accepted funds
- require(_goal <= _cap);
- }
- function createTokenContract() internal returns (MintableToken) {
- return new SampleCrowdsaleToken();
- }
- }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement