Sub Mez
	/if ( ${MezTimer} || ${Me.Casting.ID} || ${Me.XTarget} <= ${MezIfMoreThan} ) /return
	/declare search string local npc los radius ${MezDistance} notid ${PetID}
	/declare i int local 1
	/declare TankTargetId int local 0

	/if ( ${Me.XTarget} > ${MezIfMoreThan} && ${SpawnCount[${search}]} > ${MezIfMoreThan} ) {
		/squelch /target clear
		/delay 5
		/assist ${AssistPlayer}
		/delay 1s
		/varset TankTargetId ${Target.ID}
		/if ( !${TankTargetId} || !${Target.ID} ) {
			/return
		}
		/for i 1 to ${Me.XTarget} {
			/doevents

			|If mob is not mezzable, don't try
			/if ( !${MezImmuneList.Find[${Me.XTarget[${i}].CleanName}]} ) {
				/target id ${Me.XTarget[${i}].ID}
				/delay 1s
				/delay 1s ${Target.ID}&&${Target.BuffsPopulated}
				/if ( ${Target.ID} != ${TankTargetId} && ${Target.ID} != ${Me.Pet.ID} ) {
					/if ( !${Target.Buff[${MezSpellIcon}].ID} && ${Target.LineOfSight} && ${Target.Distance} <= ${MezDistance} ) {
						/call Announce "Mezzing ${Target.CleanName}"
						/casting "${MezSpell}" ${MezSpellGem} -maxtries|3
						/delay ${Spell[${MezSpell}].CastTime.TotalSeconds}s ${Cast.Status.Equal[I]}||${Target.Buff[${MezSpellIcon}].ID}||${Target.ID}==${TankTargetId}
						/if ( ${Me.Casting.ID} && (${Target.Buff[${MezSpellIcon}].ID} || ${Target.ID}==${TankTargetId}) ) /stopcast
						/delay 2s
						/doevents
					}
				}
			}
		}
		/next i
	}
	/varset MezTimer ${MezTimer.OriginalValue}
/return

Sub CharmPet
	/if ( ${Me.Pet.ID} ) {
		/varset PetID ${Me.Pet.ID}
		/call PetAttack
		/if ( ${ShouldBuffPet} ) {
			/if ( !${Me.Pet.Buff[${CharmBuffSpell}]} ) {
				/casting "${CharmBuffSpell}" ${CharmBuffSpellGem} -targetid|${Me.Pet.ID}
				/delay 10s ${Cast.Status.Equal[I]}||!${Me.Pet.ID}
			}
		}
	} else {
		|/echo Pet is NOT charmed, is he alive?
		:SkipPetDebuff
		/if ( ${Spawn[id ${PetID}].ID} && ${SpawnCount[npc radius 150 id ${PetID}]} > 0 ) {
			/target id ${PetID}
			/delay 1s ${Target.ID}
			/delay 1s ${Target.BuffsPopulated}
			/squelch /face fast
			|
			/if ( ${Target.ID}==${PetID} ) {
				/doevents

				/if ( ${ShouldStun} && ${Me.SpellReady[${StunSpell}]} && ${Spawn[id ${PetID}].Distance} < 75 ) {
					/call Announce "Casting ${StunSpell}"
					/casting "${StunSpell}" ${StunSpellGem} -maxtries|3 -targetid|${PetID}
					/delay ${Spell[${StunSpell}].CastTime.TotalSeconds}s ${Cast.Status.Equal[I]}
				}

				/if ( ${ShouldDebuffPet} && !${Target.Buff[${DebuffSpell}].ID} ) {
					/call Announce "Debuffing pet with ${DebuffSpell}"

					/casting "${DebuffSpell}" ${DebuffSpellGem} -maxtries|3 -targetid|${PetID}
					/delay ${Spell[${DebuffSpell}].CastTime.TotalSeconds}s ${Cast.Status.Equal[I]}
				}

				:TryMezAgain
				/if ( ${ShouldTempMez} && !${Target.Buff[${TempMezSpell}].ID} ) {
					/call Announce "Casting ${TempMezSpell}"
					/casting "${TempMezSpell}" ${TempMezSpellGem} -maxtries|3 -targetid|${PetID}
					/delay ${Spell[${TempMezSpell}].CastTime.TotalSeconds}s ${Cast.Status.Equal[I]}
				}
				/if ( ${Cast.Result.Equal[CAST_RESIST]} ) {
					/goto :TryMezAgain
				}

				/if ( ${Me.SpellReady[${CharmSpell}]} ) {
					/call Announce "Charming pet (${CharmSpell})"
					/casting "${CharmSpell}" ${CharmSpellGem} -maxtries|1 -targetid|${PetID}
					/delay ${Spell[${CharmSpell}].CastTime.TotalSeconds}s ${Cast.Status.Equal[I]}||!${Target.ID}
				}


				/if ( !${Me.Pet.ID} ) {
					/delay 5
					/goto :SkipPetDebuff
				}
			}
		}
	}
/return