Sistema de Faggio & Destruction Time ~Nyft

#include a_samp
#include streamer

#define function%0(%1) \
    forward%0(%1); public%0(%1)

#define PRESSED(%0) \
    (((newkeys & (%0)) == (%0)) && ((oldkeys & (%0)) != (%0)))


#define PICKUP_FAGGIO_X         125.0640
#define PICKUP_FAGGIO_Y         -83.8021
#define PICKUP_FAGGIO_Z         1.5781

#define SPAWN_FAGGIO_X          125.2240
#define SPAWN_FAGGIO_Y          -88.8164
#define SPAWN_FAGGIO_Z          1.5781
#define SPAWN_FAGGIO_A          270.0000


static
    gVehicleFaggioID[MAX_PLAYERS] = {INVALID_VEHICLE_ID, ...},
    gVehicleFaggioTimer[MAX_PLAYERS] = {-1, ...},
    gVehicleFaggioCount[MAX_PLAYERS];

main(){}

public OnGameModeInit()
{
    CreateDynamicPickup(1318, 1, PICKUP_FAGGIO_X, PICKUP_FAGGIO_Y, PICKUP_FAGGIO_Z, .streamdistance = 50.0);
    CreateDynamic3DTextLabel("{1E90FF}Faggio\n{FFFFFF}Aperte F ou Enter para pegar", -1, PICKUP_FAGGIO_X, PICKUP_FAGGIO_Y, PICKUP_FAGGIO_Z+0.75, 50.0, .testlos = 1);
    return 1;
}

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
    if(PRESSED(KEY_SECONDARY_ATTACK))
    {
        if(IsPlayerInAnyVehicle(playerid))
            return 1;

        if(IsPlayerInRangeOfPoint(playerid, 1.0, PICKUP_FAGGIO_X, PICKUP_FAGGIO_Y, PICKUP_FAGGIO_Z))
        {
            if(gVehicleFaggioID[playerid] != INVALID_VEHICLE_ID)
                return SendClientMessage(playerid, -1, "* Você não pode pegar uma Faggio com outra criada.");

            gVehicleFaggioID[playerid] = CreateVehicle(462, SPAWN_FAGGIO_X, SPAWN_FAGGIO_Y, SPAWN_FAGGIO_Z, SPAWN_FAGGIO_A, -1, -1, -1);
            PutPlayerInVehicle(playerid, gVehicleFaggioID[playerid], 0);
        }
    }
    return 1;
}

public OnPlayerStateChange(playerid, newstate, oldstate)
{
    if(newstate == PLAYER_STATE_DRIVER)
    {
        if(gVehicleFaggioID[playerid] != INVALID_VEHICLE_ID)
        {
            if(gVehicleFaggioCount[playerid] != 0 && gVehicleFaggioTimer[playerid] != -1)
            {
                KillTimer(gVehicleFaggioTimer[playerid]);
                gVehicleFaggioTimer[playerid] = -1;
                gVehicleFaggioCount[playerid] = 0;
            }
        }
    }
    if(oldstate == PLAYER_STATE_DRIVER)
    {
        if(gVehicleFaggioID[playerid] != INVALID_VEHICLE_ID)
        {
            if(!gVehicleFaggioCount[playerid] && gVehicleFaggioTimer[playerid] == -1)
            {
                gVehicleFaggioCount[playerid] = 30;
                gVehicleFaggioTimer[playerid] = SetTimerEx("OnDestroyFaggioUpdate", 1000, true, "i", playerid);
            }
        }
    }
    return 1;
}

function OnDestroyFaggioUpdate(playerid)
{
    if(gVehicleFaggioTimer[playerid] != -1)
    {
        if(!(--gVehicleFaggioCount[playerid]))
        {
            KillTimer(gVehicleFaggioTimer[playerid]);
            gVehicleFaggioTimer[playerid] = -1;
            gVehicleFaggioCount[playerid] = 0;
            DestroyVehicle(gVehicleFaggioID[playerid]);
            gVehicleFaggioID[playerid] = INVALID_VEHICLE_ID;
        }
        else
        {
            new string[32];
            format(string, sizeof(string), "~r~FAGGIO DESTRUIDA EM ~w~%d", gVehicleFaggioCount[playerid]);
            GameTextForPlayer(playerid, string, 1000, 5);
        }
    }
    return 1;
}