BNF Math Expression

Initial symbol = <expression>

<expression> ::= <arithmetic_expression> | <boolean_expression>

<arithmetic_expression> ::= <arithmetic_expression_type> |
                <arithmetic_expression_type><operator><arithmetic_expression> |
                <parentized_expression> |
                <parentized_expression><operator><arithmetic_expression> |
                <polynomial_expression_with_result>

<arithmetic_expression_type> ::= <function> | <number> | <polynomial_expression>

<parentized_expression> ::= "(" <arithmetic_expression> ")"

<boolean_expression> ::= <boolean_condition> |
             <boolean_condition> <boolean_operator> <boolean_expression> |
             <parentized_boolean_expression> |
             <parentized_boolean_expression><boolean_operator><boolean_expression>

<parentized_boolean_expression> ::= "(" <boolean_expression> ")"

<number> ::= <integer> | <float> | <signal><integer> | <signal><float>

<integer> ::= <digit> | <digit><integer>

<float> ::= <integer>"."<integer>

<digit> ::= "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9" | "0"

<letter> ::= "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" | "j" | "k" | "l" | "m" |
         "n" | "o" | "p" | "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z" |
         "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J" | "K" | "L" | "M" |
         "N" | "O" | "P" | "Q" | "R" | "S" | "T" | "U" | "V" | "W" | "X" | "Y" | "Z"

<signal> ::= "-" | "+"

<operator> ::= "+" | "-" | "*" | "/" | "^" | "%"

<relational_operator> ::= ">" | "<" | ">=" | "<=" | "=="

<boolean_operator> ::= "&&" | "||"

<boolean_condition> ::= "true" | "false"

<function> ::= <function_name> "(" <parameter_list> ")"

<function_name> ::= <letter> <name>

<name> ::= <letter> | <digit> | <letter><name> | <digit><name> | ""

<parameter_list> ::= <parameter> | <parameter>","<parameter_list>

<parameter> ::= <function> | <number> | <polynomial_expression>

<polynomial_expression> ::= <polynomial_term> |
                <polynomial_term> <operator> <polynomial_expression>

<polynomial_term> ::= <letter><exponent> |
              <signal><letter><exponent> |
              <number><letter><exponent>

<exponent> ::=  "^"<function><exponent> |
        "^"<polynomial_expression> |
        "^"<number><exponent> | ""

<polynomial_expression_with_result> ::= <polynomial_expression> "=" <result>

<result> ::= <function> | <number> | <polynomial_expression>