Keyhotee-git PKGBUILD

pkgname=keyhotee-git
pkgver=r186.8e20201
pkgrel=3
pkgdesc="Decentralized ID and Communication"
arch=('i686' 'x86_64')
url="http://invictus-innovations.com/keyhotee"
license=('custom')
depends=('miniupnpc' 'openssl' 'qt5-base')
makedepends=('boost' 'cmake' 'git' 'qt5-webkit')
source=(git+https://github.com/InvictusInnovations/keyhotee.git
        git+https://github.com/InvictusInnovations/BitShares.git
        git+https://github.com/InvictusInnovations/fc)
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

_gitname=keyhotee

pkgver() {
  cd "$srcdir/$_gitname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/$_gitname"

  # 12/7/2013 - clone BitShares into Keyhotee-build subdirectory
  git clone "$srcdir/BitShares" "$srcdir/$_gitname/BitShares"
  git clone "$srcdir/fc" "$srcdir/$_gitname/BitShares/fc"

  msg "Fixing memory order method for Boost 1.55..."
  # change memory order method from "consume" to "acquire" to fix Boost 1.55 compiling error
  # https://github.com/InvictusInnovations/fc/blob/phoenix/src/thread/thread_d.hpp#L221
  sed -i "s/consume/acquire/" $srcdir/$_gitname/BitShares/fc/src/thread/thread_d.hpp

  msg "Starting build..."
  # create debug build
  cmake -DINVICTUS_ROOT="$srcdir/$_gitname" -DCMAKE_BUILD_TYPE=Debug .
  make
}

package() {
  # install Keyhotee debug binary
  install -Dm755 $srcdir/$_gitname/bin/KeyhoteeD $pkgdir/usr/bin/KeyhoteeD

  # install license file
  install -Dm644 $srcdir/$_gitname/BitShares/LICENSE.md $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: