Chuyển chữ tiếng Việt sang tiếq Việt

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=C:\Program Files (x86)\AutoIt3\Icons\MyAutoIt3_Red.ico
#AutoIt3Wrapper_Res_Description=Chuyển chữ tiếng Việt sang tiếq Việt
#AutoIt3Wrapper_Res_LegalCopyright=LYO
#AutoIt3Wrapper_Run_Tidy=y
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/sf /sv
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiButton.au3>
#include <EditConstants.au3>

Global $Word = ["C", "K", _
        "X", "S", _
        "Q", "K", _
        "Nh", "N'", _
        "Tr", "C", _
        "Gi", "Z", _
        "Gh", "G", _
        "Ph", "F", _
        "Ng", "Q", _
        "Ngh", "Q", _
        "Kh", "X", _
        "Th", "W", _
        "D", "Z", _
        "R", "Z", _
        "Đ", "D"]

Global $GUI = GUICreate("Chuyển chữ tiếng Việt sang tiếq Việt",655,677,-1,-1,-1,-1)
Global $Text_Input = GUICtrlCreateEdit("",10,8,636,293,BitOr($ES_WANTRETURN,$WS_VSCROLL),-1)
GUICtrlSetFont(-1,11,400,0,"Arial")
Global $Text_Output = GUICtrlCreateEdit("",10,340,636,293,BitOr($ES_WANTRETURN,$WS_VSCROLL),-1)
GUICtrlSetFont(-1,11,400,0,"Arial")
Global $Convert = GUICtrlCreateButton("Chuyển",330,305,283,30,-1,-1)
GUICtrlSetFont(-1,11,400,0,"Arial")
Global $Status = GUICtrlCreateLabel("Trạng thái:",10,644,289,20,-1,-1)
GUICtrlSetFont(-1,11,400,0,"Arial")
GUICtrlSetBkColor(-1,"-2")
Global $Copy = GUICtrlCreateButton("Sao chép",324,640,289,30,-1,-1)
GUICtrlSetFont(-1,11,400,0,"Arial")
Global $Checkbox_Auto = GUICtrlCreateCheckbox("Tự động Sao chép khi nhấn Chuyển",51,309,253,20,-1,-1)
GUICtrlSetFont(-1,11,400,0,"Arial")
GUISetState(@SW_SHOW, $GUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Convert
            _Convert()
            If _IsChecked($Checkbox_Auto) Then ClipPut(GUICtrlRead($Text_Output))
        Case $Copy
            ClipPut(GUICtrlRead($Text_Output))
    EndSwitch
WEnd

Func _IsChecked(Const $iControlID)
    Return BitAND(GUICtrlRead($iControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked

Func _Convert()
    GUICtrlSetData($Status, "Trạng thái: Đang chuyển...")
    $Get_Input = GUICtrlRead($Text_Input)

    ; Chuyển Ch riêng để bỏ tình trạng nhầm lẫn
    $Get_Input = StringReplace($Get_Input, "Ch", "~[+-]", 0, 1)
    $Get_Input = StringReplace($Get_Input, "CH", "~[++]", 0, 1)
    $Get_Input = StringReplace($Get_Input, "ch", "~[--]", 0, 1)

    ; Chuyển đổi những chữ còn lại
    For $i = 0 To UBound($Word) - 2 Step 2
        $Get_Input = StringReplace($Get_Input, $Word[$i], $Word[$i + 1], 0, 1)
        $Get_Input = StringReplace($Get_Input, StringLower($Word[$i]), StringLower($Word[$i + 1]), 0, 1)
        $Get_Input = StringReplace($Get_Input, StringUpper($Word[$i]), StringUpper($Word[$i + 1]), 0, 1)
    Next

    ; Trả Ch về về giá trị đúng
    $Get_Input = StringReplace($Get_Input, "~[+-]", "C", 0, 1)
    $Get_Input = StringReplace($Get_Input, "~[++]", "C", 0, 1)
    $Get_Input = StringReplace($Get_Input, "~[--]", "c", 0, 1)
    GUICtrlSetData($Text_Output, $Get_Input)
    GUICtrlSetData($Status, "Trạng thái: Đã xong!")
EndFunc   ;==>_Convert