SysInfoFind

@echo off
if %os%==Windows_NT goto WINNT
goto NOCON

:WINNT
echo SysInfoFind - Version 1.0 - Teckademics
echo.
echo.

REM set variables
set system=
set manufacturer=
set model=
set serialnumber=
set productnumber=
set MACAD=
set osname=
set cpun=
set username=
set domain=
set sp=
setlocal ENABLEDELAYEDEXPANSION
set "volume=C:"
set totalMem=
set availableMem=
set usedMem=

echo Gathering data for %computername%...

REM Get Computer Name
FOR /F "tokens=2 delims='='" %%A in ('wmic OS Get csname /value') do SET system=%%A

REM Get Computer Manufacturer
FOR /F "tokens=2 delims='='" %%A in ('wmic ComputerSystem Get Manufacturer /value') do SET manufacturer=%%A

REM Get Computer Model
FOR /F "tokens=2 delims='='" %%A in ('wmic ComputerSystem Get Model /value') do SET model=%%A

REM Get CPU Info
FOR /F "tokens=2 delims='='" %%A in ('wmic CPU get Name /value') do SET cpun=%%A

REM Get Username
FOR /F "tokens=2 delims='='" %%A in ('wmic computersystem get Username /value') do SET username=%%A

REM Get Domain
FOR /F "tokens=2 delims='='" %%A in ('wmic computersystem get domain /value') do SET domain=%%A

REM Get Computer Serial Number
FOR /F "tokens=2 delims='='" %%A in ('wmic Bios Get SerialNumber /value') do SET serialnumber=%%A

REM Get Product Number
FOR /F "tokens=2 delims='='" %%A in ('wmic /namespace:\\root\wmi path MS_SystemInformation get SystemSKU /value') do SET productnumber=%%A

REM Get Computer OS
FOR /F "tokens=2 delims='='" %%A in ('wmic os get Name /value') do SET osname=%%A
FOR /F "tokens=1 delims='|'" %%A in ("%osname%") do SET osname=%%A

REM Get Computer OS SP
FOR /F "tokens=2 delims='='" %%A in ('wmic os get ServicePackMajorVersion /value') do SET sp=%%A

REM Get Memory
FOR /F "tokens=4" %%a in ('systeminfo ^| findstr Physical') do if defined totalMem (set availableMem=%%a) else (set totalMem=%%a)
set totalMem=%totalMem:,=%
set availableMem=%availableMem:,=%
set /a usedMem=totalMem-availableMem

FOR /f "tokens=1*delims=:" %%i IN ('fsutil volume diskfree %volume%') DO (
    SET "diskfree=!disktotal!"
    SET "disktotal=!diskavail!"
    SET "diskavail=%%j"
)
FOR /f "tokens=1,2" %%i IN ("%disktotal% %diskavail%") DO SET "disktotal=%%i"& SET "diskavail=%%j"

echo.
echo.
echo.
echo Information for %system%
echo Info saved as %system%_Info.txt
echo.
echo _____________________
echo Manufacturer: %manufacturer%
echo Model: %model%
echo Serial Number: %serialnumber%
echo Product Number: %productnumber%
echo.
echo _____________________
echo Operating System: %osname%
echo Architecture: %processor_architecture%
echo Service Pack: %sp%
echo Username: %username%
echo Domain: %domain%
echo.
echo _____________________
echo CPU Model: %CPUN%
echo Harddrive Total: %disktotal:~0,-9% GB
echo Harddrive Available: %diskavail:~0,-9% GB
echo RAM Total: %totalMem%
echo RAM Available: %usedMem%
echo.

REM Generate file
SET file="%~dp0%computername%_Info.txt"
echo __________________________________________________________ >> %file%
echo. >> %file%
echo. >> %file%
echo System Name: %system% >> %file%
echo. >> %file%
echo ______________________________ >> %file%
echo Manufacturer: %manufacturer% >> %file%
echo Model: %model% >> %file%
echo Serial Number: %serialnumber% >> %file%
echo Product Number: %productnumber% >> %file%
echo. >> %file%
echo ______________________________ >> %file%
echo Operating System: %osname% >> %file%
echo Architecture: %processor_architecture% >> %file%
echo Service Pack: %sp% >> %file%
echo Username: %username% >> %file%
echo Domain: %domain% >> %file%
echo. >> %file%
echo ______________________________ >> %file%
echo CPU Model: %CPUN% >> %file%
echo Harddrive Total: %disktotal:~0,-9% GB >> %file%
echo Harddrive Available: %diskavail:~0,-9% GB >> %file%
echo RAM Total: %totalMem% >> %file%
echo RAM Available: %usedMem% >> %file%
echo. >> %file%
echo. >> %file%
echo __________________________________________________________ >> %file%
goto choice2

:choice2
echo ______________________________
Echo View Network Information?
set /P c=Y/N?...
if /I "%c%" EQU "N" goto :exit
if /I "%c%" EQU "Y" goto :ipinfo

:ipinfo
echo.
echo ______________________________
echo Additional Network Information for %computername%
echo.
ipconfig /all
ipconfig /all > %computername%_Network.txt
echo.
echo.
echo Info saved as %computername%_Network.txt
echo ______________________________
pause

:exit
exit

goto END

:NOCON
echo Error...Invalid Operating System...
echo Error...No actions were made...
goto END

:END