Small Stats GUI 1.1 SVN

bind p [showgui stats; onrelease cleargui]

newgui stats [
    local tmp
    tmp = (concat (getfrags) (getdeaths) (getaccuracy) (getflags) (
        substr (min 999999 (gettotaldamage)) 0 6
    ) (
        substr (min 999999 (- (gettotalshots) (gettotaldamage))) 0 6
    ) (
        substr (divf (max 0 (getfrags)) (max 1 (getdeaths))) 0 4
    ) (
        substr (minf 999999 (divf (gettotaldamage) (max 1 (getdeaths)))) 0 6
    ))
    guilist [
        guilist [
            guitext "^f7Kills" 0
            guitext "^f7Deaths" 0
            guitext "^f7Accuracy" 0
            cond (m_ctf (getmode)) [
                guitext "^f7Flags Scored" 0
            ] (m_collect (getmode)) [
                guitext "^f7Skulls Collected" 0
            ]
            guibar
            guitext "^f7Damage Dealt" 0
            guitext "^f7Damage Wasted" 0
            guibar
            guitext "^f7KpD" 0
            guitext "^f7DDpD" 0
        ]
        guilist [
            guitext (concat "^f7 :^f2" (at $tmp 0)) 0
            guitext (concat "^f7 :^f2" (at $tmp 1)) 0
            guitext (concatword "^f7 :^f2 " (at $tmp 2) "^%") 0
            if (|| (m_collect (getmode)) (m_ctf (getmode))) [
                guitext (concat "^f7 :^f2" (at $tmp 3)) 0
            ]
            guibar
            guitext (concat "^f7 :^f2" (at $tmp 4)) 0
            guitext (concat "^f7 :^f2" (at $tmp 5)) 0
            guibar
            guitext (concat "^f7 :^f2" (at $tmp 6)) 0
            guitext (concat "^f7 :^f2" (at $tmp 7)) 0
        ]
    ]
] "Personal Stats"