SNN (symmetric nearest neighbour) filter

/* SNN (symmetric nearest neighbour) filter; cf. http://subsurfwiki.org/wiki/Symmetric_nearest_neighbour_filter

This is some sort of a denoising filter with an edge enhancing effect. What's implemented here is not strictly an SNN filter, but instead the pixels in each pair are weighted by the negative fourth power of their differences relative to the reference pixel and blended. If edge enhancement is not desired, setting ee=false takes the median of the reference pixel and the pixels in the pair (i.e. the closer of the two pixels, unless their differences have opposite sign).

Why did I even write this filter?

int radius: filtering radius (default 1)
bool ee: edge enhancement (default true)
string chroma: chroma processing; if not set to "process", the returned clip is Y8 (default "process")

Dependencies: ApplyEvery, Masktoolsv2, RgTools. Avisynth 2.6 or Avisynth+ also required.
*/

function snn(clip c,int "radius",bool "ee",string "chroma")
{
    chroma = default(chroma,"process")
    r = default(radius,1)
    ee = default(ee,true)
    function shift(clip c,int x,int y) {c.pointresize(c.width(),c.height(),x,y)}
    function closer(clip a,clip b,clip c,bool ee)
    {
        ab = mt_makediff(a,b)
        ac = mt_makediff(a,c)
        mindiff = mt_lutxy(ab,ac,"x 128 - y 128 - * x 128 - 3 ^ y 128 - 3 ^ + x 128 - 4 ^ y 128 - 4 ^ 0.0001 + + / * round 128 +")
        mt_makediff(a,mindiff)
        ee ? last : interleave(a,b,c).clense().selectevery(3,1)
    }
    function point(clip c,int n,int r,bool ee)
    {
        x=n%(2*r+1)
        y=(n-x)/(2*r+1)
        c
        closer(last,shift(x-r,y-r),shift(r-x,r-y),ee)
    }
    function points(clip c,int n,int r,bool ee)
    {
        n > 0 ? interleaveevery(points(c,n-1,r,ee),point(c,n,r,ee),n+1,0) : point(c,0,r,ee)
    }
    assert(c.isyuv(),"snn: input clip must be YUV")
    c.converttoy8()
    points(last,2*(r*r+r),r,ee)
    temporalsoften(r*r+r,255,255)
    selectevery(2*(r*r+r)+1,r*r+r)
    chroma == "process" ? ytouv(c.utoy().snn(radius,ee,"ignore"),c.vtoy().snn(radius,ee,"ignore"),last) : last
}