burgle

#burgle
#
# written by Hanryu
# Please report any bugs to Hanryu#0052 (Discord) or [email protected]
# Initial script burgled from Jalika
# Some bits stolen from Reveler's Burgle Script, v.1.0, 02/15/2020
# This script is designed to use Oulander, http://outlanderapp.com
# 2020-02-15
#    Cleaned up for release to Prime
# 2020-02-18
#    Search while hidden in first room, not in second
#    Added check to look for guards after you move to second room
# 2020-02-27
#    Significant rewrite, will now skip the bedroom.
# 2020-02-28
#    Got busted in a linear on a bad move because of bad boundary conditions added a bunch of \b's
#    risking changing `move` to `put`
# 2020-02-29
#    now targeting anything BUT the Kitchen
#    Added walk sub to move rooms
# 2020-03-11
#    Added variable override for locks v. althletics
# 2020-05-21
#    Noticed I had a bad trigger for logging data, fixt
#    Added trigger for failed searches to be logged also
# 2020-06-24
#    Added some to the log trigger, missed arrows/bolts/stones/leathers/plate etc prior to this
# 2020-08-04
#   Global var control of number of rooms hit
#   This is because my internet sucks sometimes and I am getting caught
# 2020-09-14
#   changing to focus on Athletics
# 2020-11-02
#   Modifications for eddy
# 2021-03-24
#   Comment out blend since I capped stealth
# 2021-04-26
#   Failed burgles now send text alerts
# 2021-09-25
#   add athletics check since since I capped
# 2021-11-15
#   fixed it so I stop keeping vOILe
# 2021-11-19
#   searching for a good cowbell
# 2021-12-09
#   O2 conversion
# 2022-01-30
#   found a rosewood one!
# 2022-09-14
#   Can I make this target just the armory for blunt ammo?
#   fixing help
#   preferring rope
# 2022-11-20
#   rel blend logic
# 2022-12-16
#   started stowing again, why not?
#debug 5

# put #log >SCRIPTCHECK.txt WATCH THIS BURGLE!
# waitfor A good positive attitude

## use me if you don't need input
if matchre("%0", "help|HELP|Help") then {goto help}

if matchre("%0", "(\d)? ?rooms? ?(\d)?") then {
  put #var BurgleRooms $1
  delay 0.2
  put #echo >user #990000 >BURGLE: Number of rooms to $BurgleRooms
  exit
  }

#### LOAD VARIABLES ####
eval Scriptname titlecase(%scriptname)
eval SCRIPTNAME tocaps(%scriptname)
timer start
var Kill 0
if ($Athletics.LearningRate <= $Locksmithing.LearningRate) then {
  var EntryMethod Athletics
  } else {
  var EntryMethod Locksmithing
  }
if matchre("%0", "(locks|ath)") then {
  var EntryMethod $1
  if matchre("%EntryMethod", "locks") then {var EntryMethod Locksmithing}
  if matchre("%EntryMethod", "ath") then {var EntryMethod Athletics}
  if ($Athletics.LearningRate > 17) then {var EntryMethod Locksmithing}
  if ($Locksmithing.LearningRate > 17) then {var EntryMethod Athletics}
  }
var guard 0
var surface counter
var direction
var otherDirection
var Reverse northeast-southwest northwest-southeast southeast-northwest southwest-northeast east-west west-east north-south south-north
var validDirections out|northeast|northwest|southeast|southwest|east|west|north|south|in
var PathBack
var MoveCounter 0
var zoneid $zoneid
var roomid $roomid
put #var BurgleFailed False
var ArmorySearch False
if matchre("%0", "(armory|ammo)") then {
  var ArmorySearch True
  var EntryMethod Athletics
  }

#### LOAD ACTIONS ####
action put #log >BurgledItems-$charactername.csv $date,$time,%zoneid%roomid,%surface,FAIL when "^You rummage around .+, but find nothing that looks valuable\.$"
action put #log >BurgledItems-$charactername.csv $date,$time,%zoneid%roomid,%surface,$1 when "until you find (?:some|an?) (.*)\.  It looks valuable, so you decide to take it\.$"
action goto fail when "^A scream shocks you, as the owner discovers you ransacking their home\.  You flee, the owner's calls for help following you outside\.$|^Your lack of stealth gives away your criminal intent, attracting the attention of local law enforcement\."
action var guard 1 when "^Footsteps nearby make you wonder if you\'re pushing your luck\."
action var surface counter when "^\[Someone Else's Home, Kitchen\]$"
action var surface bed when "^\[Someone Else's Home, Bedroom\]$"
action var surface table when "^\[Someone Else's Home, Work Room\]$"
action var surface desk when "^\[Someone Else's Home, Sanctum\]$"
action var surface rack when "^\[Someone Else's Home, Armory\]$"
action var surface bookshelf when "^\[Someone Else's Home, Library\]$"

#### ABORTS and PREP ####
if ($BurgleTime > $gametime) then {goto end}
put set roomname
waitfor Ok.
if ("$righthand" != "Empty") then {gosub stow right}
if ("$lefthand" != "Empty") then {gosub stow left}

top:
  if ($roundtime > 0) then {pause $pauseTime}
  if (($webbed) || ($stunned)) then {pause 0.1}
  matchre top ^\.\.\.wait|^Sorry,|^You are still stun|^You can't do that while entangled
  matchre NotYet ^You should wait at least (.+) roisaen for the heat to die down\.
  matchre GetReady ^The heat has died down from your last caper\.
  put burgle recall
  matchwait

GetReady:
  if ("$charactername" = "Hanryu") then {gosub call blend snap}

ChooseEntryMethod:
  put #echo >User #FF00FF >BURGLE: Using %EntryMethod
  goto %EntryMethod
error:
help:
  put #printbox .burgle Athletics/Locksmithing|  will specify the method but override if exp dictates|.burgle #|  will set the number of rooms to burgle and exit|.burgle ammo|  will bum rush the armory then flee
  exit

Athletics:
  gosub get my heavy rope
  goto burgle

Locksmithing:
  gosub get my $lockpickStacker
  gosub wear my $lockpickStacker
  goto burgle
burgle:
  if ((!$hidden) || (!$invisible)) then {gosub hide}
  if (!$standing) then {gosub stand}
  gosub hide
  if ($roundtime > 0) then {pause $pauseTime}
  matchre burgle \.\.\.wait|^Sorry,
  match badLoc You don't see any likely marks in the area
  match InHouse Obvious exits:
  put hide;burgle
  matchwait

InHouse:
  if ("$righthand" != "Empty") then {gosub stow right}
  if ("$lefthand" != "Empty") then {gosub stow left}
  if ((%guard) || ($BurgleRooms < 1)) then {goto leave}
  if (%ArmorySearch = True) then {goto ArmorySearch}
  if ($BurgleRooms = 1) then {
    gosub search
    goto leave
    }
ArmorySearch:
  if ($hidden) then {send shiver}
  if contains("$roomexits", ",") then {goto Branched}
  else {goto Linear}

# Set to search the bedroom and the OTHER room
Branched:
  if matchre("$roomexits", "\b(%validDirections)\b, \b(%validDirections)\b\.") then {
    var direction $1
    var otherDirection $2
    gosub walk %direction
    if matchre("%Reverse", "\b%direction-(\w+)") then {var PathBack $1|}
    if (%guard) then {goto BackToKitchen}
    if (!(%ArmorySearch) || matchre("%surface", "rack")) then {gosub search}
    gosub walk %PathBack[%MoveCounter]
    if (%guard) then {goto leave}
    gosub walk %otherDirection
    if matchre("%Reverse", "\b%otherDirection-(\w+)") then {var PathBack $1|}
    if (%guard) then {goto BackToKitchen}
    if (!(%ArmorySearch) || matchre("%surface", "rack")) then {gosub search}
    goto BackToKitchen
  }

Linear:
  if matchre("$roomexits", "\b(%validDirections)\b") then {
    var direction $1
    gosub walk %direction
    if matchre("%Reverse", "\b%direction-(\w+)") then {var PathBack $1|}
    eval validDirections replacere("%validDirections", "\b%PathBack[0]\|", "")
    if (%guard) then {goto BackToKitchen}
    if (!(%ArmorySearch) || matchre("%surface", "rack")) then {gosub search}
    if (%guard) then {goto BackToKitchen}
    }
  if matchre("$roomexits", "\b(%validDirections)\b") then {
    var direction $1
    gosub walk %direction
    if matchre("%Reverse", "\b%direction-(\w+)") then {var PathBack %PathBack$1}
    math MoveCounter add 1
    if (%guard) then {goto BackToKitchen}
    if (!(%ArmorySearch) || matchre("%surface", "rack")) then {gosub search}
    }

BackToKitchen:
  gosub walk %PathBack[%MoveCounter]
  math MoveCounter subtract 1
  if (%MoveCounter >= 0) then {goto BackToKitchen}

leave:
  match done You take a moment to reflect on the caper you just pulled as you
  put go window
  matchwait 3
  if matchre("$roomobjs", "kitchen window") then {goto leave}
  else {goto BackToKitchen}

fail:
  put #log >SCRIPTCHECK.txt Failed burgling!
stunned:
  if ($stunned) then {
    eval mytimeout $gametimeupdate + 60
    waiteval ($gametimeupdate > %mytimeout) || (!$stunned)
    goto stunned
    }
  put #var BurgleFailed True

done:
  gosub FoundLoot
  put #eval BurgleTime $gametime + 1810
badLoc:
  if ("$righthand" = "rope") then {gosub stow my rope}
  if ($BurgleLoot!=) then {put #echo >talk #990000 $BurgleLoot}
  put set !roomname
  waitfor Ok.
  if ("$righthand" != "Empty") then {gosub stow right}
  if ("$lefthand" != "Empty") then {gosub stow left}
  if ("$BurgleFailed" = "True") then {gosub call exit}
  if ($SpellTimer.Blend.active) then {gosub release blend}
  timer stop
  eval seconds round(%t) % 60
  if (%seconds < 10) then {var seconds 0%seconds}
  eval minutes %t / 60
  eval minutes floor(%minutes)
  put #echo >User #FF00FF <%SCRIPTNAME: %minutes:%seconds
end:
  put #parse ** BURGLE DONE **
  exit

NotYet:
  put #printbox You have not let the heat die down!
  goto end

#### COMMON SUBROUTINES ####
include commonINC

search:
research:
  put #echo >talk BURGLE: searching: %surface
  if ($roundtime > 0) then {pause $pauseTime}
  matchre research \.\.\.wait|^Sorry,|I could not find what you were referring to\.
  match return Roundtime
  put search %surface
  matchwait 7
  put #echo #FF6600 DEBUG: search timed out
  put #echo >talk #FF6600 [$time]DEBUG: search timed out
  return

FoundLoot:
  if ("$righthand" = "Empty") then {goto checkLeftHand}
  gosub portal
  var temp $righthand
  if matchre("%temp","([\w-']+) \w+( \w+)") then {var temp $1$2}
  put #echo >talk #FF0000 BURGLE:     found: $righthand
  put #var BurgleLoot $BurgleLoot|%temp
  if matchre("%temp","memory orb|keepsake box|jewelry box|bolts|arrows|stones") then {
    gosub stow my %temp
    goto checkLeftHand
    }
  if matchre("%temp","\b(?:oil|pins)\b") then {
    gosub stow my %temp in my $container_crafting in my portal in my eddy
    goto checkLeftHand
    }
  if ("$righthand" != "Empty") then {gosub stow my %temp in my $container_burgle}
checkLeftHand:
  if ("$lefthand" = "Empty") then {return}
  gosub portal
  var temp $lefthand
  if matchre("%temp","([\w-']+) \w+( \w+)") then {var temp $1$2}
  put #echo >talk #FF0000 BURGLE:     found: $lefthand
  put #var BurgleLoot $BurgleLoot|%temp
  if matchre("%temp","memory orb|keepsake box|jewelry box|bolts|arrows|stones") then {
    gosub stow my %temp
    return
    }
  if matchre("%temp","\b(?:oil|pins)\b") then {
    gosub stow my %temp in my $container_crafting in my portal
    return
    }
  if ("$leftthand" != "Empty") then {gosub stow my %temp in my $container_burgle}
  return


#### HIDE ####
hide:
  if ($roundtime > 0) then {pause $pauseTime}
  matchre hide \.\.\.wait|^Sorry,|Are you sure you want to do that\?  You'll interrupt your research!
  matchre returner You blend in with your surroundings|You're already hidden|You melt into|You look around, but can't see any place to hide yourself\.|^Eh\?  But you're already hidden!
  put hide
  matchwait

#### MOVE ####
walk:
  var walkVar &0
rewalk:
  if ($roundtime > 0) then {pause $pauseTime}
  matchre rewalk \.\.\.wait|^Sorry,
  match return Obvious
  put %walkVar
  matchwait

###############
#### This is old code to search the kitchen and the OTHER but not the bedroom
#Branched:
#  if matchre("$roomexits","\b(%validDirections)\b, \b(%validDirections)\b\.") then {
#    var direction $1
#    var otherDirection $2
#
#    match bedroom [Someone Else's Home, Bedroom]
#    matchre other \[Someone Else's Home, \w+\]
#    put peer %direction
#    matchwait
#
#    other:
#      pause 0.1
#      gosub walk %direction
#      if matchre("%Reverse","\b%direction-(\w+)") then {var PathBack $1}
#      gosub search
#      goto BackToKitchen
#
#    bedroom:
#      pause 0.1
#      gosub walk %otherDirection
#      if matchre("%Reverse","\b%otherDirection-(\w+)") then {var PathBack $1}
#      gosub search
#      goto BackToKitchen
#  }