@ECHO off
REM Set to folder name of robocraft.exe executable
SET robodir=D:\games\SteamComLib\steamapps\common\Robocraft
REM Will keep %logs% logs in addition to current log
SET logs=10

REM === CODE START ===
SET cur=%logs%

REM if there is no new output log there is no need to rename files
IF NOT EXIST "%robodir%\RobocraftClient_Data\output_log.txt" (
  ECHO Missing output log. Skipping.
  GOTO game
)

REM if exists, delete oldest backup to make room for new
IF EXIST "%robodir%\RobocraftClient_Data\output_log.%cur%.txt" (
  DEL "%robodir%\RobocraftClient_Data\output_log.%cur%.txt"
)

REM loop through existing backup logs and increment file names by one until %logs% backups exist
:loop

REM if output_log.%mone%.log exists rename log, incrementing %mone% to %cur% (where %mone% equals %cur% minus 1)
SET /a mone=%cur%-1
IF EXIST "%robodir%\RobocraftClient_Data\output_log.%mone%.txt" (
  MOVE /Y "%robodir%\RobocraftClient_Data\output_log.%mone%.txt" "%robodir%\RobocraftClient_Data\output_log.%cur%.txt"
)

REM decrement %cur% and restart loop
SET /a cur-=1
REM if final iteration escape loop to :fnsh
IF %cur% LEQ 0 ( GOTO fnsh )
GOTO loop

:fnsh
REM if exists, make backup of most recent log
IF EXIST "%robodir%\RobocraftClient_Data\output_log.txt" (
  MOVE /Y "%robodir%\RobocraftClient_Data\output_log.txt" "%robodir%\RobocraftClient_Data\output_log.1.txt"
)

:game
REM clear variables (probably unnecessary)
SET cur=
SET mone=

REM change to robocraft directory and run game
CD "%robodir%"
Robocraft.exe