Timeranger Helpers v2

function DupFrame(clip c, int f) {
    return c.Trim(f,f).assumefps("ntsc_video")
}

function Zoom(clip c, int left, int top, int right, int bottom) {
    return(c.spline36resize(c.width(),c.height(),left,top,right,bottom))
}

#It's more convenient to start with select60 and edit to 24/30 than a trim,
function Select60(clip in, int start, int end, int "a", int "b", int "c", int "d") {
    return(in.trim(start,end))
}

function Select30(clip c, int start, int end, int "w", int "x", int "y", int "z") {
    return(c.trim(start,end).selecteven())
}

function Select24(clip in, int start, int end, int a, int b, int c, int d, bool "show") {
    show = default(show, false)
    if (show == true) {
        trimmed = in.trim(start,end)
        return Show10(trimmed,a,b,c,d)
    } else {
    return in.trim(start,end).selectevery(10,a,b,c,d,d)
    }
}

function Show10(clip in, int "first", int "second", int "third", int "fourth") {
    for (n = 0, 10) {
        m = string(n)
        w = round(in.width * 0.75)
        h = round(in.height * 0.75)
        dim = "(" + string(w) + "," + string(h) + ")"
        eval("frame" + m + "=in.selectevery(10," + m + ")")
        eval("frame" + m + "=frame" + m + ".bicubicresize" + dim)
        eval("frame" + m + "=frame" + m + """.subtitle("""" + m + """",x=10,y=6)""")
    }

    if (defined(first)) {
        eval(highlightStr(first))
    }
    if (defined(second)) {
        eval(highlightStr(second))
    }
    if (defined(third)) {
        eval(highlightStr(third))
    }
    if (defined(fourth)) {
        eval(highlightStr(fourth))
    }

    k = blankclip(frame0,1)
    t = stackhorizontal(frame0,frame1,frame2,frame3)
    m = stackhorizontal(frame4,frame5,frame6,k)
    b = stackhorizontal(frame7,frame8,frame9,k)
    return stackvertical(t,m,b)
}

function highlightStr(int n) {
    m = string(n)
    return "frame" + m + "=highlightEdge(frame" + m + ")"
}


function highlightEdge(clip in)
{
    return(in.crop(4,4,-4,-2).addborders(4,4,4,2,color=color_red))
}