Creative Cloud Packager example installation script

@echo off

REM Adobe Creative Cloud Packager example installation script
REM Place this script inside your package directory, alongside the cpp file which defines the package and
REM Run this script with administrative privileges
REM Make certain that Creative Cloud Packager is not running when executing this script
REM For support, please visit https://www.adobe.com/support/
REM if using a transforms file, it should be named AcroPro.mst and located in the same directory as AcroPro.msi

@setlocal enableextensions
@cd /d "%~dp0"


:AcrobatXI
REM to specify the language, use the additional parameter --installLanguage
REM e.g. ExceptionDeployer --workflow=install --mode=pre --installLanguage "fr_FR"
REM otherwise the operating system language will be used

cd Exceptions
IF NOT EXIST "AcrobatProfessional11*" GOTO ACROBATXI_END
 echo Installing Acrobat XI...

 ExceptionDeployer --workflow=install --mode=pre --AcrobatTransforms=AcroPro.mst
:ACROBATXI_END
cd ..


:AcrobatDC
REM to specify the language, use the additional parameter: /sl "%INSTALLLANGUAGE%"
REM e.g. Setup.exe /sAll /extUI /rs /l /sl "fr_FR"
REM otherwise the operating system language will be used

cd Exceptions
IF NOT EXIST "APRO15*" GOTO ACROBATDC_END
 echo Installing Acrobat DC...
 cd APRO15*
 cd "Adobe Acrobat"
 start /wait Setup.exe /sAll /extUI /rs /l
 cd ..\..
:ACROBATDC_END
cd ..


:BUILD
echo Installing license from package and any applications in the "Build" directory
cd Build
for %%f in (*.msi) do set "BUILDMSI=%%f"
start /wait msiexec.exe /i "%BUILDMSI%" /qn /lv* "%TEMP%\%BUILDMSI%.log"
cd ..


:PostExceptions
echo Installing any remaining applications from the "Exceptions" directory
REM Note: Acrobat DC will not be installed by this step, as it is installed earlier on
cd Exceptions
 ExceptionDeployer.exe --workflow=install --mode=post
cd ..

REM uncomment the next line to not close the window after completion in case of any problems
REM pause