EASY batch Save load system for any script needing User save

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
        @Echo OFF & PUSHD "%~dp0"&REM Save / Load system by T3RRY         :::
:::     Variables to be saved Require $. Prefix IE Set "$.Name=Value"     :::
:Save.Load &REM SYNTAX: <User Name> <Directory Name> <Save / Load / View> :::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    IF "%~1" == "?" (Echo.[User Name] [Directory Name] [Save / Load / View]&Pause&Exit /B 0)
    IF "%~3" == "" (Echo.Parameters missing.&Echo.[User Name] [Directory Name] [Save / Load / View]& Exit /B 1)
    Set "User.Name=%~1"
    Set "Program.DIR=%~2"
    Set "Save.Load=%~3"
    IF Not Exist "%TEMP%\%Program.DIR%" MD "%TEMP%\%Program.DIR%" || (Echo Invalid Directory Name & Exit /B 1)
    IF exist "%TEMP%\%Program.DIR%\%User.Name%.bat" IF /I "%Save.Load%" == "Load" (Goto :Var.Load) Else IF /I "%Save.Load%" == "View" (Goto :File.View)
    (For %%A in ("one=one two" "two=two one") Do Set "$.%%~A")& REM Example Variables
    (
    Echo @Echo off
    For /F "UsebackQ Tokens=* Delims=" %%S in (`"Set $."`) Do Echo Set "%%~S"
    Echo Goto :EOF
    )>"%TEMP%\%Program.DIR%\%User.Name%.bat" || Exit /B 1
Exit /B 0
:Var.Load
    CALL "%TEMP%\%Program.DIR%\%User.Name%.bat" || Exit /B 1
    For /F "Tokens=1,2 Delims==" %%A in ('Set $.') DO Echo %%A = %%B
Exit /B 0
:File.View
CLS&&(Type "%TEMP%\%Program.DIR%\%User.Name%.bat" | More) || Exit /B 1
Exit /B 0