systemChat "Game Init";

if (!isServer) exitWith {};

private ["_dummy","_dummyClassName","_carrierPartPos"];

_carrierParts = [
    ["OPTRE_engine_left","EngL",0],
    ["OPTRE_engine_right","EngR",0],
    ["OPTRE_tail","Tail",0],
    ["OPTRE_center","Centre",0],
    ["OPTRE_center_nose","NoseCentre",0],
    ["OPTRE_nose","Nose",0],
    ["OPTRE_bridge","bridge",0],
    ["OPTRE_hangar_lift","lift",0],
    ["OPTRE_slipdrive","slipdrive",180],
    ["OPTRE_airlock_door","airlock1",90],
    ["OPTRE_airlock_door","airlock2",90],
    ["OPTRE_Corvette_archer_system","archer1",0],
	["OPTRE_Corvette_archer_system","archer2",180],
	["OPTRE_Corvette_M910_Turret","pointdefense1",180]
];

_shipBase = param [0, objNull];

{deleteVehicle _x; } forEach (_shipBase getVariable ["OPTRE_DrakeParts",[]]);

_shipBasePos = getposATL _shipBase;
_carrierDir = getdir _shipBase;
_carrierPos = getposATL _shipBase;

//private _carrierPitchBank = _shipBase call bis_fnc_getPitchBank;
//_carrierPitchBank params [["_carrierPitch",0],["_carrierBank",0]]; // Does not work due to engines carrier must be flat.

_parts = [];
{
	private ["_crewArray"];

    _dummy = createVehicle [(_x select 0), [0,0,0], [], _carrierDir, "CAN_COLLIDE"];
	_crewArray = [ _dummy ,  (createGroup West) ] call BIS_fnc_spawnCrew;
    _dummy setDir (_carrierDir + (_x select 2));

    _carrierPartPos = _shipBase modelToWorldWorld (_shipBase selectionPosition (_x select 1));
    _dummy setPosWorld _carrierPartPos;

    //[_dummy, _carrierPitch, _carrierBank] call bis_fnc_setPitchBank; // Does not work due to engines carrier must be flat.

    _parts pushBack _dummy;
	if (count _crewArray > 0) then {_parts = _parts + _crewArray;};

} foreach _carrierParts;

for "_i" from 0 to 32 do {
	private ["_memPointName"];
    if (_i < 10) then { // Numbers Bellow 10 need a 0 added to the name.
        _memPointName = format ["Component0%1",_i];
    } else { // Numbers above 9 do not.
        _memPointName = format ["Component%1",_i];
    };

    _dummy = createVehicle ["OPTRE_hallway_door_a", [0,0,0], [], _carrierDir, "CAN_COLLIDE"];
    _dummy setDir _carrierDir;

    _carrierPartPos = _shipBase modelToWorldWorld (_shipBase selectionPosition _memPointName);
    _dummy setPosWorld _carrierPartPos;

    _parts pushBack _dummy;

};

 for "_i" from 0 to 25 do { // call all the 90 doors Door_90d_X 0-X

     _memPointName = format ["Door_90d_%1",_i];

    _dummy = createVehicle ["OPTRE_hallway_door_a", [0,0,0], [], _carrierDir, "CAN_COLLIDE"];
    _dummy setDir (_carrierDir + 90);

    _carrierPartPos = _shipBase modelToWorldWorld (_shipBase selectionPosition _memPointName);
    _dummy setPosWorld _carrierPartPos;

    _parts pushBack _dummy;

};

_shipBase setVariable ["OPTRE_DrakeParts", _parts, true];