Example Direction Looking in Inform 7

"Example Direction Looking" by Aika

A room can be ghost-filled. [This is a spooky room full of ghosts; flashlights react to these.]
A room can be portal-filled. [This room has a portal to another dimension; radios react to these.]

Test1 is a room.
Test2 is a room. Test2 is north of Test1.
Test3 is a room. Test3 is ghost-filled. Test3 is east of Test1.
Test4 is a room. Test4 is portal-filled. Test4 is south of Test1.
Test5 is a room. Test5 is ghost-filled. Test5 is portal-filled. Test5 is west of Test1.

A detective-item is a kind of thing.

Definition: a detective-item is reacting:
	decide no. [This is the default, if we haven't coded anything for when the detective-item will trigger]

To say ReactionFlav of (D - a detective-item):
	say "The [D] whines.". [This is the default, if we haven't coded anything for when the detective-item will trigger]

flashlight is a detective-item. flashlight is carried by the player.

To say ReactionFlav of (D - flashlight):
	say "The [D] flickers.".

Definition: flashlight is reacting:
	if the noun is a direction: [just to confirm what we should hopefully already know, this function was called during an action where the noun given was a direction]
		let R be the room noun from the location of the player;
		if R is ghost-filled, decide yes;
	decide no.

radio is a detective-item. radio is carried by the player.

Definition: radio is reacting:
	if the noun is a direction: [just to confirm what we should hopefully already know, this function was called during an action where the noun given was a direction]
		let R be the room noun from the location of the player;
		if R is portal-filled, decide yes;
	decide no.

Check examining a direction:
	if there is a held reacting detective-item:
		repeat with D running through held reacting detective-items:
			say ReactionFlav of D;
		say "That's [if the number of held reacting detective-item is 1]a bit[otherwise]extremely[end if] unnerving..." instead. [We need to use 'instead' here, because if we don't, the action will continue, triggering the code to say its usual 'you see nothing special in that direction']

[The examine directions rule is not listed in the carry out examining rulebook.] [This is commented out because we shouldn't need it. But if we struggle to successfully circumvent this rule, we can include this line to give us more flexibility. However, this does mean that now when someone examines a direction with nothing interesting, it'll say something dumb like 'You see nothing special about the east'. So we might want to address that later.]