rem == LKMS3.0 - Kepmeret Szamolo v3.0 feat. TotalCommander & IrfanView, 2010.01.29. ==

@echo off

set iview="c:\Program Files (x86)\IrfanView\i_view32.exe"
set find=c:\Windows\System32\find.exe

set kepinfo1=%~dp1\info1.txt
set kepinfo2=%~dp2\info2.txt

set szel=500

rem == a kepinfok lekerese ==
%iview% %1 /info info1.txt
%iview% %2 /info info2.txt

rem == a kepmeretek kideritese ==
for /f "tokens=4,6" %%a in ('type %kepinfo1% ^| %find% /i "dimensions"')do (set /a w1=%%a) & (set /a h1=%%b)
for /f "tokens=4,6" %%a in ('type %kepinfo2% ^| %find% /i "dimensions"')do (set /a w2=%%a) & (set /a h2=%%b)

rem == a meret szamolasa ==
set /a f=((h1+h2)*10)/2

set /a a1=(w1*10000)/h1
set /a a2=(w2*10000)/h2

set /a fa1=f*a1
set /a fa2=f*a2

set /a fas=fa1+fa2
set /a sa=(szel*1000000)/(fas/1000)

set /a finw1=(fa1/1000)*sa
set /a finw2=(fa2/1000)*sa

set /a finh=((finw1/a1)+(finw2/a2))/200

set /a finw1=finw1/1000000
set /a finw2=finw2/1000000

rem == az atnevezeshez kell ==
set newfilename1=%~dp1%~n1_s2%~x1
set newfilename2=%~dp2%~n2_s2%~x2

rem == az iview.exe paraméterei ==
set resize1=/resize=(0,%finh%) /aspectratio /resample /jpgq=92 /convert=%newfilename1%
set resize2=/resize=(0,%finh%) /aspectratio /resample /jpgq=92 /convert=%newfilename2%

rem == a végső parameteres parancs ==
%iview% %~f1 %resize1%
%iview% %~f2 %resize2%

del info1.txt info2.txt