carpentry_furniture.zs

////Imports
import crafttweaker.item.IItemStack;
import mods.artisanworktables.builder.RecipeBuilder;

////Variables
val frameBoard = <bibliocraft:framingboard>;
val frameSheet = <bibliocraft:framingsheet>;
val frameHeavy = <earthworks:item_timber>;
val stick = <ore:stickWood>;
val artisansSaw = <ore:artisansHandsaw>;
val artisansHammer = <ore:artisansHammer>;
val planer = <earthworks:tool_hand_planer>;


var furnitureMats = [
	<minecraft:planks>,
	<minecraft:planks:1>,
	<minecraft:planks:2>,
	<minecraft:planks:3>,
	<minecraft:planks:4>,
	<minecraft:planks:5>
] as IItemStack[];


var tableVC = {
	<minecraft:planks> : <variedcommodities:table>,
	<minecraft:planks:1> : <variedcommodities:table:1>,
	<minecraft:planks:2> : <variedcommodities:table:2>,
	<minecraft:planks:3> : <variedcommodities:table:3>,
	<minecraft:planks:4> : <variedcommodities:table:4>,
	<minecraft:planks:5> : <variedcommodities:table:5>
} as IItemStack[IItemStack];




for plank in furnitureMats {
	recipes.remove(tableVC[plank]);
	RecipeBuilder.get("carpenter")
		.setShaped([[frameSheet.reuse(), frameSheet.reuse(), frameSheet.reuse()], [stick.reuse(), null, stick.reuse()]])
		.setTool(artisansSaw, 1)
		.setTool(planer, 1)
		.setSecondaryIngredients([plank * 4])
		.addOutput(tableVC[plank])
		.requireGameStages("ALL", ["woodcutting_2", "carpentry_table_vc"])
		.create();
}