tupplespacepackage-realtupples.ads

pragma Ada_2022;
with Ada.Strings.Unbounded;
private with Ada.Containers.Vectors, Ada.Containers.Hashed_Maps, Ada.Strings.Hash, Ada.Streams.Storage.Unbounded, Ada.Tags, Ada.Finalization;

package tupplespacepackage.RealTupples is

   type MyMapType is limited private;
   protected type RealTuppleSpace is new TuppleSpace with
      overriding procedure Out_Operation (T : Tupple'Class);
      overriding entry In_Operation (Result : out Tupple'Class);
      overriding entry RD_Operation (Result : out Tupple'Class);
      overriding procedure Inp_Operation (Result : out Tupple'Class);
      overriding procedure RDP_Operation (Result : out Tupple'Class);
   private
      The_Map : MyMapType;
   end RealTuppleSpace;

   type Integer_Positive_String_Tupple is new Tupple with record
      I   : Integer;
      Pos : Positive;
      A   : Ada.Strings.Unbounded.Unbounded_String;
   end record;

   type String_String_Tupple is new Tupple with record
      A, B : Ada.Strings.Unbounded.Unbounded_String;
   end record;

  function Encode (I : Integer; Pos : Positive; A : String)
     return Integer_Positive_String_Tupple is (I, Pos, Ada.Strings.Unbounded.To_Unbounded_String (A));
   function Encode (A, B : String) return String_String_Tupple is (Ada.Strings.Unbounded.To_Unbounded_String (A), Ada.Strings.Unbounded.To_Unbounded_String (B));

private

   use Ada.Streams.Storage.Unbounded, Ada.Tags, Ada.Finalization;
    type AccessStream is access Stream_Type;

    type FinalizedType is new Controlled with record
        Stream: not null AccessStream := new Stream_Type;
    end record;
    overriding procedure Finalize (Finale: in out FinalizedType);
    package newQueues is new Ada.Containers.Vectors
     (Positive, FinalizedType);
   subtype Queue is newQueues.Vector;

   function Hash (A : Ada.Tags.Tag) return Ada.Containers.Hash_Type
     is (Ada.Strings.Hash (Ada.Tags.External_Tag (A)));

   protected type LockedQueue is
      procedure Out_Operation (T : Tupple'Class);
      entry In_Operation (Result : out Tupple'Class);
      entry RD_Operation (Result : out Tupple'Class);
   private
      PatternQueue : aliased Queue;
   end LockedQueue;

   type AccessToProtected is access LockedQueue;
   package newMaps is new Ada.Containers.Hashed_Maps
     (Key_Type        => Ada.Tags.Tag,
      Element_Type    => AccessToProtected,
      Hash            => Hash,
      Equivalent_Keys => "=");

   type MyMapType is new newMaps.Map with null record;

end tupplespacepackage.RealTupples;