titlebar weather

on *:start: StartTitleBarWeather
;edit the alias below to reflect your zip code or city.
alias -l ttlbarWeather { GetWunderground noop noop 45015 }
alias -l ttlbarDate titlebar $chr(7) $asctime(dddd mmmm dd yyyy h:nntt) $chr(7) $gettok($titlebar,2-,7)
alias StartTitleBarWeather {
  titlebar
  $iif($timer(TitleUpdate),.timer $+ $v1 off)
  $iif($timer(ttlbarWeather),.timer $+ $v1 off)
  .timerTitleUpdate -o 0 1 ttlbarDate
  ttlbarWeather
  .timerttlbarWeather -o 0 400 ttlbarWeather
}
alias -l GetWunderground {
  var %sockname $+(ttlbarWunderground,$network,$2,$ticks)
  hmake %sockname 5
  sockopen %sockname www.wunderground.com 80
  sockmark %sockname $1-2 $+(/cgi-bin/findweather/getForecast?query=,$replace($3-,$chr(32),$+(%,20)),&wuSelect=WEATHER)
}
On *:sockopen:ttlbarWunderground*: {
  if (!$sockerr) {
    sockwrite -nt $sockname GET $gettok($sock($sockname).mark,3,32) HTTP/1.0
    sockwrite -n $sockname Host: www.wunderground.com
    sockwrite -n $sockname $crlf
  }
  else { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
}
On *:sockread:ttlbarWunderground*: {
  if ($sockerr) { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
  else {
    var %Wunderground | sockread %Wunderground
    if (<div id="tempActual"> isin %Wunderground) hadd $sockname Temp true
    elseif ($hget($sockname,Temp) == true) && ($regex(%Wunderground,/<span class="nobr"><[^<]*>([^<]*)<\/span>([^<]*)<\/span>/i)) {
      hadd $sockname Temp $+($regml(1),$replace($remove($regml(2),&nbsp;),&deg;,$chr(186)))
    }
    elseif ($regex(%Wunderground,/<div id="curCond">([^<]*)</div>/i)) {
      hadd $sockname conditions $regml(1)
    }
    elseif ($regex(%Wunderground,/<span id="windCompassSpeed"[^>]*>([^<]*)<\/span>/i)) {
      titlebar - $gettok($titlebar,1,7) $chr(7) Temperature: $hget($sockname,temp) $chr(7) Conditions: $hget($sockname,conditions) $chr(7) Wind: $regml(1)
      hfree $sockname
      sockclose $sockname
    }
  }
}
On *:sockclose:ttlbarWunderground*: hfree $sockname