getDamageOnLeek

/*
Renvoi les dégâts minimum et maximum en prenant en compte le bouclier de la cible

Paramètres :
weaponOrChip : Constante d'une arme ou d'une puce
leek : Id du poireau auquel seront infligés les dégâts

Opérations : Presque 900
Niveau : 38

Auteur : TheTintin
*/

function getDamageOnLeek (weaponOrChip, leek) {
    var damage = [];
    var effects;

    if (isWeapon(weaponOrChip)) {
        effects = getWeaponEffects(weaponOrChip);
    } else if (isChip(weaponOrChip)) {
        effects = getChipEffects(weaponOrChip);
    }

    for (var effect in effects) {
        if (effect[0] == EFFECT_DAMAGE) {
            push(damage, effect[1]);
            push(damage, effect[2]);
            break;
        }
    }

    if (isEmpty(damage)) {
        return [0,0];
    }

    for (var i = 0; i < count(damage); i++) {
        damage[i] = damage[i] * (1 + (getStrength() / 100));
        damage[i] = round(damage[i] * (1 - (getRelativeShield(leek) / 100)));
        damage[i] = damage[i] - getAbsoluteShield(leek);
        if (damage[i] < 0) {
            damage[i] = 0;
        }
    }

    return damage;
}

/*
Exemple d'utilisation :
var damageMin = getDamageOnLeek (CHIP_FLAME, getNearestEnemy() );
*/