-	script	InstanceBossKilled	-1,{
	end;

OnNPCKillEvent:
	getmapxy(.@map1$, .@x1, .@y1, UNITTYPE_PC, strcharinfo(0));
	switch(killedrid) {
	default: end;
	//=========================================================
	//=                        Hourly                         =
	//=========================================================
	case 2131: // Wandering Purple Dragon - Hazy Forest
		.@map_name$ = instance_mapname("1@mist");
		.@reward = 2;
		break;

	case 1087: // Orc Hero - Orc Memory
		.@map_name$ = instance_mapname("2@orcs");
		.@reward = 2;
		break;

	case 2194: // Giant Octopus - Octopus Cave
		.@map_name$ = instance_mapname("1@cash");
		.@reward = 3;
		break;

	// Malangdo Culvert
	case 2187: // Dark Coelacanth
	case 2188: // Weird Coelacanth
	case 2189: // Mutant Coelacanths
	case 2190: // Violent Coelacanths
		.@map_name$ = instance_mapname("2@pump");
		.@reward = 1;
		break;

	case 1929: // Unsealed Baphomet - Sealed Shrine
		.@map_name$ = instance_mapname("2@cata");
		.@reward = 12;
		break;

	//=========================================================
	//=                         Daily                         =
	//=========================================================
	case 2319: // Buwaya - Buwaya's Cave
		.@map_name$ = instance_mapname("1@ma_c");
		.@reward = 23;
		break;

	//case : // Central Laboratory - 3 Boss
	//case 3124: // Charleston 3 - Central Laboratory
	//case 2942: // Evil Fanatic - Devil's Tower

	case 2529: // Faceworm Queen - Faceworm Nest
		.@map_name$ = instance_mapname("1@face");
		.@reward = 23;
		break;

	//case 2564: // Fenris Fenrir - Geffen Magic Tournament

	case 2959: // Torturous Redeemer - Ghost Palace
		.@map_name$ = instance_mapname("1@spa");
		.@reward = 23;
		break;

	case 2996: // Celine Kimi - Horror Toy Factory - 1@xm_d
		.@map_name$ = instance_mapname("1@xm_d");
		.@reward = 23;
		break;

	case 3029: // Reaper Yanku - Isle of Bios
		.@map_name$ = instance_mapname("1@dth3");
		.@reward = 23;
		break;

	case 3254: // T_W_O - The Last Room
		.@map_name$ = instance_mapname("1@uns");
		.@reward = 23;
		break;

	//case : //  - Morse's Cave
	//case 3073: // Awakened Ferre - Nightmarish Jitterbug

	// Old Glast Heim
	case 2475: // Corruption Root
		.@map_name$ = instance_mapname("1@gl_k");
		.@reward = 23;
		break;
	case 2476: // Amdarais
		.@map_name$ = instance_mapname("2@gl_k");
		.@reward = 23;
		break;

	case 2542: // Doyen Irene - Sara's Memory - 1@sara
		.@map_name$ = instance_mapname("1@sara");
		.@reward = 20;
		break;

	//case 3097: // Morocc The Desperate God - Temple of Demon God
	// case  : // Wave Mode

	case 3450: // Bijou - Room of Consciousness - 1@mir
		.@map_name$ = instance_mapname("1@mir");
		.@reward = 23;
		break;

	//case 3628: // Heart Hunter Ebel - Heart Hunter War Base 2
	//case 3621: // Pet Child - Werner Laboratory Central Room

	//=========================================================
	//=                         3 Days                        =
	//=========================================================
	case 2022: // Nidhoggur's Shadow - Nidhoggur's Nest
		.@map_name$ = instance_mapname("2@nyd");
		.@reward = 3*24;
		break;

	// case : // 2-1 & 2-2 Biolab MVPs - Wolfchev's Laboratory
	// case : // Sky Fortress

	//=========================================================
	//=                         Weekly                        =
	//=========================================================
	case 2322: // Bakonawa - Bakonawa Extermination
		.@map_name$ = instance_mapname("1@ma_b");
		.@reward = 7*24;
		break;

	case 2317: // Bangungot - Bangungot's Instance
		.@map_name$ = instance_mapname("1@ma_h");
		.@reward = 7*24;
		break;

	// case : // Endless Tower

	case 3190: // Sarah Irene - Sarah and Fenrir
		.@map_name$ = instance_mapname("1@glast");
		.@reward = 7*24;
		break;

	}
	// Check if is instance map
	if (.@map_name$ == "" || .@map1$ != .@map_name$) {
		end;
	}
	if ((.@party_id = getcharid(1))) {
		getpartymember .@party_id,0;
		getpartymember .@party_id,1;
		getpartymember .@party_id,2;
		for (.@i = 0; .@i < $@partymembercount; .@i++) {
			if (isloggedin($@partymemberaid[.@i], $@partymembercid[.@i])) {
				getmapxy(.@map2$, .@x2, .@y2, UNITTYPE_PC, $@partymembername$[.@i]);
				if (.@map1$ == .@map2$)
					getitem 33012, .@reward, $@partymemberaid[.@i];
			}
		}
	} else {
		getitem 33012, .@reward;
	}
	end;

}