Consultas:


#Contratos feitos com sancionados

PREFIX ardo: <http://www.arida.com/ontology/>

SELECT  ?nome_uasg ?id_contrato ?inicio_sancao ?dt_inicio_vigencia
        ?final_sancao ?nome_fornecedor ?abrangencia ?nome_orgao_sancionador
        ?sigla_uf ?tipo_sancao
WHERE {
    ?contrato a ardo:Contrato ;
      ardo:contrato_id ?id_contrato ;
      ardo:data_inicio_vigencia ?dt_inicio_vigencia ;
      ardo:temContratado ?fornecedor ;
      ardo:temContratante ?uasg .

    ?fornecedor a ardo:PessoaJuridica ; ardo:nome_fornecedor ?nome_fornecedor .

    ?uasg ardo:nome ?nome_uasg .

    ?sancao a ardo:SancaoAplicada ;
      ardo:data_inicio ?inicio_sancao ;
      ardo:data_final ?final_sancao ;
      ardo:aplicadaSobre ?fornecedor ;
      ardo:tipo_sancao ?tipo_sancao

    OPTIONAL {
      ?sancao a ardo:SancaoCNEP ; ardo:valor_multa ?valor_multa .
    }

    OPTIONAL {
      ?sancao a ardo:SancaoCEIS ; ardo:abrangencia ?abrangencia.
      ?orgaoSancionador ardo:sanciona ?sancao ;
          ardo:nome_orgao ?nome_orgao_sancionador ;
          ardo:temUF ?uf .
      ?uf ardo:sigla_uf ?sigla_uf .

    }

   FILTER (?dt_inicio_vigencia > ?inicio_sancao)

  }


#Compras onde o fornecedor está sancionado
SELECT ?nome_uasg  ?compra ?dt_ratificacao ?dt_ratificacao_date ?sancao ?inicio_sancao ?final_sancao ?fornecedor ?nome_fornecedor
WHERE {
    ?compra a ardo:ComprasSemLicitacao ;
      ardo:data_ratificacao ?dt_ratificacao ;
      ardo:unidadeResponsavel ?uasg .

    ?compra ardo:temItem ?item .

    ?item ardo:temVencedor ?fornecedor .

    ?uasg ardo:nome ?nome_uasg .

    ?sancao a ardo:SancaoAplicada ; ardo:data_inicio ?inicio_sancao ; ardo:data_final ?final_sancao ; ardo:aplicadaSobre ?fornecedor.

    ?fornecedor a ardo:PessoaJuridica ; ardo:nome_fornecedor ?nome_fornecedor .

    BIND(xsd:date(xsd:dateTime(?dt_ratificacao)) AS ?dt_ratificacao_date)

    FILTER (?dt_ratificacao_date > ?inicio_sancao)

  }

#UASGs e a quantidade respectiva de contratos duvidosos

PREFIX ardo: <http://www.arida.com/ontology/>

SELECT ?nome_uasg ?qtd_de_contratos ?qtd_de_contratos_duvidosos ?quo
WHERE {

   ?uasg a ardo:UASG;
        ardo:nome ?nome_uasg .

   {
    SELECT ?uasg COUNT(*) AS ?qtd_de_contratos
    WHERE {
        ?contrato a ardo:Contrato;
            ardo:temContratante ?uasg;
            ardo:temContratado ?fornecedor.
        ?fornecedor a ardo:PessoaJuridica .
    }
   }

    {
    SELECT ?uasg COUNT(*) AS ?qtd_de_contratos_duvidosos
    WHERE {
        ?contrato_d a ardo:Contrato;
            ardo:temContratante ?uasg;
            ardo:temContratado ?fornecedor_s.
        ?fornecedor_s a ardo:PessoaJuridica, ardo:Sancionado .

    }
   }

   BIND(?qtd_de_contratos_duvidosos / xsd:double(?qtd_de_contratos) AS ?quo)
  }

ORDER BY DESC(?quo)
LIMIT 10

#UASG e respectiva Quantidade de compras sem licitação duvidosas

PREFIX ardo: <http://www.arida.com/ontology/>

SELECT ?nome_uasg ?qtd_compras_sem_licitacao ?qtd_compras_sem_licitacao_duvidosas ?quo
WHERE {

   ?uasg a ardo:UASG;
        ardo:nome ?nome_uasg .

   {
    SELECT ?uasg COUNT(*) AS ?qtd_compras_sem_licitacao
    WHERE {
        ?compraSemLicitacao a ardo:ComprasSemLicitacao;
            ardo:unidadeResponsavel ?uasg.
                ?compraSemLicitacao ardo:temItem ?item .
                ?item ardo:temVencedor ?fornecedor .
                ?fornecedor a ardo:PessoaJuridica .
    }
   }

   {
    SELECT ?uasg COUNT(*) AS ?qtd_compras_sem_licitacao_duvidosas
    WHERE {
        ?compraSemLicitacao_d a ardo:ComprasSemLicitacao;
            ardo:unidadeResponsavel ?uasg.
                ?compraSemLicitacao_d ardo:temItem ?item_d .
                ?item_d ardo:temVencedor ?fornecedor_d .
                ?fornecedor_d a ardo:PessoaJuridica, ardo:Sancionado .
    }
   }

  BIND(?qtd_compras_sem_licitacao_duvidosas / xsd:double(?qtd_compras_sem_licitacao) AS ?quo)

  }

ORDER BY DESC(?quo)
LIMIT 10

#UASG e Quantidade de Fornecedores respectivos de Contratos
PREFIX ardo: <http://www.arida.com/ontology/>

SELECT ?nome_uasg ?qtd_de_fornecedor ?qtd_de_fornecedor_s ?quo
WHERE {

   ?uasg a ardo:UASG; ardo:nome ?nome_uasg .

  {
    SELECT ?uasg COUNT(DISTINCT ?fornecedor) AS ?qtd_de_fornecedor
    WHERE {
      ?contrato a ardo:Contrato;
        ardo:temContratante ?uasg;
        ardo:temContratado ?fornecedor.
      ?fornecedor a ardo:PessoaJuridica .
    }
  }

  {
    SELECT ?uasg COUNT(DISTINCT ?fornecedor_s) AS ?qtd_de_fornecedor_s
    WHERE {
      ?contrato_d a ardo:Contrato;
        ardo:temContratante ?uasg;
        ardo:temContratado ?fornecedor_s.
      ?fornecedor_s a ardo:PessoaJuridica, ardo:Sancionado .

    }
  }

  BIND(?qtd_de_fornecedor_s / xsd:double(?qtd_de_fornecedor) AS ?quo)

}

ORDER BY DESC(?quo)
LIMIT 10



#UASG e Quantidade de Fornecedores respectivos de Compras sem Licitação

PREFIX ardo: <http://www.arida.com/ontology/>

SELECT ?nome_uasg ?qtd_fornecedores ?qtd_fornecedores_d ?quo
WHERE {

   ?uasg a ardo:UASG;
        ardo:nome ?nome_uasg .

   {
    SELECT ?uasg COUNT(DISTINCT ?fornecedor) AS ?qtd_fornecedores
    WHERE {
        ?compraSemLicitacao a ardo:ComprasSemLicitacao;
            ardo:unidadeResponsavel ?uasg.
                ?compraSemLicitacao ardo:temItem ?item .
                ?item ardo:temVencedor ?fornecedor .
                ?fornecedor a ardo:PessoaJuridica .
    }
   }

   {
    SELECT ?uasg COUNT(DISTINCT ?fornecedor_d) AS ?qtd_fornecedores_d
    WHERE {
        ?compraSemLicitacao_d a ardo:ComprasSemLicitacao;
            ardo:unidadeResponsavel ?uasg.
                ?compraSemLicitacao_d ardo:temItem ?item_d .
                ?item_d ardo:temVencedor ?fornecedor_d .
                ?fornecedor_d a ardo:PessoaJuridica, ardo:Sancionado .
    }
   }

  BIND(?qtd_fornecedores_d / xsd:double(?qtd_fornecedores) AS ?quo)

  }

ORDER BY DESC(?quo)
LIMIT 10

# Descrição, média de preço e valor máximo estimado de itens com suas respectivas unidades
PREFIX ardo: <http://www.arida.com/ontology/>

SELECT ?descricao ?media_valor_estimado ?max_valor_estimado ?min_valor_estimado ?unidades_utilizadas
WHERE {

    ?servico a ardo:Servico ;
      ardo:codigo ?codigo ;
        ardo:descricao ?descricao .

    {
      SELECT ?servico AVG(?valor_por_servico) AS ?media_valor_estimado MAX(?valor_por_servico) AS ?max_valor_estimado MIN(?valor_por_servico) AS ?min_valor_estimado  GROUP_CONCAT(DISTINCT ?un ; SEPARATOR=", ") AS ?unidades_utilizadas
      WHERE {
        ?compras a ardo:ComprasSemLicitacao ;
          ardo:temItem ?item .

        ?item ardo:instanciaDe ?servico ;
          ardo:valor_estimado ?valor_estimado;
          ardo:quantidade ?quantidade;
          ardo:temVencedor ?fornecedor;
          ardo:unidade_medida ?un     .

      ?fornecedor a ardo:PessoaJuridica .
      FILTER NOT EXISTS{
        ?fornecedor a ardo:Sancionado .
      }


      BIND(?valor_estimado/ xsd:double(?quantidade ) AS ?valor_por_servico)

      }
    }
}
LIMIT 20

# Descrição e Média de Preço de Itens

PREFIX ardo: <http://www.arida.com/ontology/>

SELECT ?descricao ROUND(?media_valor_estimado) ROUND(?media_valor_estimado_d)
WHERE {

    ?servico a ardo:Material ;
      ardo:codigo ?codigo ;
        ardo:descricao ?descricao .

    {
      SELECT ?servico AVG(?valor_por_servico) AS ?media_valor_estimado
      WHERE {
        ?compras a ardo:ComprasSemLicitacao ;
          ardo:temItem ?item .

        ?item ardo:instanciaDe ?servico ;
          ardo:valor_estimado ?valor_estimado;
          ardo:quantidade ?quantidade;
                ardo:temVencedor ?fornecedor.

      ?fornecedor a ardo:PessoaJuridica .

      BIND(?valor_estimado/ xsd:double(?quantidade ) AS ?valor_por_servico)

      }
    }

    {
      SELECT ?servico AVG(?valor_por_servico) AS ?media_valor_estimado_d
      WHERE {
        ?compras a ardo:ComprasSemLicitacao ;
          ardo:temItem ?item .

        ?item ardo:instanciaDe ?servico ;
          ardo:valor_estimado ?valor_estimado;
          ardo:quantidade ?quantidade;
                ardo:temVencedor ?fornecedor.

      ?fornecedor a ardo:PessoaJuridica, ardo:Sancionado .

      BIND(?valor_estimado/ xsd:double(?quantidade ) AS ?valor_por_servico)

      }
    }
}

ORDER BY DESC(?media_valor_estimado_d)
LIMIT 20


# Razão Social dos Sancionados

PREFIX ardo: <http://www.arida.com/ontology/>

SELECT ?cnpj ?informado ?razao_social
WHERE{
    ?fornecedor a ardo:PessoaJuridica, ardo:Sancionado ;
        ardo:cnpj ?cnpj ;
        ardo:nome_informado ?informado ;
        ardo:nome_fornecedor ?nome_siasg ;
        ardo:razao_social ?razao_social .


}
LIMIT 30


# Período da Sanção Aplicada

PREFIX ardo: <http://www.arida.com/ontology/>

SELECT ?fornecedor ?data_inicial
WHERE{
    ?fornecedor a ardo:PessoaJuridica, ardo:Sancionado .

    ?sancao a ardo:SancaoAplicada;
       ardo:aplicadaSobre ?fornecedor;
       ardo:data_inicio ?data_inicial.

}
LIMIT 30

# Ramo de negocio com indicios de Sanções Aplicadas
SELECT ?nome_ramo COUNT(DISTINCT ?fornecedor) AS ?numero_de_fornecedores
WHERE {

    ?sancao a ardo:SancaoAplicada ;
      ardo:data_inicio ?inicio_sancao ;
      ardo:data_final ?final_sancao ;
      ardo:aplicadaSobre ?fornecedor.

    ?fornecedor a ardo:PessoaJuridica ;
      ardo:nome_fornecedor ?nome_fornecedor ;
      ardo:temRamoDeNegocio ?ramo .

    ?ramo ardo:descricao ?nome_ramo .

  }
GROUP BY ?nome_ramo
ORDER BY DESC(?numero_de_fornecedores)
LIMIT 15

#Agregação dos fornecedores por Porte
SELECT ?porte_nome COUNT(DISTINCT ?fornecedor) AS ?numero_de_fornecedores
WHERE {

    ?sancao a ardo:SancaoAplicada ; ardo:data_inicio ?inicio_sancao ; ardo:data_final ?final_sancao ; ardo:aplicadaSobre ?fornecedor.

    ?fornecedor a ardo:PessoaJuridica ; ardo:nome_fornecedor ?nome_fornecedor ; ardo:temPorte ?porte .
    ?porte ardo:descricao ?porte_nome .

  }
GROUP BY ?porte_nome
ORDER BY DESC(?numero_de_fornecedores)


# Listagem das modalidades de Licitação Encontradas
SELECT ?nome_modalidade COUNT(*)
WHERE{
       ?licitacao a ardo:Licitacao.
       ?licitacao a ?modalidade .
       ?modalidade rdfs:subClassOf ardo:ModalidadeLicitacao .
       ?modalidade rdfs:label ?nome_modalidade .
}