on 750:text:!gban *:?: {
  var %banmask = $address($2,2)
  .writeini Globalban.ini %banmask Banmaster $nick
  .writeini Globalban.ini %banmask Zeit $fulldate
  .writeini Globalban.ini %banmask Grund $3-
  globalban %banmask $3-
  msg $nick Globaler Hostban auf %banmask added.
}

on 750:text:!nban *:?: {
  var %bannick = $2
  .writeini Globalban.ini %bannick Banmaster $nick
  .writeini Globalban.ini %bannick Zeit $fulldate
  .writeini Globalban.ini %bannick Grund $3-
  globalnickban %bannick $3-
  msg $nick Globaler Nickban auf %bannick added.
}

on 750:text:!gbinfo:?: {
  msg $nick Information:
  msg $nick !gban <Nick> <Grund> = Fuer einen globalen Hostbann auf die Banmask des Nicks.
  msg $nick !nban <Nick> <Grund> = Fuer einen globalen Nickbann auf den Nick.
  msg $nick !rgban <Banmask> = Fuer das entfernen eines globalen Host- oder Nickbanns.
  msg $nick (Der Ban wird dabei in allen Channeln, wo ich @ oder % bin entfernt.)
}

alias globalban {
  var %x = $chan(0)
  while (%x) {
    if ($me isop $chan(%x)) || ($me ishop $chan(%x)) {
      var %y = $nick($chan(%x),0)
      while (%y) {
        if ($nick($chan(%x),%y) == $me) {
        }
        elseif ($address($nick($chan(%x),%y),2) == $1) {
          kick $chan(%x) $nick($chan(%x),%y) $2-
        }
        dec %y
      }
    }
    dec %x
  }
}

alias globalnickban {
  var %x = $chan(0)
  while (%x) {
    if ($me isop $chan(%x)) || ($me ishop $chan(%x)) {
      var %y = $nick($chan(%x),0)
      while (%y) {
        if ($nick($chan(%x),%y) == $1) {
          kick $chan(%x) $nick($chan(%x),%y) $2-
        }
        dec %y
      }
    }
    dec %x
  }
}

alias globalunban {
  var %x = $chan(0)
  while (%x) {
    if ($me isop $chan(%x)) || ($me ishop $chan(%x)) {
      mode $chan(%x) -b $1
    }
    dec %x
  }
}

on *:join:#: {
  if ($me isop $chan) || ($me ishop $chan) {
    if ($readini(Globalban.ini,$address($nick,2),Grund))  {
      mode $chan +b $address($nick,2)
      kick $chan $nick Banned: $readini(Globalban.ini,$address($nick,2),Grund) Set by $readini(Globalban.ini,$address($nick,2),Banmaster) on $readini(Globalban.ini,$address($nick,2),Zeit) $+ .
    }
    elseif ($readini(Globalban.ini,$nick,Grund))  {
      mode $chan +b $nick
      kick $chan $nick Banned: $readini(Globalban.ini,$nick,Grund) Set by $readini(Globalban.ini,$nick,Banmaster) on $readini(Globalban.ini,$nick,Zeit) $+ .
    }
  }
}

on 750:text:!rgban *:?: {
  if (!$readini(Globalban.ini,$2,Grund)) {
    msg $nick $2 is not in the Globalban.ini
  }
  else {
    .remini Globalban.ini $2
    msg $nick Globalban $2 is removed.
    globalunban $2
  }
}

on ^*:nick: {
  var %theme.i = 1
  while (%theme.i <= $comchan($newnick, 0)) {
    %theme.chan = $comchan($newnick, %theme.i)
    if ($readini(Globalban.ini,$newnick,Grund))  {
      mode $comchan($newnick, %theme.i) +b $newnick
      kick $comchan($newnick, %theme.i) $newnick Banned: $readini(Globalban.ini,$newnick,Grund) Set by $readini(Globalban.ini,$newnick,Banmaster) on $readini(Globalban.ini,$newnick,Zeit) $+ .
    }
    inc %theme.i
  }
  unset %theme.chan
}