///////// Main Loop
//equip weapon
if not @findobject 'righthand'
  equipitem 'weapon' 2
  pause 500
endif
//equip shield
if not @findobject 'lefthand' and @findobject 'righthand'
  equipitem 'shield' 2
  pause 500
endif
@getenemy 'murderer' 'enemy' 'criminal' 'gray' 'closest'
pause 400
if @findobject 'enemy'
  @clearjournal
  if @inrange 'enemy' 10
    if hits 'enemy' == maxhits 'enemy'
      virtue 'honor'
      waitfortarget 5000
      target! 'enemy' 200
      pause 300
      canceltarget
      attack 'enemy'
    endif
    ////////////////////////////////////////
    //use ability
    // comment out the one you wish not to use
    if mana >= 64 and timer 'abilitytimer' > 500
      //primary
      setability 'primary' 'on'
      //secondary
      //  setability 'secondary' 'on'
      //
    endif
    if @injournal 'attack with lightning!' or @injournal 'failure message'
      cast "counter attack"
      clearjournal
    endif
    if @injournal 'You attack with lightning precision!' or @injournal 'failure message'
      cast "Lightning Strike"
      clearjournal
    endif
    ///////////////////////////
    ///////////////////////////
    ///////////////////////////
    /////Disco target
    if not @injournal 'jarring' and not @injournal 'already' and not @injournal 'would have no effect'
      if timer 'discotimer' >= 2050 and @inrange 'enemy' 6
        useskill 'Discordance'
        waitfortarget 1000
        target! 'enemy' 2000
        settimer 'discotimer' 0
        pause 126
        canceltarget
      endif
      clearjournal
    endif
    ////////////////
    ////////////////
    ////////////////
    //// Enemy of one
    if not buffexists 'Enemy of One'
      cast 'Enemy of One'
      pause 250
    endif
    ////////////////
    ////////////////
    ////////////////
    // Divine Fury
    if not buffexists "divine fury"
      cast 'Divine Fury'
      pause 500
      if @injournal 'not yet recovered' 'system' or @injournal 'you are already' 'system'
        replay
      endif
      clearjournal
    endif
    /////////////////////
    /////////////////////
    /////////////////////
    ///// Consecrate Weapon
    if timer 'consecratetimer' >= 9000
      if not buffexists "Consecrate Weapon"
        cast "Consecrate Weapon"
        pause 500
        settimer 'consecratetimer' 0
        if @injournal 'not yet recovered' 'system' or @injournal 'you are already' 'system'
          replay
        endif
        clearjournal
      endif
    endif
    attack 'enemy'
  endif
endif
////////////////////////////////////////
////////////////////////////////////////
////////////////////////////////////////
/// Healing
if timer 'bandagetimer' >= 10250
  //poisoned
  if poisoned 'self'
    bandageself
    waitfortarget 1500
    target! 'self'
    settimer 'bandagetimer' 0
  elseif diffhits > 8
    bandageself
    waitfortarget 1500
    target! 'self'
    settimer 'bandagetimer' 0
  endif
  pause 200
endif
///////////////////////////////////////////
///////////////////////////////////////////
///////////////////////////////////////////
// smelt ore's
if @usetype! 0x19b9 'any' 'backpack'
  waitfortarget 1500
  @target! 'portableforge'
elseif @usetype! 0x19b8 'any' 'backpack'
  waitfortarget 1500
  @target! 'portableforge'
elseif @usetype! 0x19ba 'any' 'backpack'
  waitfortarget 1500
  @target! 'portableforge'
endif
///////////////////////////////
//clip hides to leather
for 0 to 'tailorclips'
  while @findtype 'tailorclips[]'
    @usetype 0xf9f
    waitfortarget 1000
    @target! 'found'
  endwhile
endfor
///////////////////////////////////////////
///////////////////////////////////////////
///////////////////////////////////////////
// Use Storage Key's
////////////////////////////////
//store ingots
if @findtype 0x1bf2
  waitforcontext 'ingotkey' 2 1000
  waitforgump 0x6abce12 1000
  replygump 0x6abce12 0
endif
/////////////////////////////////////
//store reagents
for 0 to 'regs'
  while @findtype 'regs[]' 'backpack'
    waitforcontext 'regkey' 2 1000
    waitforgump 0x6abce12 1000
    replygump 0x6abce12 0
    pause 200
    waitforcontext 'scribekey' 2 1000
    waitforgump 0x6abce12 1000
    replygump 0x6abce12 0
    pause 200
    break
  endwhile
endfor
/////////////////////////////////////////
////store hides
if @findtype 0x1081
  waitforcontext 'tailorkey' 2 1000
  waitforgump 0x6abce12 1000
  replygump 0x6abce12 0
endif
////////////////////////////////
////////////////////////////////
////////////////////////////////
///Loot Jewelry
/////////////////////////
//Find Corpse
if @findtype '0x2006' 'any' 'ground' '1' '1'
  @setalias '0' 'found'
  @useobject '0'
  pause 300
  ///Check for Artifact
  for 0 to Gearlist
    for 2
      if @findtype Gearlist[] 'any' '0'
        @setalias 'Geartocheck' 'found'
        waitforproperties 'Geartocheck' 3000
        if @property 'Artifact' 'Geartocheck'
          sysmsg 'Artifact' '1990'
          @moveitem 'Geartocheck' 'LootBag'
          pause 1000
        endif
      endif
    endfor
  endfor
  //////////////////////////
  //Locate Jewelry
  for 0 to Jewelry
    for 2
      if @findtype Jewelry[] 0 '0'
        @setalias 'Skills' 'found'
        waitforproperties 'Skills' 3000
        if @property 'Swordsmanship' 'Skills' >= 12
          sysmsg 'Swords!' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Parry' 'Skills' >= 11
          sysmsg 'Parry!' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Tactics' 'Skills' >= 11
          sysmsg 'Tactics' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Animal Taming' 'Skills' >= 11
          sysmsg 'Taming' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Archery' 'Skills' >= 11
          sysmsg 'Archery' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Anatomy' 'Skills' >= 11
          sysmsg 'Anatomy' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Bushido' 'Skills' >= 11
          sysmsg 'Bushido' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Peacemaking' 'Skills' >= 11
          sysmsg 'Animal Lore' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Animal Lore' 'Skills' >= 11
          sysmsg 'Animal Lore' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Evaluating Intelligence' 'Skills' >= 11
          sysmsg 'Evaluating Intelligence' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Lower Reagent Cost' 'Skills' >= 17
          sysmsg 'Lower Reagent Cost' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        elseif @property 'Faster Cast Recovery' 'Skills' >= 2 and @property 'Faster Casting' 'Skills' >=1
          sysmsg 'FCR/FC' '1990'
          @moveitem 'Skills' 'LootBag'
          pause 1000
        endif
      endif
    endfor
  endfor
endif
//Close Corpse
ignoreobject '0'
////////////////////////////////
// checks and gold
if @findtype 0xeed 0x0 'backpack'
  useobject 0x42c79fe3
  waitforgump 0x9021dd59 1500
  replygump 0x9021dd59 5 2
  waitfortarget 1500
  targettype! 0xeed 0x0 500
  pause 100
  canceltarget
  pause 400
  replygump 0x9021dd59 0 2
elseif @findtype 0x14f0 52 'backpack'
  useobject 0x42c79fe3
  waitforgump 0x9021dd59 1500
  replygump 0x9021dd59 5 2
  waitfortarget 1500
  targettype! 0x14f0 52 500
  pause 100
  canceltarget
  pause 400
  replygump 0x9021dd59 0 2
endif
if @contents 'tokenbag' >= 1
  waitforcontext 0x42c79fe7 0 1500
endif