VadSid_6

Model Small
Stack 1024
.186
DATASEG
    OutValNL db 1 ;Флаг перевода на новую строку после вывода функцией OutVal
    NegC dw 0 ;Счетчик отрицательных элементов
    PosSum dw 0 ;Сумма положительных элементов
    CurZero dw 0 ;Количество нулевых элементов текущей строки
    MaxZero dw 0    ;максимально встреченное количество нулевых элементов
    MaxZeroLN db 0
    BiggerElem dw 0 ;Наибольший по модулю элемент матрицы A

    Temp dw 0
    BufLen db 3h ;Максимальное количество символов для ввода
    BufSize db 0h ;Реальное количестве введенных символов
    Text db 255 dup(0) ;Буфер для ввода текста, а также генерации вывода
    NewLine db 0Dh, 0Ah, '$'

    N DB 0   ;Размерность матрицы
    A DW 256 DUP(0) ;Память для матрицы
    B DW 256 DUP(0) ;Матрица B

    InputN db 'Введите размер матрицы: $';
    InputMatr db 'Введите матрицу: $';
    PosElemsSum db 'Сумма положительных элементов: $';
    NegElemsCount db 'Количество отрицательных элементов: $';
    MaxZeroesLine db 'Строка с максимальным количеством нулевых элементов: $';
    SrcMatrix db 'Матрица: ', 0dh, 0ah, '$';
    ResultMatrix db 'Результирующая матрица: ', 0dh, 0ah, '$';
    Space db ' $';
    Inp_1 db 'A($'
    Inp_2 db ',$'
    Inp_3 db ') = $'

CODESEG

Start:
    mov ax,@data
    mov ds,ax ;Адрес сегмента данных куда положено
InpSizeAgain:
    mov dx,offset InputN ;Выводим приглашение для ввода и вводим размерность матрицы
    call OutStr
    call ReadLine
    cmp ax,1        ;Проверяем, чтобы размер не был слишком велик.
    jb InpSizeAgain
    cmp ax,9
    ja InpSizeAgain
    mov [n],al ;Кладем ее в ячейку n
    mov dx,offset InputMatr ;Выводим приглашение для ввода матрицы, и вводим ее.
    mov si,offset A
    xor bx,bx
InputI:         ;Непосредственно сам ввод
            ;Матрица будет расположена по строкам в ряд. Первая строка, затем сразу-же следующая.
    mov [OutValNL],0 ;Вывод без перехода на новую строку, пока что
    mov dx,offset Inp_1 ;Выводим подсказку для ввода (какой элемент по счету вводим)
    call OutStr
    xor ax,ax
    mov al,bh
    inc al
    call OutVal
    mov dx,offset Inp_2
    call OutStr
    mov al,bl
    inc al
    call OutVal
    mov dx,offset Inp_3
    call OutStr

    mov [OutValNL],1 ;А теперь с переходом
    call ReadLine
    ;Сразу проверим, отрицательный ли элемент
    test ax,ax
    jns AfterCalcNeg ;Если нет - посчитаем сумму
    inc [NegC]  ;Если да, корректируем переменные-счетчики
    xor ax,ax   ;Обнуляем отрицательный элемент
    jmp AfterCalc
AfterCalcNeg:
    add [PosSum],ax ;Если элемент положительный, увеличиваем сумму
AfterCalc:
    mov [si],ax
    test ax,ax
    jnz NotIncZeroes
    inc word ptr [CurZero]
NotIncZeroes:
    add si,2
NegAgain:   ;Получаем абсолютное значение текущего элемента
    neg ax
    js NegAgain
    cmp [BiggerElem],ax
    jae NotUpdateBE
    mov [BiggerElem],ax
NotUpdateBE:
    inc bh
    cmp bh,[n]
    jne InputI  ;Каждую строку
    mov ax,[CurZero] ;Проверяем на максимальное количество нулевых элементов. Если находим, где больше, то обновляем.
    cmp ax,[MaxZero]
    jle NotReplaceMax
    mov [MaxZero],ax
    mov [MaxZeroLN],bl
    inc [MaxZeroLN]
NotReplaceMax:
    mov word ptr [CurZero],0
    xor bh,bh
    inc bl
    cmp bl,[n]
    je NoLongJmp    ;Каждый столбец
    jmp InputI
NoLongJmp:
    ;Рассказываем, сколько и чего обнаружили.
    mov dx,offset PosElemsSum
    call OutStr
    mov ax,[PosSum]
    call OutVal
    mov dx,offset NegElemsCount
    call OutStr
    mov ax,[NegC]
    call OutVal
    mov dx,offset MaxZeroesLine
    call OutStr
    xor ax,ax
    mov al,[MaxZeroLN]
    call OutVal
    ;Выведем исходную матрицу
    mov dx,offset SrcMatrix
    call OutStr
    mov si,offset A
    call OutMatrix


    ;Теперь сделаем матрицу B.
MatrixBGen:
    mov si,offset A
    mov di,offset B
    xor ax,ax
    mov al,[n]
    mul ax
    mov cx,ax   ;В CX - количество элементов матрицы A
MulLoop:
    mov ax,[si] ;Умножаем каждый элемент на найденный максимальный.
    mul word ptr [BiggerElem]
    mov [di],ax
    add di,2
    add si,2
    dec cx
    jnz MulLoop

    mov dx,offset ResultMatrix
    call OutStr
    mov si,offset B
    call OutMatrix

    mov ah,04Ch
    int 21h


    ;Функция, выводит матрицу на экран
OutMatrix:
    mov [OutValNL],0 ;Вывод без перехода на новую строку, пока что
    xor bx,bx
OutNextElem:
    mov ax,[si]
    call OutVal
    mov dx,offset Space
    call OutStr
    add si,2
    inc bh
    cmp bh,[n]
    jne OutNextElem ;Каждую строку
    mov dx,offset NewLine
    call OutStr
    xor bh,bh
    inc bl
    cmp bl,[n]
    jne OutNextElem
    mov [OutValNL],1 ;Включаем переход назад
    ret


    ;Функция, читает строку символов с клавиатуры
    ;По выходу возвращает в регистре AX введенное число.
ReadLine:
    pusha
Againa:
    mov ah,0ah
    mov [BufLen],4
    mov dx,offset BufLen
    int 21h
    xor di,di
    xor ax,ax
    mov cl,[BufSize]
    xor ch,ch
    xor bx,bx
    mov si,cx
    mov cl,10
    xor bp,bp
    cmp byte ptr [Text+di],'-'
    jne ConvToBin
    inc bp
    inc di
ConvToBin:
    mov bl,byte ptr [Text+di]
    sub bl,"0"
    js Againa
    cmp bl,9
    ja Againa
    mul cx
    add ax,bx
    inc di
    cmp di,si
    jb ConvToBin
AfterAll:
    dec bp
    jnz NotNeg2
    neg ax
NotNeg2:
    mov [Temp],ax
    mov dx,offset NewLine
    call OutStr
    popa
    mov ax,[Temp]
        ret

    ;Функция, выводит содержимое регистра ax на экран.
    ;Перед этим, двоичное значение в AX преобразуется в строку по адресу Text.
OutVal:
    pusha
    mov si,offset Text
    test ax,ax
    jns d0
    neg ax
    mov [si],byte ptr '-'
    inc si
d0:
    mov bx,10
    xor cx,cx
d1:
    xor dx,dx
    idiv bx
    push dx
    inc cx
    test ax,ax
    jnz d1
d2:
    pop ax
    add al,"0"
    mov [si],al
    inc si
    loop d2
    mov [si],byte ptr '$'
    mov dx, offset Text
    call OutStr
    cmp [OutValNL],0
    je NotOutNL
    mov dx, offset NewLine
    call OutStr
NotOutNL:
    popa
    ret

    ;Функция, выводит строку по адресу ds:dx
OutStr:
    pusha
    mov ah,09h
    int 21h
    popa
    ret
END Start