//================================================================================================
// File Name  : captains_curse.gsc
// Authors    : ZCTxCHAOSx, Quizz and ConvictioNDR
// Notes	  : Original written by ZCTxCHAOSx and Quizz. Modified and ported into Black Ops 3 by ConvictioNDR.
//================================================================================================
#using scripts\shared\flag_shared;
#using scripts\zm\_zm_score;
#using scripts\shared\util_shared;
#using scripts\zm\_zm_utility;
#using scripts\zm\_zm_audio;

function main()
{
	activation = GetEnt("power_player","targetname");
	thread give_power_to_player(activation);
}
function give_power_to_player(trig)
{
	trig SetCursorHint( "HINT_NOICON" );
	while(1)
	{
		cost = 1500;
		trig sethintstring("Press [{+activate}] to call upon the Captain's Curse ^3[Cost: "+cost+"]");
		trig waittill( "trigger", player );

		if(player.score >= cost)
		{
			zm_utility::play_sound_at_pos( "purchase", player.origin );
			trig sethintstring("Come Back Next Round");
			player zm_score::minus_to_player_score(cost);
			player EnableInvulnerability();
			player SetBlur( 2.0, 1.0 );
			for(i=0;i<30;i++) // lasts 15 seconds
			{
				zombies = GetAiSpeciesArray("axis");
				for(k=0;k<zombies.size;k++)
				{
					if(Distance2D( player.origin, zombies[k].origin ) < 256)
						zombies[k] dodamage( zombies[k].health + 200, zombies[k].origin );
				}
				wait .5;
			}

			player DisableInvulnerability();
			player SetBlur( 0.01, 1.0 );
			level waittill( "between_round_over" );
		}
		else
		{
			player playsound( "evt_perk_deny" );
			player zm_audio::create_and_play_dialog( "general", "outofmoney" );
			wait 1.5;
		}
	}
}