farum bajada ftp

======================================================
Se trata de bajar y subir los ficheros al ftp de farum
======================================================
- subimos ficheros de pedidos

En los bajados hacemos:
- logs errores fichero de pedidos avisar por email a la gente de compras y pasarlos a históricos y a su carpeta compras para que los vean cuando quieran
- facturas avisamos que hay nuevas, y guardamos en sus carpetas correspondientes
- acuerdos avisamos que hay nuevos, y guardamos en sus carpetas correspondientes

=============================================================================================
Primero lo más facil que es el fichero que ejecuta el ftp, en mi caso se llama ftp_farum_conf:
==============================================================================================
Se irá creando ficheros "semaforo" si hay nuevos ficheros facturas o de acuerdos para luego saber que hacer


usuario
contraseña
cd /SUBIDA
pwd
binary
prompt
lcd carpeta_subida
mput *.txt
cd /BAJADA
lcd carpeta_bajada
mget *.txt
mdelete *.txt
cd /FACTURAS/ALT
mget *.*
mdelete *.*
!if exist FA*.pdf echo "facturas nuevas en carpeta farum ALT">>farum_nuevas_facturas.txt
!if exist FA*.pdf copy /y FA*.pdf carpeta_facturas_proveedores\farum\ALT
!if exist FA*.pdf del /q FA*.pdf
cd /FACTURAS/MRK
mget *.*
mdelete *.*
!if exist FA*.pdf echo "facturas nuevas en carpeta farum MRK">>farum_nuevas_facturas.txt
!if exist FA*.pdf copy /y FA*.pdf carpeta_facturas_proveedores\farum\MRK
!if exist FA*.pdf del /q FA*.pdf
cd /FACTURAS/MSD
mget *.*
mdelete *.*
!if exist FA*.pdf echo "facturas nuevas en carpeta farum MSD">>farum_nuevas_facturas.txt
!if exist FA*.pdf copy /y FA*.pdf carpeta_facturas_proveedores\farum\MSD
!if exist FA*.pdf del /q FA*.pdf
cd /FACTURAS/NND
mget *.*
mdelete *.*
!if exist FA*.pdf echo "facturas nuevas en carpeta farum NND">>farum_nuevas_facturas.txt
!if exist FA*.pdf copy /y FA*.pdf carpeta_facturas_proveedores\farum\NND
!if exist FA*.pdf del /q FA*.pdf
cd /FACTURAS/SNF
mget *.*
mdelete *.*
!if exist FA*.pdf echo "facturas nuevas en carpeta farum SNF">>farum_nuevas_facturas.txt
!if exist FA*.pdf copy /y FA*.pdf carpeta_facturas_proveedores\farum\SNF
!if exist FA*.pdf del /q FA*.pdf
cd /DOCUMENTACION/ACUERDOS
rem mget *.*
rem mdelete *.*
!if exist cf*.pdf echo "acuerdos nuevos en la intranet">>farum_nuevos_acuerdos.txt
!if exist cf*.pdf copy /y cf*.pdf carpeta_facturas_proveedores\farum\ACUERDOS
!if exist cf*.pdf del /q cf*.pdf
bye



======================================================================================
Y ahora el batch que se ejecuta en el servidor cada x minutos que lanza el ftp anterior
=======================================================================================


rem  FARUMPLUS.   SUBIMOS Y BAJAMOS FICHEROS
::
:FARUM
cd e:\v\pedidos_por_ftp
:: borramos primero ficheros semaforo anteriores
if exist carpeta_bajada\farum_nuevas_facturas.txt del /q carpeta_bajada\farum_nuevas_facturas.txt
if exist carpeta_bajada\farum_nuevos_acuerdos.txt del /q carpeta_bajada\farum_nuevos_acuerdos.txt
::
:: conexion ftp en el que subimos ficheros y bajamos todo facturas y acuerdos
:FTP
rem if not exist carpeta_subida\*.txt goto OKS
if exist carpeta_subida\*.txt echo FARUM empezamos a subir fichero %date% %time%>>"carpeta_log\ftp_central_log.txt"
ftp -s:carpeta_ftp\ftp_farum_conf2.txt ftp.eldefarum.org
if exist carpeta_subida\*.txt echo FARUM terminamos de subir ficheros %date% %time%>>"carpeta_log\ftp_central_log.txt"
::
:: movemos a histórico los pedidos subidos
if exist carpeta_subida\*.txt copy /y carpeta_subida\*.txt carpeta_subida\his\*.*
if exist carpeta_subida\*.txt del /q carpeta_subida\*.txt
::
:OKS
:: FARUMPLUS ahora tratamos los ficheros de bajada
rem if not exist carpeta_bajada\*.txt goto FIN
::
:: los correctos a historico del principal y de la intranet
if exist carpeta_bajada\ST_0*.txt copy /y carpeta_bajada\ST_0*.txt carpeta_bajada\his\*.*
if exist carpeta_bajada\ST_0*.txt copy /y carpeta_bajada\ST_0*.txt carpeta_compras
if exist carpeta_bajada\ST_0*.txt del /q carpeta_bajada\ST_0*.txt
::
:ERRORES
:: los incorrectos aviso por email esperando 7 segundos por cada envio
for %%l in (carpeta_bajada\ST_1*.txt) do (
	start carpeta_bajada\mandaemail.exe "Pedido a FARUM incorrecto no procesado_mirar adjunto" "lou@za.com,rub@za.com,nat@za.com,jul@za.com" "no" %%l
	ping -n 7 127.0.0.1 >nul
)
:: Y los paso a his
if exist carpeta_bajada\ST_1*.txt copy /y carpeta_bajada\ST_1*.txt carpeta_bajada\his\*.*
if exist carpeta_bajada\ST_1*.txt del /q carpeta_bajada\ST_1*.txt
::
:FACTURAS
:: FARUMPLUS nuevas facturas aviso por email
if exist carpeta_bajada\farum_nuevas_facturas.txt start carpeta_bajada\mandaemail.exe "FARUM ha enviado nuevas facturas_Revisa adjunto" "teo@za.com,lau@za.com,jes@za.com,jul@za.com" "no" carpeta_bajada\farum_nuevas_facturas.txt
::
:ACUERDOS
:: FARUMPLUS nuevos acuerdos aviso por email
if exist carpeta_bajada\farum_nuevos_acuerdos.txt start carpeta_bajada\mandaemail.exe "FARUM han llegado nuevos acuerdos con los laboratorios_Revisa intranet" "lou@za.com,nat@za.com,rub@za.com,jul@za.com" "no"
:FIN