Create MAXtoA AOVs

(
	local AOVs = #("coat", "diffuse_direct", "diffuse_indirect", "emission", "N", "object", "shadow_matte", "specular_direct", "specular_indirect", "sss_direct", "sss_indirect", "transmission", "volume", "Z")
	fn addAOVs =
	(
		renderers.current.AOV_Manager.drivers[1].aovList.count = 1 --clear out previous AOVs so there is only 1 left
		for i = 1 to AOVs.count - 1 do
		(
			append renderers.current.AOV_Manager.drivers[1].aovList (copy renderers.current.AOV_Manager.drivers[1].aovList[1])
		)
		for i = 1 to AOVs.count do
		(
			renderers.current.AOV_Manager.drivers[1].aovList[i].name = AOVs[i]
			if (renderers.current.AOV_Manager.drivers[1].aovList[i].name == "object" or renderers.current.AOV_Manager.drivers[1].aovList[i].name == "shadow_matte") do (renderers.current.AOV_Manager.drivers[1].aovList[i].data = "rgb")
		)
	)
	if (classof renderers.current != Arnold)
	then
	(
		messagebox ("Arnold is not set to be the current renderer,\nMake Arnold the current renderer in the Render Setup dialog.")
	)
	else
	(
		if (renderers.current.AOV_Manager == undefined) do
		(
			renderSceneDialog.open()
			renderSceneDialog.close()
		)
		if (renderers.current.AOV_Manager.drivers.count > 0) and (renderers.current.AOV_Manager.drivers[1].aovList.count > 0)
		then
		(
			if renderers.current.AOV_Manager.drivers[1].aovList.count > 1 then
			(
				if (queryBox ("This operation will delete the " + (renderers.current.AOV_Manager.drivers[1].aovList.count as string) + " AOVs you currently have,\nand then it will create new ones.\n\nWould you like to continue?")) then
				(
					addAOVs()
				)
				else
				(
					exit
				)
			) else
			if renderers.current.AOV_Manager.drivers[1].aovList.count == 1 do addAOVs()
			renderscenedialog.update()
		)
		else
		(
			messagebox ("You need to add an AOV file first,\nlike, ANY AOV will do.")
			renderSceneDialog.open()
		)
	)
)